Layer fade not working in a "LockAll" command

[JaCAD]

Hey all,

I'm working on a simple function to lock, unlock, thaw, etc, all layers in the drawing.
I've got it working, but I have a question about the fade setting.
Normally, when you use the "LockLayer" command, or lock a layer through the layer dialog, the layer fades, and I like this effect. However, when I run the following command, the layers get locked, but don't fade. Does anyone know how to fix this so the layers still fade when I run this command?

Thanks!

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun C:LockAll ( / )

  (DoToAllLayers 'Lock :vlax-true)
  (princ)
  );end defun

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun DoToAllLayers (Prop Val / Layers Lim Cnt LyrObj)

  (setq Layers (vla-get-layers #AcDoc#)
	Lim (vla-get-count Layers)
	Cnt -1
	)

  (while (< (setq Cnt (1+ Cnt)) Lim)
    (setq LyrObj (vla-item Layers Cnt))

    (vlax-put-property LyrObj Prop Val)
    );end while

  );end defun

[BlackBox]

Presuming you have the correct lock fade setting, you need to regenerate the viewports.

Separately, why not simply use:

(defun c:LOCKALL ()
  (command "._-layer" "lock" "*" "")
  (princ))

[BlackBox]

Also, consider this example:

(defun DoToAllLayers  (Doc Prop Val / )
  (vlax-for lay  (vla-get-layers Doc)
    (if (vlax-property-available-p lay Prop)
      (vl-catch-all-apply 'vlax-put (list lay Prop Val)))))

Instead of passing Visual LISP arguments to your sub-function, then extracting the layer count from the layers collection, simply iterate through the collection and make all applicable changes.

I've included the Document Object as an argument, as in this case with SDI = 0, you can send this sub-function the Document Object for any open document in the Document's Collection and yield the desired result. This could also be utilized within an ObjectDBX routine as well.

Just a thought.

[Tharwat]

All within one shut .

(setq lays (vla-get-layers
             (vla-get-activedocument (vlax-get-acad-object))
           )
)
(vlax-for x lays
  (if (eq (vla-get-lock (setq l (vla-item lays (vla-get-name x))))
          :vlax-false
      )
    (vla-put-lock l :vlax-true)
  )
)

Tharwat

[Lee Mac]

@ Tharwat,

The highlighted section is unnecessary, since you already have the Layer Object bound to symbol 'x':

(setq lays (vla-get-layers
             (vla-get-activedocument (vlax-get-acad-object))
           )
)
(vlax-for x lays
  (if (eq (vla-get-lock (setq l (vla-item lays (vla-get-name x))))
          :vlax-false
      )
    (vla-put-lock l :vlax-true)
  )
)

It could be better written as:

(setq lays (vla-get-layers
             (vla-get-activedocument (vlax-get-acad-object))
           )
)
(vlax-for x lays
  (if (eq (vla-get-lock x) :vlax-false)
    (vla-put-lock l :vlax-true)
  )
)

However, I would be inclined to follow the route suggested by Renderman, but note that a Regen may be required to show the fade:

(defun c:test ( / _ApplyCollectionProperty acdoc )

  (defun _ApplyCollectionProperty ( collection property value )
    (vlax-for item collection
      (vl-catch-all-apply 'vlax-put-property (list item property value))
    )
  )

  (setq acdoc (vla-get-activedocument (vlax-get-acad-object)))
  (_ApplyCollectionProperty (vla-get-layers acdoc) 'lock :vlax-true)
  (vla-regen acdoc acallviewports)
  (princ)
)

[BlackBox]

Nice one, Lee!

*IF* the OP is going to make this into a production tool (not a learning exercise), I'd suggest that vla-startUndoMark, and vla-endUndoMark be added for completeness.

Cheers!

[Tharwat]

@ Tharwat,

The highlighted section is unnecessary, since you already have the Layer Object bound to symbol 'x':

It could be better written as:

(setq lays (vla-get-layers
             (vla-get-activedocument (vlax-get-acad-object))
           )
)
(vlax-for x lays
  (if (eq (vla-get-lock x) :vlax-false)
    (vla-put-lock l :vlax-true)
  )
)

I tried that before but it did not work at all on Cad 2010 it's been giving me a message that the vla-object is nil ,
but it worked well on Cad 2009 in the office,


I wonder how !!

Thank you .

[marko_ribar]

It's because of this "typo" mistake :

(setq lays (vla-get-layers
             (vla-get-activedocument (vlax-get-acad-object))
           )
)
(vlax-for x lays
  (if (eq (vla-get-lock x) :vlax-false)
    (vla-put-lock x :vlax-true)
  )
)

M.R.

[Lee Mac]

Good catch Marko, I modified things a little too hastily, but hopefully Tharwat gets the idea

[Tharwat]

but hopefully Tharwat gets the idea

Certainly I did.