add and total lines/pline

[CADiver]

does anyone know the lisp that allows you to select several lines or polylines and adds the total linear length

[BlackBox]

Welcome to AUGI!

Here's one I wrote a while ago:

(defun c:LENT () (c:LengthTotal))
(defun c:LengthTotal ( / ss)
  (princ "\rLENGTH: TOTAL ")
  (vl-load-com)
  (if (setq ss (ssget "_:L" '((0 . "ARC,LINE,*POLYLINE"))))
    ((lambda (i / o)
	 (vlax-for x (setq ss (vla-get-activeselectionset
					    (vla-get-activedocument
						 (vlax-get-acad-object))))
	   (cond ((vl-position (setq o (vla-get-objectname x)) '("AcDbLine" "AcDbPolyLine"))
			(setq i (+ i (vla-get-length x))))
		    ((= "AcDbArc" o)
			(setq i (+ i (vla-get-arclength x))))))
	  (prompt (strcat "\nTotal Length  >>  " (rtos i 2 2)))
	 (vla-delete ss))
	 0)
    (prompt "\n** Nothing selected ** "))
  (princ))

Edit - This will count the total length for Arcs, Lines, and *Polylines.

HTH

[CADiver]

Thanks! I've been out of the design for a few years but now I'm back in it. New Year = New Goals...

Thanks for the lisp, I'll try it out.

[BlackBox]

You're welcome.

[alanjt]

@RM:

(vlax-curve-getDistAtParam <ename> (vlax-curve-getEndParam <ename>))

Also, there's no reason to filter out objects on locked layers.

[BlackBox]

(vlax-curve-getDistAtParam <ename> (vlax-curve-getEndParam <ename>))

True. *Tips hat*

Also, there's no reason to filter out objects on locked layers.

This was done for our workflow - we'd isolate certain layers, the select.

[alanjt]

True. *Tips hat*



This was done for our workflow - we'd isolate certain layers, the select.

Does that mean ssget will still select objects not on a set of isolated layers when lockfade is used or are you talking about something else?

I don't use lockfade, so I've never tested.

[BlackBox]

Does that mean ssget will still select objects not on a set of isolated layers when lockfade is used or are you talking about something else?

I don't use lockfade, so I've never tested.

Correct - I use LAYLOCKFADECTL = 50, and use :L to mitigate displayed (locked) layers, regardless of fade %.

[alanjt]

Correct - I use LAYLOCKFADECTL = 50, and use :L to mitigate displayed (locked) layers, regardless of fade %.

Wild. Never thought about that but I've never been a fan of the lockfade option.

[BlackBox]

Wild. Never thought about that but I've never been a fan of the lockfade option.

Mostly used as a design tool when laying out project features (i.e., roadway, ponds, medians, swales, etc.), as you can still snap to entities on displayed (locked) layers, without worry of mistakenly deleting, moving, modifying them, etc.