Create layer lisp problem in R2012

[marc.verdaasdonk697335]

Hi Guys,

I’ve got a lisp routine that creates a layer, sets the color, weight and specially the description.
It works perfectly in AutoCAD2010. Now I’m upgrading to AutoCAD 2012 and the program will not work….

Can anybody help my, with correcting my program, or sharing another working one?

(defun CreateLayer (Name FrzLock Color LType Plot LWeight Desc)
  (entmakex
    (list (cons 0 "LAYER")
  (cons 100 "AcDbSymbolTableRecord")
  (cons 100 "AcDbLayerTableRecord")
  (cons 2 Name)
  (cons 70 FrzLock)
  (cons 62 Color)
  (cons 6 LType)
  (cons 290 Plot)
  (cons 370 LWeight)
  (list -3 (list "AcAecLayerStandard" (cons 1000 "") (cons 1000 Desc)))
    )
  )
  (setvar "CLAYER" Name)
)

Thank you,
Marc

[rkmcswain]

Works fine here in 2013.
Make sure you are not trying to reference something that doesn't exist. For example, you can't create a new layer and set the HIDDEN linetype to it, if HIDDEN is not loaded.

[marc.verdaasdonk697335]

the keyin I've used:

(CreateLayer "54_00-P" 0 50 "continuous" 1 50 "Gas general (primary)")

and that doesn't do it!

[rkmcswain]

Your function worked fine here in 2013.

While you're in ACAD, type in VLIDE.
In this window, ppen a new file, then paste your code in.
Below that, outside the (defun), paste in your function above.
Now load all the code in the window (Ctrl+Alt+E)

This should at least point you to the line where it's failing.

[Tharwat]

It did not work either due to the description , I removed the description and it did work .

[Tharwat]

I guess this way works better ..

(defun CreateLayer (Name FrzLock Color LType Plot LWeight)
  (entmakex (list (cons 0 "LAYER")
                  (cons 100 "AcDbSymbolTableRecord")
                  (cons 100 "AcDbLayerTableRecord")
                  (cons 2 Name)
                  (cons 70 FrzLock)
                  (cons 62 Color)
                  (cons 6 LType)
                  (cons 290 Plot)
                  (cons 370 LWeight)
            )
  )
)
(if (setq l (CreateLayer "54_00-P" 0 50 "continuous" 1 50))
  (progn (vla-put-Description (vlax-ename->vla-object l) "Gas general (primary)")
         (setvar "CLAYER" "54_00-P")
  )
)
(vl-load-com)

[marc.verdaasdonk697335]

I also found the problem is in the description.
The description is the most important part of this code.

On the other hand, I need to be able to use this code with variables. I need to create layers from the tool pallet so that's why I want to code to use something like:

(CreateLayer "layername" 0 50 "continuous" 1 50 "description")

What I can’t understand is why it worked in R2010 and not in R2012. The code is the same…..

[Tharwat]

I need to be able to use this code with variables. I need to create layers from the tool pallet so that's why I want to code to use something like:

(CreateLayer "layername" 0 50 "continuous" 1 50 "description")

So here it goes ....

(defun CreateLayer (Name FrzLock Color LType Plot LWeight Desc)
  (setq l (entmakex (list (cons 0 "LAYER")
                          (cons 100 "AcDbSymbolTableRecord")
                          (cons 100 "AcDbLayerTableRecord")
                          (cons 2 Name)
                          (cons 70 FrzLock)
                          (cons 62 Color)
                          (cons 6 LType)
                          (cons 290 Plot)
                          (cons 370 LWeight)
                    )
          )
  )
  (if l
    (progn (vla-put-Description (vlax-ename->vla-object l) Desc) (setvar "CLAYER" Name))
  )
)
(vl-load-com)

(CreateLayer "54_00-P" 0 50 "continuous" 1 50 "Gas general (primary)")

EDIT : Name of Layer were written instead of the variable name

[marc.verdaasdonk697335]

This is very close!

Only thing is that I use the lisp in a menu. This menu is also used to control the layers. So it will happen that the code is used to activate a layer.
This doesn't work now.

So is it possible to change the code that the layer gets active when it already excists.

[irneb]

Uhmm ... setvar the CLayer to the new layer's name perhaps? Like you had in the old one's last line?

BTW, what should happen if the layer already exists? Should the properties be updated, or left as is?