input a number then put in dimension text

[vobavinh325690]

hi everyone,
I want to find a program for my work faster
So I google and come up with this but it did not work
please any one give me some hint

(Defun c:balls ()
(setq a (getint "\nEnter the number of balls:"))
(setq newdim (entsel "\n Select Dimension to annotation:"))
(setq newdimvalue "a @270 CTS= <>")
(command "dimedit" "n" newdimvalue newdim "")
(princ)
)

thanks very much

[Lee Mac]

You will need to use strcat to concatenate the value of the variable 'a' converted to a string, with the rest of the string.

i.e.

(strcat (itoa a) " @270 CTS= <>")

[Lee Mac]

This might be another way to approach it, rather than using the dimedit command:

(defun c:balls ( / a d )

  (initget 6)
  (setq a (itoa (cond ((getint "\nEnter the Number of Balls <1>: ")) ( 1 ))))

  (while
    (progn (setvar 'ERRNO 0) (setq d (car (entsel "\nSelect Dimension: ")))
      (cond
        ( (= 7 (getvar 'ERRNO))
          (princ "\n--> Missed, Try Again.")
        )
        ( (eq 'ENAME (type d))
          (if (wcmatch (cdr (assoc 0 (setq d (entget d)))) "*DIMENSION")
            (entmod (subst (cons 1 (strcat a " @270 CTS= <>")) (assoc 1 d) d))
            (princ "\n--> Invalid Object Selected.")
          )
        )
      )
    )
  )
  (princ)
)

[vobavinh325690]

thanks you very much