Save structured data in an entity

[jason907238]

that sample came from http://through-the-interface.typepad...circles_1.html

What types of ojbects can a dictionalry hold? I know of other Dictionaries or xRecords.

The ResultBuffer is held in xRecords.Data.

[Peter.Elliott]

You can also save DataTable objects in dictionaries:
NamedObjsDict.SetAt(String Name, Autodesk.AutoCAD.DatabaseServices.DataTable)

[fixo]

Welcome on board!
Good point
Here is some code how to manage it
http://forums.augi.com/showpost.php?...52&postcount=1

[bweir]

A trick I also use is to use XML serialization to store custom data in an Xrecord. In short I have a custom class that holds data, I serialize it into a memory stream, turn it into a compressed/encrypted string of bytes and store them in the Xrecord. Only down side is if I have pointers to ObjectIds, I have to add addtional ResultBuffers to account for them and handle them when decoding the data.

[dgorsman]

A trick I also use is to use XML serialization to store custom data in an Xrecord. In short I have a custom class that holds data, I serialize it into a memory stream, turn it into a compressed/encrypted string of bytes and store them in the Xrecord. Only down side is if I have pointers to ObjectIds, I have to add addtional ResultBuffers to account for them and handle them when decoding the data.

Slick. Could even leave it as an XML fragment stored as a string provided its not too long.

[jimmytadams]

I was trying to do this same thing based on a document from Autodesk University 2008 by Jeffery Geer (A Pattern for Storing Structured Data in AutoCAD Entities CP401-2).

It got me pretty far down the road:

I have polyline that graphically represents a pipe. Obviously, the polyline can not contain data for a pipe: size, material, insulationtype, insulationthickness, schedule, etc. So, I have created a custom object with all of the appropriate properties, methods, events, etc that I need for it to behave as a pipe. My custom object has a reference to the actual polyline with a Handle property stored as a long(since AutoCAD objects can not be serialized).

My object is marked serializable. I serialize it to binary and attach the binary in 127 byte chunks to the xRecord of the polyline object. My code works AWESOME!!! Thanks Jeffery.

However, as soon as I attach this binary xrecord, I get the following message when I try to save the drawing:

"One or more objects in this drawing cannot be saved to the specified format. The operation was not completed and no file was created”

I assume that since this was an AU course that some one has tried this at some point and knows how to bypass this error, but I can not find anyone willing to admit it. Does anyone here want to stake a claim to my praise?

[bweir]

I've had similar issues, it is usually traced back to some transaction or other object not being disposed of correctly. Look through your code closely (in VB.NET use the Using... End Using syntax whenever possible) and be sure you make use of the proper transaction type. I've caught my self using the OpenCloseTransaction a few times where I should not be. I blame it on intellisence

[jason907238]

I have tried disposing all objects, I have tried to have "using" everywhere that it would accept it. I even tried the XmlSerializer. I still can't save once I have placed something in the dictionaries.

Any suggestiosn would be appreciated.

        <System.Xml.Serialization.XmlRootAttribute("xValue", Namespace:="http://www.cpandl.com", IsNullable:=False)> _
Public Class xValue
       Public Name As String
       Public Value As String
End Class
Public Shared Sub Write(_DictName As String, _SubDictName As String, _XRecordName As String, _WriteValue As String)
            Dim _xValue As New xValue
            _xValue.Name = _XRecordName
            _xValue.Value = _WriteValue
            Using stream As New MemoryStream()
                Dim serializer As New System.Xml.Serialization.XmlSerializer(GetType(xValue))
                serializer.Serialize(stream, _xValue)
                stream.Position = 0
                Using reader As TextReader = New StreamReader(stream)
                    Dim xmlString As String = reader.ReadToEnd()
                    Dim data As New ResultBuffer()

                    data.Add(New TypedValue(CInt(DxfCode.Text), _xValue.[GetType]().FullName))
                    While xmlString.Length > 0
                        Dim buffer As String = ""
                        If xmlString.Length >= 1024 Then
                            buffer = xmlString.Substring(0, 1024)
                            xmlString = xmlString.Substring(1024)
                        Else
                            buffer = xmlString
                            xmlString = ""
                        End If
                        data.Add(New TypedValue(CInt(DxfCode.Text), buffer))
                    End While

                    '' Get the current document and database
                    Dim acDoc As Document = Application.DocumentManager.MdiActiveDocument
                    Dim acCurDb As Database = acDoc.Database

                    '' Start a transaction
                    Using doclock As DocumentLock = acDoc.LockDocument
                        Using acTrans As Transaction = acCurDb.TransactionManager.StartTransaction()
                            Try
                                Using mDict As DBDictionary = GetDict(acCurDb, acTrans, _DictName)
                                    If mDict Is Nothing Then
                                        MsgBox("Dictionary does not exist")
                                    Else
                                        If Not mDict.Contains(_SubDictName) Then mDict.SetAt(_SubDictName, New DBDictionary)

                                        Using SubDict As DBDictionary = CType(acTrans.GetObject(mDict.GetAt(_SubDictName), OpenMode.ForRead), DBDictionary)
                                            If Not SubDict.Contains(_XRecordName) Then SubDict.SetAt(_XRecordName, New Xrecord)

                                            Using xRec As Xrecord = CType(acTrans.GetObject(SubDict.GetAt(_XRecordName), OpenMode.ForWrite), Xrecord)
                                                '                        xRec.Data = GetBufferFromList(itm, _XRecordName)
                                                'Dim Buff As New ResultBuffer
                                                'For Each mSt As String In _WriteValues
                                                '    Buff.Add(New TypedValue(DxfCode.Text, mSt))
                                                'Next
                                                xRec.Data = data
                                                SubDict.SetAt(_XRecordName, xRec)
                                                acTrans.Commit()
                                            End Using
                                        End Using
                                    End If
                                End Using
                            Catch ex As System.Exception
                                acDoc.Editor.WriteMessage(ex.Message & vbLf & ex.StackTrace)
                            End Try
                        End Using
                    End Using
                End Using
            End Using
        End Sub


        Public Shared Function Read(_DictName As String, _SubDictName As String, _XRecordName As String) As String
            Dim ReadVal As String
            Dim serializer As New System.Xml.Serialization.XmlSerializer(GetType(xValue))

            '' Get the current document and database
            Dim acDoc As Document = Application.DocumentManager.MdiActiveDocument
            Dim acCurDb As Database = acDoc.Database

            '' Start a transaction
            Using doclock As DocumentLock = acDoc.LockDocument
                Using acTrans As Transaction = acCurDb.TransactionManager.StartTransaction()
                    Try
                        If DictExists(acCurDb, acTrans, _DictName) Then
                            Using mDict As DBDictionary = GetDict(acCurDb, acTrans, _DictName)
                                If mDict.Contains(_SubDictName) Then
                                    Using SubDict As DBDictionary = CType(acTrans.GetObject(mDict.GetAt(_SubDictName), OpenMode.ForRead), DBDictionary)
                                        If SubDict.Contains(_XRecordName) Then
                                            Dim xRec As Xrecord = CType(acTrans.GetObject(SubDict.GetAt(_XRecordName), OpenMode.ForWrite), Xrecord)
                                            '                                   Dim First As Boolean = True
                                            'For Each tval As TypedValue In xRec.Data
                                            '    If ReadVal Is Nothing Then ReDim ReadVal(0 To 0) Else ReDim Preserve ReadVal(0 To ReadVal.Count)
                                            '    ReadVal(UBound(ReadVal)) = tval.Value
                                            '    '                                        First = False
                                            'Next
                                            Using rb As ResultBuffer = xRec.Data
                                                If rb IsNot Nothing Then
                                                    Using stream As New MemoryStream()
                                                        Dim tvs As TypedValue() = rb.AsArray()
                                                        If tvs IsNot Nothing Then
                                                            If tvs(0).TypeCode = CShort(DxfCode.Text) Then
                                                                Dim xmlString As String = ""
                                                                Dim writer As TextWriter = New StreamWriter(stream)
                                                                For i As Integer = 1 To tvs.Length - 1
                                                                    If tvs(i).TypeCode = CShort(DxfCode.Text) Then
                                                                        xmlString = DirectCast(tvs(i).Value, String)
                                                                        writer.Write(xmlString)
                                                                    End If
                                                                Next
                                                                writer.Flush()
                                                                stream.Position = 0
                                                                ReadVal = TryCast(serializer.Deserialize(stream), xValue).Value
                                                            End If
                                                        End If
                                                    End Using
                                                End If
                                            End Using
                                        End If
                                    End Using
                                End If
                            End Using
                        End If
                    Catch ex As System.Exception
                        acDoc.Editor.WriteMessage(ex.Message & vbLf & ex.StackTrace)
                    End Try
                End Using
            End Using

            Return ReadVal
        End Function

[Jeff H]

You do not need the using statement for those objects you open with a transaction.
You do need to commit the transaction.
Add a acTrans.Commit() before its End Using and see if that works.

[fixo]

I've tested your code after changes as Jeff mentioned above,
looks like it's working with no problems on my A2010,
here is a complete code I've used:

   

Public Class XdataSerialize
    <System.Xml.Serialization.XmlRootAttribute("xValue", Namespace:="http://www.cpandl.com", IsNullable:=False)> _
    Public Class xValue
        Public Name As String
        Public Value As String
    End Class
    Public Shared Function DictExists(db As Database, tr As Transaction, ByVal dictname As String) As Boolean
        Dim isexist As Boolean = False

        Using (tr)
            Dim nod As DBDictionary = TryCast(tr.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForRead), DBDictionary)
            If nod Is Nothing Then
                isexist = False
            End If
            Dim id As ObjectId = ObjectId.Null
            Try
                id = nod.GetAt(dictname)
                Dim dict As DBDictionary = TryCast(tr.GetObject(id, OpenMode.ForRead), DBDictionary)
                If dict Is Nothing Then
                    isexist = False
                Else
                    isexist = True
                End If
            Catch ex As Exception
                isexist = False
            End Try
        End Using
        Return isexist
    End Function
    Public Shared Function GetDict(db As Database, tr As Transaction, ByVal dictname As String) As DBDictionary
        Dim dict As New DBDictionary

        Using (tr)
            Dim nod As DBDictionary = TryCast(tr.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForRead), DBDictionary)
            If nod Is Nothing Then
                Return Nothing
            End If
            Dim id As ObjectId = ObjectId.Null
            Try
                id = nod.GetAt(dictname)
                dict = TryCast(tr.GetObject(id, OpenMode.ForRead), DBDictionary)
                If dict Is Nothing Then
                    Return Nothing
                Else
                    Return dict
                End If
            Catch ex As Exception
                Return Nothing
            End Try
        End Using

    End Function

    Public Shared Sub Write(_DictName As String, _SubDictName As String, _XRecordName As String, _WriteValue As String)
        Dim xmlString As String
        Dim _xValue As New xValue
        _xValue.Name = _XRecordName
        _xValue.Value = _WriteValue
        Using stream As New MemoryStream()
            Dim serializer As New System.Xml.Serialization.XmlSerializer(GetType(xValue))
            serializer.Serialize(stream, _xValue)
            stream.Position = 0
            Using reader As TextReader = New StreamReader(stream)
                xmlString = reader.ReadToEnd()
            End Using
            Dim data As New ResultBuffer()

            data.Add(New TypedValue(CInt(DxfCode.Text), _xValue.[GetType]().FullName))
            While xmlString.Length > 0
                Dim buffer As String = ""
                If xmlString.Length >= 1024 Then
                    buffer = xmlString.Substring(0, 1024)
                    xmlString = xmlString.Substring(1024)
                Else
                    buffer = xmlString
                    xmlString = ""
                End If
                data.Add(New TypedValue(CInt(DxfCode.Text), buffer))
            End While

            '' Get the current document and database
            Dim acDoc As Document = Application.DocumentManager.MdiActiveDocument
            Dim acCurDb As Database = acDoc.Database

            '' Start a transaction
            Using doclock As DocumentLock = acDoc.LockDocument
                Using acTrans As Transaction = acCurDb.TransactionManager.StartTransaction()
                    Try
                        Dim mDict As DBDictionary = GetDict(acCurDb, acTrans, _DictName)
                        If mDict Is Nothing Then
                            MsgBox("Dictionary does not exist")
                        Else
                            If Not mDict.Contains(_SubDictName) Then mDict.SetAt(_SubDictName, New DBDictionary)

                            Dim SubDict As DBDictionary = DirectCast(acTrans.GetObject(mDict.GetAt(_SubDictName), OpenMode.ForRead), DBDictionary)
                            If Not SubDict.Contains(_XRecordName) Then SubDict.SetAt(_XRecordName, New Xrecord)

                            Dim xRec As Xrecord = DirectCast(acTrans.GetObject(SubDict.GetAt(_XRecordName), OpenMode.ForWrite), Xrecord)
                            '                        xRec.Data = GetBufferFromList(itm, _XRecordName)
                            'Dim Buff As New ResultBuffer
                            'For Each mSt As String In _WriteValues
                            '    Buff.Add(New TypedValue(DxfCode.Text, mSt))
                            'Next
                            xRec.Data = data
                            SubDict.SetAt(_XRecordName, xRec)
                            acTrans.Commit()
                            
                        End If

                    Catch ex As System.Exception
                        acDoc.Editor.WriteMessage(ex.Message & vbLf & ex.StackTrace)
                    End Try
                End Using
            End Using

        End Using
    End Sub


    Public Shared Function Read(_DictName As String, _SubDictName As String, _XRecordName As String) As String
        Dim ReadVal As String = String.Empty
        Dim serializer As New System.Xml.Serialization.XmlSerializer(GetType(xValue))

        '' Get the current document and database
        Dim acDoc As Document = Application.DocumentManager.MdiActiveDocument
        Dim acCurDb As Database = acDoc.Database

        '' Start a transaction
        Using doclock As DocumentLock = acDoc.LockDocument
            Using acTrans As Transaction = acCurDb.TransactionManager.StartTransaction()
                Try
                    If DictExists(acCurDb, acTrans, _DictName) Then
                        Dim mDict As DBDictionary = GetDict(acCurDb, acTrans, _DictName)
                        If mDict.Contains(_SubDictName) Then
                            Dim SubDict As DBDictionary = CType(acTrans.GetObject(mDict.GetAt(_SubDictName), OpenMode.ForRead), DBDictionary)
                            If SubDict.Contains(_XRecordName) Then
                                Dim xRec As Xrecord = CType(acTrans.GetObject(SubDict.GetAt(_XRecordName), OpenMode.ForWrite), Xrecord)
                                '                                   Dim First As Boolean = True
                                'For Each tval As TypedValue In xRec.Data
                                '    If ReadVal Is Nothing Then ReDim ReadVal(0 To 0) Else ReDim Preserve ReadVal(0 To ReadVal.Count)
                                '    ReadVal(UBound(ReadVal)) = tval.Value
                                '    '                                        First = False
                                'Next
                                Dim rb As ResultBuffer = xRec.Data
                                If rb IsNot Nothing Then
                                    Using stream As New MemoryStream()
                                        Dim tvs As TypedValue() = rb.AsArray()
                                        If tvs IsNot Nothing Then
                                            If tvs(0).TypeCode = CShort(DxfCode.Text) Then
                                                Dim xmlString As String = ""
                                                Dim writer As TextWriter = New StreamWriter(stream)
                                                For i As Integer = 1 To tvs.Length - 1
                                                    If tvs(i).TypeCode = CShort(DxfCode.Text) Then
                                                        xmlString = DirectCast(tvs(i).Value, String)
                                                        writer.Write(xmlString)
                                                    End If
                                                Next
                                                writer.Flush()
                                                stream.Position = 0
                                                ReadVal = TryCast(serializer.Deserialize(stream), xValue).Value
                                            End If
                                        End If
                                    End Using
                                End If

                            End If

                        End If

                    End If
                Catch ex As System.Exception
                    acDoc.Editor.WriteMessage(ex.Message & vbLf & ex.StackTrace)
                End Try
            End Using
        End Using

        Return ReadVal
    End Function

    <CommandMethod("XXD")> _
    Public Sub Getdictionary()
        Dim doc As Document = Application.DocumentManager.MdiActiveDocument
        Dim ed As Editor = doc.Editor
        Dim db As Database = doc.Database
        Using tr As Transaction = db.TransactionManager.StartTransaction()
            Dim dn As String = "BM-LinkDictionary" ''<--- change dictionary name to your suit
            Dim dict As DBDictionary = GetDict(db, tr, dn)
            Dim msg As String = ""
            For Each de As DictionaryEntry In dict
                msg = msg + de.Key.ToString + vbTab + de.Value.ToString + vbLf
            Next
            MsgBox(msg)
        End Using
    End Sub
End Class

~'J'~