Prompting Properties of Selected Entity on Separate Lines

[harilalmn]

Hi All,
This program is to list the properties of a selected object.
But it prompts all the properties on single line. I would like the properties listed one by one on separate lines. How do I modify it to do so?

(defun c:Prop ()
(setq en(car(entsel)))
(foreach a (entget en) (princ a))
(PRINC)
)

[harilalmn]

Well, I did something like this;

(defun c:Prop ()
(setq en(car(entsel)))
(foreach a (entget en) (princ a)
  (prompt "\n")
)
(PRINC)
)

Anything better?

[rkmcswain]

Well, I did something like this;
Anything better?

You might want to (entget) just once, then handle the list.

(defun c:Prop ()
(setq en (entget (car (entsel))))
(foreach a en
  (princ a)
  (prompt "\n")
)
(PRINC)
)

;;; alternative
(defun c:Prop (/ en)
  (setq en (entget (car (entsel))))
  (mapcar '(lambda (x) (princ x)(princ "\n")) en)
  (princ)
)

[alanjt]

(defun c:Info (/ opt obj)
  ;; VLA & DXF Info of selected Primary or Nested object
  ;; Alan J. Thompson
  (initget 0 "Nested Primary")
  (setq opt (cond ((getkword "\nSpecify selection mode [Nested/Primary] <Primary>: "))
                  ("Primary")
            )
  )
  (if (setq obj (car ((if (eq opt "Primary")
                        entsel
                        nentsel
                      )
                       (strcat "\nSelect " opt " object for VLA & DXF info: ")
                     )
                )
      )
    (progn
      (textscr)
      (princ "\nVLA Info:\n\n")
      (vlax-dump-object (vlax-ename->vla-object obj) T)
      (princ "\nDXF Info:\n")
      (mapcar 'print (entget obj '("*")))
    )
  )
  (princ)
)