Repeat a command in lisp...

[the_andyman17]

I'm trying to get this sub-routine to ask a user to draw a line by picking two points. I don't want the user to have to do anything other than pick two points. They don't even have to hit enter. This works fine, the problem I'm having is repeating it an unlimited amount of times until the user hits ENTER.

I know I can do this setting pt1 and pt2 variables and drawing a line between them, but I like the vanilla "line" command how it previews the line before you pick the 2nd point.

The problem is at the 2nd "while".
Here it is:

(defun polyop ()
(command "-layer" "m" "Hal_Edge" "")
(command "pline")
(prompt "\nDraw slab edge at polygonal opening:")
(while (= (getvar "cmdactive") 1) (command pause))
(command "-layer" "m" "Hal_Cross" "")
(while
	(prompt "\nDraw crossing line:")
	(command "line" pause pause "")
)
(princ)
);defun
(princ)

[rkmcswain]

....the problem I'm having is repeating it an unlimited amount of times until the user hits ENTER.

Try this:

(command "._LINE")
(while (eq 1 (logand (getvar"CMDACTIVE") 1))
  (command pause)
)

[the_andyman17]

Thanks, but that didn't work unfortunately.

[rkmcswain]

What doesn't work about it?

[alanjt]

Should work fine. One of the downfalls to using PAUSE is you lose any prompts. However, you can add your own...

(command "._LINE")
(while (eq 1 (logand (getvar "CMDACTIVE") 1))
  (princ "\nSpecify point: ")
  (command pause)
)

[RobertB]

Should work fine. One of the downfalls to using PAUSE is you lose any prompts. However, you can add your own...

I believe this is what the OP is looking for:

(defun polyop  (/ pt1 pt2)
 (command "._-layer" "_make" "Hal_Edge" "")
 (command "._pline")
 (prompt "\nDraw slab edge at polygonal opening: ")
 (while (= (getvar "cmdactive") 1) (command pause))
 (command "._-layer" "_make" "Hal_Cross" "")
 (while (and (setq pt1 (getpoint "\nSpecify first point: "))
             (setq pt2 (getpoint pt1 "\nSpecify second point: ")))
  (command "._line" pt1 pt2 ""))
 (princ))
(princ)