Engineering Notation in DXF Codes

[jsteveadams]

Hi Everybody,

I know I this is a dumb question, but please help me anyway..... :^)

I am trying write a lisp to get the distance betweem two AECC_points by picking the point number entity (they used to be attributes, don't know what they are now, as I'm new to LDD).

When I extract the dxf codes for the AECC_points I get, for example:

for assoc 11:
(429707.0 2.09055e+006 -1.0e+020)

when I check the distance (distance a b) between two entities I get:
1.0e+020

I checked DDunits, and everything's A-ok. (Linear units set to decimal, not engineering)

How can I get results that are in regular-ol' distances? i.e. 196.12'

Thanks, Steve (LDD Companion C3D 2009)

[RobertB]

If you are just reporting what is the distance value and are happy with a string, you can use: (rtos (distance a b) 2 2)

[jsteveadams]

Thanks Mr. Bell,

But when I try:

(setq a 1.0e+020)
(rtos a 2 2)

I still get : "1.00E+20"

Any ideas?

Thanks,

Steve

[ccowgill]

I know it isnt any help, but I was never able to figure it out when I had the problem last year. Instead, I just decided to modify my methods. I was attempting to select points with large coordinates, so I modified my code to move all points closer to 0,0, run the program, then move everything back (via undo)

[David Bethel]

1e+20 is a very very big number. Bigger than the 15 significant digits than acad can handle in a real number. -David

[irneb]

Try this

(defun rtos1 (n p / i f s s1)
  (setq i (fix (abs n)) ;Get the integer portion
        f (- (abs n) i) ;Get the fraction portion
  ) ;_ end of setq

  ;; Do the integer portion
  (if (= i 0) ;If integer is zero
    (setq s "0") ;Then set string to reflect
    (progn ;Else
      (setq s "") ;Initialize string to empty
      (while (> i (- (expt 10 8) 1)) ;While i has more than 8 digits
        (setq s1 (itoa (fix (rem i (expt 10 8))))) ;Get the last 8 digits from i
        (while (< (strlen s1) 8) (setq s1 (strcat "0" s1))) ;Padd with zeros
        (setq s (strcat s1 s) ;Add last 8 digits to string
              i (fix (/ i (expt 10 8))) ;Remove last 8 digits from i
        ) ;_ end of setq
      ) ;_ end of while
      (if (> i 0) ;If digits still left in i
        (setq s (strcat (itoa (fix i)) s)) ;Add to string
      ) ;_ end of if
    ) ;_ end of progn
  ) ;_ end of if

  ;; Do the fraction part
  (if (and (> p 0) (> f 0)) ;If there is a fraction part
    (progn
      (setq s (strcat s ".")) ;Add the decimal point
      (while (and (> p 0) (not (equal f 0.0 (expt 0.09999999 p)))) ;While f has digits below the decimal
        (setq i (fix (* f 10)) ;Get the 1st digit after the decimal
              s (strcat s (itoa i)) ;Add it to the string
              f (- (* f 10) i) ;Move f's digits & remove the integer portion
              p (1- p) ;Remove the prcision just added
        ) ;_ end of setq
      ) ;_ end of while
      ;; Pad left over precision with zeros
      (while (> p 0)
        (setq s (strcat s "0")
              p (1- p)
        ) ;_ end of setq
      ) ;_ end of while
    ) ;_ end of progn
  ) ;_ end of if

  ;; Check if negative
  (if (< n 0)
    (setq s (strcat "-" s))
  ) ;_ end of if
  s ;Return the string
) ;_ end of defun

It only handles decimal though, and you have to add the precision. E.g. (rtos1 1.0e+20 0) gives "100000000000000000000", and (rtos1 1.0e-20 20) gives "0.00000000000000000001". But (rtos1 1.0e-20 19) gives "0.0000000000000000000"

[jsteveadams]

Thanks irneb, I really appreciate your time and the code.

I run into a lot of these notations nowadays, and this will let me be able to use those numbers.

Thank you,

Steve

[irneb]

You're welcome.

BTW, from the name of this thread I was at first of the opinion you were requesting something different. I.e. Engineering Notation works on exponents of 10 in multiples of 3 (e.g. 30000 = 30.0E+03). I mention this since I ran into a similar problem with OpenOffice Calc (the Excel alternative).

See my 2 attachments in this thread: http://qa.openoffice.org/issues/show_bug.cgi?id=5930

It can do the true Engineering Notation as well as SI (i.e. mili, kilo, giga, etc.). Unfortunately it's only written to work in OOoCalc, not Excel.