Select entities by color of an exploded block

**cadconcepts** · 2011-06-17, 05:50 PM

Hi All

What I am trying to do is explode a block and then find all of the entities that were within the block that are in red (1) and create a selection set of them. I have been working with the following snippet of code and I cannot get it to work. Any help is greatly appreciated. Thanks.

Manuel

Code:

     (setq entmp (entlast))
     (command ".explode" entmp)
     (setq nsset (ssadd)
             ent (entnext entmp)
     )
    (while entmp
      (if (= (dxf 62 (entget ent)) 1)
        (setq nsset (ssadd ent nsset)
                ent (entnext entmp)
                entmp ent
        
          )
       )
    )

**Opie** · 2011-06-17, 06:52 PM

Are these items set to red based on the layer or are they set to red by object? If they are by layer, then there will not be a group code for 62.

You would need to get a list of layers that have red assigned to them. Remember, layers that are set to Off have their color assigned as a negative number.

Once you have this list, you could update your selection set filter to also include those layers.

Another thing is a successful EXPLODE command creates a new selection set.

**cadconcepts** · 2011-06-17, 07:02 PM

Opie

Can I search a select set for all entities on a layer whose color has been changed to red? Thanks.

Manuel

**Tharwat** · 2011-06-17, 07:41 PM

Maybe This way ?

Add your Layer name as shown below .

Code:

(setq ss (ssget "_x" '((8 . "YourlayerName")(62 . 1))))

**Opie** · 2011-06-17, 08:14 PM

Tharwat, I don't think that will work. You want to select entities that may have the color changed or have their layer color set to the desired value.

Manuel, you need to cycle through the layer list and create a list of layers with your desired color. You could do this with a while statement.

Code:

(defun LayerListByColor	(ColorNumber / LayerData LayerList)
  (setq LayerList '())
  (while (setq LayerData (tblnext "LAYER" (not LayerData)))
    (if	(= (cdr (assoc 62 LayerData)) ColorNumber)
      (setq
	LayerList (append LayerList (list (cdr (assoc 2 LayerData))))
      )
    )
  )
  (if (> (length LayerList) 0)
    LayerList
  )
)

Once this list is generated, use the layer names and CONStruct an associative list. You can quickly do this with the MAPCAR and LAMBDA functions.

Code:

(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1))

From there you need to add a filter for color and wrap the entire filter with an set of "XOR" filters

Code:

(setq filter (list (cons -4 "<XOR")(cons 62 1)(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1))(cons -4 "XOR>")))

You could then add this to your SSGET function.

Code:

(ssget filter)

**cadconcepts** · 2011-06-18, 12:50 PM

Tharwat

Thank you for the suggestion. I was able to modify your code to use ssget "_P" and get it to worked.

Manuel

**Lee Mac** · 2011-06-18, 01:28 PM

Here is another way to approach it:

Code:

(defun c:test ( / blk def ent enx lst rss )

  (while (setq def (tblnext "LAYER" (null def)))
    (if (= 1 (abs (cdr (assoc 62 def))))
      (setq lst (cons (cdr (assoc 2 def)) lst))
    )
  )

  (if
    (and
      (setq blk (car (entsel "\nSelect Block to Explode: ")))
      (eq "INSERT" (cdr (assoc 0 (entget blk))))
    )
    (progn
      (setq ent (entlast) rss (ssadd))
      (command "_.explode" blk)
      (while (setq ent (entnext ent))
        (setq enx (entget ent))
        (if
          (or (= 1 (cdr (assoc 62 enx)))
            (and
              (or
                (not (assoc 62 enx))
                (= 256 (cdr (assoc 62 enx)))
              )
              (member (cdr (assoc 8 enx)) lst)
            )
          )
          (ssadd ent rss)
        )
      )
      (sssetfirst nil rss)
    )
  )
  (princ)
)

**marko_ribar** · 2011-06-25, 08:05 PM

Originally Posted by Opie

Once this list is generated, use the layer names and CONStruct an associative list. You can quickly do this with the MAPCAR and LAMBDA functions.

Code:

(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1))

From there you need to add a filter for color and wrap the entire filter with an set of "XOR" filters

Code:

(setq filter (list (cons -4 "<XOR")(cons 62 1)(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1))(cons -4 "XOR>")))

Opie, I here don't understand something...

(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1))

This is behaving as one operand, in "XOR" filter condition, or is it as I suspect list of more operands with dotted pair (8 . "Layername")...

Here is written that "XOR" filter condition accepts only 2 operands and ssget makes selection if ether first operand filter condition is T, or either second operand condition is T...

If my suspection is correct, shouldn't condition be "OR", but not "XOR"...

M.R.

**marko_ribar** · 2011-06-26, 12:10 AM

I think Opie, you should try this code (with "OR" it works - selects all red objects either by object color or by red Layers with objects in them, but with "XOR" it doesn't select anything)...

Code:

(defun LayerListByColor (ColorNumber / LayerData LayerList)
  (setq LayerList '())
  (while (setq LayerData (tblnext "LAYER" (not LayerData)))
    (if	(= (cdr (assoc 62 LayerData)) ColorNumber)
      (setq
	LayerList (append LayerList (list (cdr (assoc 2 LayerData))))
      )
    )
  )
  (if (> (length LayerList) 0)
    LayerList
  )
)

(defun c:ssf (/ ss filter)
(setq filter (cons (cons -4 "<OR")(cons (cons 62 1)(mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1)))))
(setq filter (reverse filter))
(setq filter (cons (cons -4 "OR>") filter))
(setq filter (reverse filter))
(setq ss (ssget "X" filter))
(sssetfirst nil ss)
(princ)
)

M.R.

P.S. Try with XOR and see for yourself...

This variant of code has XOR filter condition and is in conjunction with AND condition - this will select all objects in red color only if 1 Layer with red color exist; if there are more than 1 Layer with red color it will select only objects that have red color property and don't belong to any of layers that are red...

Code:

(defun LayerListByColor (ColorNumber / LayerData LayerList)
  (setq LayerList '())
  (while (setq LayerData (tblnext "LAYER" (not LayerData)))
    (if	(= (cdr (assoc 62 LayerData)) ColorNumber)
      (setq
	LayerList (append LayerList (list (cdr (assoc 2 LayerData))))
      )
    )
  )
  (if (> (length LayerList) 0)
    LayerList
  )
)

(defun c:ssf (/ ss filter)
(setq filter (cons (cons -4 "<AND") (mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1)) ))
(setq filter (reverse filter))
(setq filter (cons (cons -4 "AND>") filter))
(setq filter (reverse filter))
(setq filter (cons (cons -4 "<XOR")(cons (cons 62 1) filter)))
(setq filter (reverse filter))
(setq filter (cons (cons -4 "XOR>") filter))
(setq filter (reverse filter))
(setq ss (ssget "X" filter))
(sssetfirst nil ss)
(princ)
)

M.R.

**marko_ribar** · 2011-06-27, 01:01 PM

Does anyone know why (read) function here reads only first part of string - first dotted pair

Code:

(defun LayerListByColor	(ColorNumber / LayerData LayerList)
  (setq LayerList '())
  (while (setq LayerData (tblnext "LAYER" (not LayerData)))
    (if	(= (cdr (assoc 62 LayerData)) ColorNumber)
      (setq
	LayerList (append LayerList (list (cdr (assoc 2 LayerData))))
      )
    )
  )
  (if (> (length LayerList) 0)
    LayerList
  )
)

(defun c:ssf (/ ss llbc llbcn llbcnlen filter)
(setq llbc (mapcar '(lambda (x) (cons 8 x)) (layerlistbycolor 1)))
(setq llbcn (vl-prin1-to-string llbc))
(setq llbcnlen (strlen llbcn))
(setq llbcn (substr llbcn 2 (- llbcnlen 2)))
(setq filter (list (cons -4 "<OR")(cons 62 1)(read llbcn)(cons -4 "OR>")))
(setq ss (ssget "X" filter))
(sssetfirst nil ss)
(princ)
)

M.R.
Thanks if replied...

Thread: Select entities by color of an exploded block

Thread Tools

Display

Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Re: Select entities by color of an exploded block

Similar Threads

Select entities off the screen

Can't select entities

How to automaticly select entities and create a block

Select entities without touching them

Changing block entities' color to bylayer

Posting Permissions