LISP to get total length including ARC, Pline & lines?

[windowsxp5]

Hi frnds..
i have a lisp file that can LIST the the total length of lines.(only lines; it dosent support pline,arc etc.)

anyone using (or can create) a lisp to get total lenght including ARC, Pline & lines?
i can attach the lisp file i have(linesum.lsp)

[Mike.Perry]

Hi

Have you tried the Forum search facility -

Search Forums

A quick search returned the following (hopefully will get you going in the right direction) -

Total polyline length

Multiple Pline Calculation

Does a sum or total length feature exist?

Have a good one, Mike

[stig.madsen]

Otherwise, here's a simple start if you want to write your own:

(defun C:SUMIT (/ ent dist endPar obj otype sum)
  (setvar "ERRNO" 0)
  (setq sum 0.0)
  (while (and (not (vl-catch-all-error-p
                  (setq ent (vl-catch-all-apply 'entsel))))
              (/= (getvar "ERRNO") 52))
    (setq obj    (vlax-ename->vla-object (car ent)))
    (cond ((not (vl-catch-all-error-p
               (setq endPar (vl-catch-all-apply 'vlax-curve-getEndParam (list obj)))))
           (setq dist  (vlax-curve-getDistAtParam obj endPar)
                 sum   (+ sum dist)
                 otype (vla-get-objectName obj)
           )
           (mapcar 'princ (list "\nAdding " otype ": " dist)))
          (T (princ "\nObject has no length definition"))
    )
  )
  (princ "\nTotal length: ")(princ sum)
  (princ)
)