Lisp to swap value of layer name and layer description

[feargt]

Hi,
I am working in an international firm, we have a layer structure where the layer name is in the local language and the layer description is the layer name in english.

Does anyone know of a routine that would allow a user to swap these values?

ie.

Layer Name Layer Description
Schraffur Hatch

run code

result

Layer Name Layer Description
Hatch Schraffur

I know the layer translator exists but this would probably suit our needs better.

Thanks.

[marko_ribar]

Only little problem was layer "0", so I skipped that...

(defun c:swaplayn-layd ( / adoc laycoll layn layd)
(vl-load-com)
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
(setq laycoll (vla-get-layers adoc))
(vlax-for lay laycoll
 (setq layn (vla-get-Name lay))
 (setq layd (vla-get-Description lay))
 (if (/= layn "0") 
  (progn
  (vla-put-Name lay layd)
  (vla-put-Description lay layn)
  )
 )
)
(princ)
)

M.R.

[feargt]

Hi Mark,

Thanks for the quick response

Civil 3d 2010 is returning the following on the command line after running the command.

; Fehler: Automatisierungsfehler Ungültige Eingabe

Translation is

;Error: Automation error Invalid input

any ideas?

I thought it might be due to the defpoints layer so I added that to the code by copying what you had for layer 0 and replacing 0 with defpoints but the command returns the same as above


I saw that you updated the code but unfortunately it is still returning the same error message

[Lee Mac]

This isn't an ideal way to approach it (I call it 'lazy-man's error trapping') but it should swap the name/description for the layer if possible, else it will skip the layer.

(defun c:test nil (vl-load-com)
  (vlax-for layer (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
    (vl-catch-all-apply
      (function
        (lambda ( / ln ld )
          (setq ln (vla-get-name layer)
                ld (vla-get-description layer)
          )
          (vla-put-description layer ln)
          (vla-put-name layer ld)
        )
      )
    )
  )
  (princ)
)

[marko_ribar]

try with

(if (or (/= layn "0") (/= layn "Defpoints"))

but I think it won't help... Error is due to Civil 3d you are using... In Acad 2011 it works...
M.R.

Lee, seeing your code looks fine to me, but haven't you forgot :

(vla-put-name layer ld)

[Lee Mac]

try with

(if (or (/= layn "0") (/= layn "Defpoints"))

but I think it won't help... Error is due to Civil 3d you are using... In Acad 2011 it works...
M.R.

My guess is there are also invalid characters in the description string.

[alanjt]

This isn't an ideal way to approach it (I call it 'lazy-man's error trapping') but it should swap the name/description for the layer if possible, else it will skip the layer.

Probably not ideal either, but removes the usage of vl-catch* and checks validity of a swap...

(defun c:test (/ desc)
  (vl-load-com)
  (vlax-for layer (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
    (if (and (snvalid (setq desc (vla-get-description layer)))
             (not (tblobjname "LAYER" desc))
        )
      (progn (vla-put-description layer (vla-get-name layer))
             (vla-put-name layer desc)
      )
    )
  )
  (princ)
)

I'd probably take your route since it's most like the faster one, but I don't know. I do know that tblobjname has proven to be faster than tblsearch.

[marko_ribar]

Little mistake Alan...

(defun c:test (/ desc)
  (vl-load-com)
  (vlax-for layer (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
    (if (and (snvalid (setq desc (vla-get-description layer)))
             (not (tblobjname "LAYER" desc))
        )
      (progn (vla-put-description layer (vla-get-name layer))
             (vla-put-name layer desc)
      )
    )
  )
  (princ)
)

M.R.

[alanjt]

Little mistake Alan...

(defun c:test (/ desc)
  (vl-load-com)
  (vlax-for layer (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
    (if (and (snvalid (setq desc (vla-get-description layer)))
             (not (tblobjname "LAYER" desc))
        )
      (progn (vla-put-description layer (vla-get-name layer))
             (vla-put-name layer desc)
      )
    )
  )
  (princ)
)

M.R.

Oops. Thanky, thanky.

[Lee Mac]

Lee, seeing your code looks fine to me, but haven't you forgot :

(vla-put-name layer ld)

Thanks Marko - corrected above

I'd probably take your route since it's most like the faster one, but I don't know. I do know that tblobjname has proven to be faster than tblsearch.

Also, entmod'ing the tblobjname entity will return nil if invalid and won't throw the error. But then modifying the Description could be annoying since its deep in the xData