Results 1 to 3 of 3

Thread: Find arc radius given length and chord

  1. #1
    100 Club
    Join Date
    2015-11
    Location
    Waxahachie, Texas
    Posts
    137
    Login to Give a bone
    0

    Default Find arc radius given length and chord

    Does anyone know how to draw an arc when only given the arc length and chord length?

    I know that the chord length is 19'-4 1/2" and I know that the arc length is 24'-8". How do I find the radius?

    Any help would be greatly appreciated.

  2. #2
    All AUGI, all the time buzz's Avatar
    Join Date
    2007-10
    Location
    Tucson, Arizona
    Posts
    613
    Login to Give a bone
    0

    Default Re: Find arc radius given length and chord

    See if this helps: http://norman.rasmussen.co.za/24/rad...-chord-length/

    (via my good buddy, Google)

    -Buzz
    no trophy, no flowers, no flashbulbs, no line,
    he's haunted by something he cannot define...

  3. #3
    100 Club
    Join Date
    2015-12
    Posts
    102
    Login to Give a bone
    0

    Default Re: Find arc radius given length and chord

    From the wizard known as _gile:

    Code:
    ;;; ArcChord->Angle (Newton method) by _gile
    ;;; Returns the arc angle according to its chord and length 
    
    (defun ArcChord->Angle (arc corde / k x) 
      (setq k (/ corde arc) 
            x (sqrt (- 6 (* 6 k))) 
            ) 
      (repeat 6 
        (setq x (- x (/ (- (sin x) (* k x)) (- (cos x) k)))) 
        ) 
      (* 2 x) 
    ) 
    ;;;======================================;;; 
    ;;;Testing command 
    (defun c:test (/ chord arc ang rad) 
      (while 
        (not 
          (and (setq chord (getdist "\nLength of chord: ")) 
               (setq arc (getdist "\nLength of arc: ")) 
               (< chord arc) 
               ) 
            ) 
        (prompt "Try again -- arc must be longer than chord.") 
        ) 
    
      (setq ang (ArcChord->Angle arc chord) 
            rad (/ chord (* 2. (sin (/ ang 2.)))) ) 
      (prompt 
       (strcat "\nChord length = " (rtos chord) 
                "\nArc length = " (rtos arc) 
                "\nRadius = " (rtos rad) 
                "\nAngle = " (angtos ang) ) 
      )
      (princ)
    )
    Last edited by RobertB; 2010-02-15 at 07:40 PM. Reason: Added [code] tags

Similar Threads

  1. delta radius length tangent lisp
    By mgonzales361438 in forum AutoLISP
    Replies: 3
    Last Post: 2014-06-11, 07:52 AM
  2. 2013: Autocad Lisp (Bearing, Chord, Arc, Radius)
    By jarrod822295 in forum Survey - General
    Replies: 0
    Last Post: 2013-01-13, 11:07 PM
  3. How to find the length from the start point of a polyline?
    By pferreira in forum AutoCAD Tips & Tricks
    Replies: 1
    Last Post: 2006-07-10, 03:36 AM
  4. Arcs by P.C., arc length, Radius, Tangent bearing, Delta
    By justinxxvii in forum AutoCAD General
    Replies: 4
    Last Post: 2006-04-29, 10:32 PM
  5. Dimension Radius Length
    By matt.bauer in forum AutoCAD LT - General
    Replies: 9
    Last Post: 2004-12-21, 02:28 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •