routine to insert Xref's

[moonlight_9630]

Hi guys,
this has been asked several times but i still cant find a way to do so
i need a routine to insert xref,s . what im thinking of is a script i can apply to many drawings by script pro and during each session i get asked to choose the file to xref.
do you guys have any thought or could be better idea to do this.

Many thanks in advance

[Opie]

Have you tried the XATTACH command? A little more information would be helpful.

[moonlight_9630]

Have you tried the XATTACH command? A little more information would be helpful.

Thanks Opie, it looks good, but i have to click "ok" after choosing the file to xref, i don't usually change any of the insertion default sittings, so can i automate this by script so no need to click "ok" ?
In fact i just need the fastest and easiest way to insert xrefs, I'm not stick to particular way.

[irneb]

That xattach command always opens the file selection dialog as well as the External Reference dialog. No matter if it's called from lisp or a script. Also no matter what filedia / cmddia are set to.

What I suggest you try is use the INSERT command to first insert the DWG as a block. Then change it by calling the Express tool BlockToXref's support defun (acet-block-to-xref ...). Look at the blocktoxrefsup.lsp file in the Express folder. The defun asks for the block name, the file name and then a T/nil to purge.

A bit convoluted, but at least it "should" work.

[alanjt]

Couldn't you just use (getfiled .....) and (command "_.-xref"...)?

[irneb]

Ugh , you're correct!

But you don't even need to use getfiled first. You can simply automate the arguments of the -XREF command:

(defun c:QuickXAttach (/)
  (initdia)
  (command "_.-XREF" "_Attach" "_None" '(0.0 0.0 0.0))
  (while (> (getvar "CMDACTIVE") 0) (command ""))
  (princ)
)

If you need to be able to select the insertion point, change the "_None" '(0.0 0.0 0.0) to pause.

[alanjt]

Ugh , you're correct!

But you don't even need to use getfiled first. You can simply automate the arguments of the -XREF command:

(defun c:QuickXAttach (/)
  (initdia)
  (command "_.-XREF" "_Attach" "_None" '(0.0 0.0 0.0))
  (while (> (getvar "CMDACTIVE") 0) (command ""))
  (princ)
)

If you need to be able to select the insertion point, change the "_None" '(0.0 0.0 0.0) to pause.

True, I was just thinking about if the user doesn't select a file.

(defun c:QuickXAttach (/ f)
  (if (setq f (getfiled "Select Reference File:" (getvar 'dwgprefix) "dwg" 2))
    (progn (command "_.-XREF" "_Attach" f "_None" '(0.0 0.0 0.0))
           (while (> (getvar "CMDACTIVE") 0) (command ""))
    )
  )
  (princ)
)

[irneb]

Good point

... Many ways to skin a cat:

(defun c:QuickXAttach (/)
  (initdia)
  (command "_.-XREF" "_Attach")
  (if (> (getvar "CMDACTIVE") 0)
    (progn
      (command "_None" '(0.0 0.0 0.0))
      (while (> (getvar "CMDACTIVE") 0) (command ""))
    )
  )
  (princ)
)

From the back or the front

[alanjt]

Good point

... Many ways to skin a cat:

(defun c:QuickXAttach (/)
  (initdia)
  (command "_.-XREF" "_Attach")
  (if (> (getvar "CMDACTIVE") 0)
    (progn
      (command "_None" '(0.0 0.0 0.0))
      (while (> (getvar "CMDACTIVE") 0) (command ""))
    )
  )
  (princ)
)

From the back or the front

Very impressive! I never would have thought of that.

[moonlight_9630]

Thank you guys, it was of great help