Results 1 to 2 of 2

Thread: copier un scu

  1. #1
    Woo! Hoo! my 1st post
    Join Date
    2015-08
    Posts
    1
    Login to Give a bone
    0

    Default copier un scu

    Bonjour quelqu'un connais un moyen simple de copier un scu nommés d'un dwg à un autre?

    merci

  2. #2
    I could stop if I wanted to
    Join Date
    2007-08
    Posts
    201
    Login to Give a bone
    0

    Default Re: copier un scu

    Salut,

    Tu peux voir ici

    Ou mieux, cette version (fonctionne que le dessin source soit ouvert ou non)
    Code:
    ;; IMPORTUCS (gile)
    ;; Importe tous les SCUs nommés du DWG sélectionné
     
    (defun c:importUCS (/ UCSs filename doc odbx docUCSs name ucslst)
      (vl-load-com)
      (setq	UCSs
    	 (vla-get-UserCoordinateSystems
    	   (vla-get-activedocument (vlax-get-acad-object))
    	 )
      )
      (if (setq filename
    	     (getfiled "Fichier Source" (getvar "dwgprefix") "dwg" 0)
          )
        (progn
          (vlax-for	d (vla-get-Documents (vlax-get-acad-object))
    	(if (= (strcase (vla-get-Fullname d)) (strcase filename))
    	  (setq doc d)
    	)
          )
          (or doc
    	  (setq	doc  (OpenDrawingDBX filename)
    		odbx T
    	  )
          )
          (setq docUCSs (vla-get-UserCoordinateSystems doc))
          (if (< 0 (vla-get-Count docUCSs))
    	(progn
    	  (vlax-for x docUCSs
    	    (setq name (vla-get-Name x))
    	    (or
    	      (getitem UCSs name)
    	      (wcmatch name "_Active*")
    	      (setq ucslst (cons x ucslst))
    	    )
    	  )
    	  (if ucslst
    	    (progn
    	      (vlax-invoke doc 'CopyObjects ucslst UCSs)
    	      (princ
    		(strcat "\n" (itoa (length ucslst)) " SCU(s) importé(s).")
    	      )
    	    )
    	    (princ "\nAucun SCU différent dans le dessin source.")
    	  )
    	  (and odbx (vlax-release-object doc))
    	)
    	(princ "\nAucun SCU enregistré dans le dessin source.")
          )
        )
      )
      (princ)
    )
     
    ;;; Accéder à un dessin fermé
     
    (defun OpenDrawingDBX (filename / objdbx release)
      (setq	objdbx
    	 (vlax-create-object
    	   (if (< (setq release (atoi (getvar "ACADVER"))) 16)
    	     "ObjectDBX.AxDbDocument"
    	     (strcat "ObjectDBX.AxDbDocument." (itoa release))
    	   )
    	 )
      )
      (vla-open objdbx filename)
      objdbx
    )
     
    ;;; GetItem (gile)
    ;;; Retourne le vla-object de l'item s'il est présent dans la collection
    ;;;
    ;;; Arguments
    ;;; col : la collection (vla-object)
    ;;; name : le nom de l'objet (string) ou son indice (entier)
    ;;;
    ;;; Retour : le vla-object ou nil
     
    (defun GetItem (col name / obj)
      (vl-catch-all-apply
        '(lambda () (setq obj (vla-item col name)))
      )
      obj
    )
    Last edited by 'gile'; 2009-07-05 at 08:10 PM.

Similar Threads

  1. 2014: Copier une lucarne
    By acor in forum Revit Architecture - General
    Replies: 0
    Last Post: 2013-07-17, 01:31 PM
  2. déplace/copier
    By P. De Witte in forum Revit Architecture - Tips & Tricks
    Replies: 7
    Last Post: 2012-03-30, 09:20 AM
  3. copier les cotes
    By izaline in forum Revit Architecture - Tips & Tricks
    Replies: 5
    Last Post: 2010-07-23, 12:48 PM
  4. copier un mur
    By rg3194 in forum Revit Architecture - General
    Replies: 3
    Last Post: 2007-08-10, 08:08 AM
  5. K+E 4038 Copier
    By stesta in forum AutoCAD Plotting
    Replies: 0
    Last Post: 2004-10-22, 02:14 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •