Contour elevation labelling..........help

**sanrajbhar677632** · 2012-02-10, 10:12 AM

hello all,

i wrote below piece of code for labelling elevation to contour(Polyline). it works but it labels at end of contour. what i want is to label in middle of contour with proper aligning text label . can anybody modified it for me..?

Code:

 
 
(defun c:qq()
(setq ss (ssget'((0 . "LWPOLYLINE"))))
(setq sslngth (sslength ss))
(Setq idx 0)
(repeat sslngth
  (setq ename (ssname ss (setq sslngth (1- sslngth))))
   (setq edata (entget ename))
   (setq xy (cdr (Assoc 38 edata)))
   (setq xy1(cdr (Assoc 10 edata)))
  (setq xx(rtos xy 2 0))
  (command "text" xy1 10 30 xx "")
)
)

sample dwg attached ..........!

**Bruno.Valsecchi** · 2012-02-10, 10:55 AM

Hello,

You can use also the dynamic fields !

Code:

(vl-load-com)
(defun c:Label_Side_Elevation ( / js htx AcDoc Space nw_style n obj ename pr pt deriv rtx nw_obj)
	(princ "\nSelect polylines: ")
	(setq js
		(ssget
			(list
				'(0 . "LWPOLYLINE")
				(cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
				(cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
			)
		)
	)
	(cond
		(js
			(initget 6)
			(setq htx (getdist (getvar "VIEWCTR") (strcat "\nSpecify text height <" (rtos (getvar "TEXTSIZE")) ">: ")))
			(if htx (setvar "TEXTSIZE" htx))
			(setq
				AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
				Space
				(if (= 1 (getvar "CVPORT"))
					(vla-get-PaperSpace AcDoc)
					(vla-get-ModelSpace AcDoc)
				)
			)
			(cond
				((null (tblsearch "LAYER" "Label Elevation"))
					(vlax-put (vla-add (vla-get-layers AcDoc) "Label Elevation") 'color 96)
				)
			)
			(cond
				((null (tblsearch "STYLE" "Romand-Label"))
					(setq nw_style (vla-add (vla-get-textstyles AcDoc) "Romand-Label"))
					(mapcar
						'(lambda (pr val)
							(vlax-put nw_style pr val)
						)
						(list 'FontFile 'Height 'ObliqueAngle 'Width 'TextGenerationFlag)
						(list "romand.shx" 0.0 (/ (* 15.0 pi) 180) 1.0 0.0)
					)
				)
			)
			(repeat (setq n (sslength js))
				(setq
					obj (ssname js (setq n (1- n)))
					ename (vlax-ename->vla-object obj)
					pt (vlax-curve-GetpointAtParam ename (setq pr (* 0.5 (vlax-curve-getEndParam ename))))
					deriv (vlax-curve-getFirstDeriv ename pr)
					rtx (- (atan (cadr deriv) (car deriv)) (angle '(0 0 0) (getvar "UCSXDIR")))
				)
				(if (or (> rtx (* pi 0.5)) (< rtx (- (* pi 0.5)))) (setq rtx (+ rtx pi)))
				(setq nw_obj
					(vla-addMtext Space
						(vlax-3d-point (setq pt (polar pt (+ rtx (* pi 0.5)) (getvar "TEXTSIZE"))))
						0.0
						(strcat
							"%<\\AcObjProp Object(%<\\_ObjId "
							(itoa (vla-get-ObjectID (vlax-ename->vla-object obj)))
							">%).Elevation \\f \"%lu2%pr0\">%"
						)
					)
				)
				(mapcar
					'(lambda (pr val)
						(vlax-put nw_obj pr val)
					)
					(list 'AttachmentPoint 'Height 'DrawingDirection 'InsertionPoint 'StyleName 'Layer 'Rotation)
					(list 5 (getvar "TEXTSIZE") 5 pt "Romand-Label" "Label Elevation" rtx)
				)
			)
		)
	)
	(prin1)
)

**sanrajbhar677632** · 2012-02-10, 11:07 AM

ya, it works great ! but it highlights that value in closed filled color. that what i dont want..only value with Arial font.

and one more think if you know anyother alternatives to do the same. let me know plzz..

Originally Posted by Bruno.Valsecchi

Hello,

You can use also the dynamic fields !

Code:

(vl-load-com)
(defun c:Label_Side_Elevation ( / js htx AcDoc Space nw_style n obj ename pr pt deriv rtx nw_obj)
    (princ "\nSelect polylines: ")
    (setq js
        (ssget
            (list
                '(0 . "LWPOLYLINE")
                (cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
                (cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
            )
        )
    )
    (cond
        (js
            (initget 6)
            (setq htx (getdist (getvar "VIEWCTR") (strcat "\nSpecify text height <" (rtos (getvar "TEXTSIZE")) ">: ")))
            (if htx (setvar "TEXTSIZE" htx))
            (setq
                AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
                Space
                (if (= 1 (getvar "CVPORT"))
                    (vla-get-PaperSpace AcDoc)
                    (vla-get-ModelSpace AcDoc)
                )
            )
            (cond
                ((null (tblsearch "LAYER" "Label Elevation"))
                    (vlax-put (vla-add (vla-get-layers AcDoc) "Label Elevation") 'color 96)
                )
            )
            (cond
                ((null (tblsearch "STYLE" "Romand-Label"))
                    (setq nw_style (vla-add (vla-get-textstyles AcDoc) "Romand-Label"))
                    (mapcar
                        '(lambda (pr val)
                            (vlax-put nw_style pr val)
                        )
                        (list 'FontFile 'Height 'ObliqueAngle 'Width 'TextGenerationFlag)
                        (list "romand.shx" 0.0 (/ (* 15.0 pi) 180) 1.0 0.0)
                    )
                )
            )
            (repeat (setq n (sslength js))
                (setq
                    obj (ssname js (setq n (1- n)))
                    ename (vlax-ename->vla-object obj)
                    pt (vlax-curve-GetpointAtParam ename (setq pr (* 0.5 (vlax-curve-getEndParam ename))))
                    deriv (vlax-curve-getFirstDeriv ename pr)
                    rtx (- (atan (cadr deriv) (car deriv)) (angle '(0 0 0) (getvar "UCSXDIR")))
                )
                (if (or (> rtx (* pi 0.5)) (< rtx (- (* pi 0.5)))) (setq rtx (+ rtx pi)))
                (setq nw_obj
                    (vla-addMtext Space
                        (vlax-3d-point (setq pt (polar pt (+ rtx (* pi 0.5)) (getvar "TEXTSIZE"))))
                        0.0
                        (strcat
                            "%<\\AcObjProp Object(%<\\_ObjId "
                            (itoa (vla-get-ObjectID (vlax-ename->vla-object obj)))
                            ">%).Elevation \\f \"%lu2%pr0\">%"
                        )
                    )
                )
                (mapcar
                    '(lambda (pr val)
                        (vlax-put nw_obj pr val)
                    )
                    (list 'AttachmentPoint 'Height 'DrawingDirection 'InsertionPoint 'StyleName 'Layer 'Rotation)
                    (list 5 (getvar "TEXTSIZE") 5 pt "Romand-Label" "Label Elevation" rtx)
                )
            )
        )
    )
    (prin1)
)

**Tom Beauford** · 2012-02-10, 12:14 PM

Try ContourAnnotate.lsp. It works on your attached drawing or any Map data or polylines with elevations. It places the text right-side up even in twisted views. It uses the current Text Style and Size and places the text on the same layer as the contour so it turns off with the layer. Give it a try.

**ccowgill** · 2012-02-10, 01:26 PM

Originally Posted by sanrajbhar677632

ya, it works great ! but it highlights that value in closed filled color.

what if you set FIELDDISPLAY to 0?

**Bruno.Valsecchi** · 2012-02-10, 01:51 PM

only value with Arial font

Two way possible, define a new style with arial or force in Mtext the style with the good font

highlights that value in closed filled color

Same answer that ccowgill FIELDDISPLAY

With font forced in Mtext

Code:

(vl-load-com)
(defun c:Label_Side_Elevation ( / js htx AcDoc Space n obj ename pr pt deriv rtx nw_obj)
  (princ "\nSelect polylines: ")
  (setq js
    (ssget
      (list
        '(0 . "LWPOLYLINE")
        (cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
        (cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
      )
    )
  )
  (cond
    (js
      (initget 6)
      (setq htx (getdist (getvar "VIEWCTR") (strcat "\nSpecify text height <" (rtos (getvar "TEXTSIZE")) ">: ")))
      (if htx (setvar "TEXTSIZE" htx))
      (setq
        AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
        Space
        (if (= 1 (getvar "CVPORT"))
          (vla-get-PaperSpace AcDoc)
          (vla-get-ModelSpace AcDoc)
        )
      )
      (cond
        ((null (tblsearch "LAYER" "Label Elevation"))
          (vlax-put (vla-add (vla-get-layers AcDoc) "Label Elevation") 'color 96)
        )
      )
      (repeat (setq n (sslength js))
        (setq
          obj (ssname js (setq n (1- n)))
          ename (vlax-ename->vla-object obj)
          pr (* 0.5 (vlax-curve-getEndParam ename))
          pt (vlax-curve-GetpointAtParam ename pr)
          deriv (vlax-curve-getFirstDeriv ename pr)
          rtx (- (atan (cadr deriv) (car deriv)) (angle '(0 0 0) (getvar "UCSXDIR")))
        )
        (if (or (> rtx (* pi 0.5)) (< rtx (- (* pi 0.5)))) (setq rtx (+ rtx pi)))
        (setq nw_obj
          (vla-addMtext Space
            (vlax-3d-point (setq pt (polar pt (+ rtx (* pi 0.5)) (getvar "TEXTSIZE"))))
            0.0
            (strcat
              "{\\fArial|b0|i0|c0|p34;"
              "%<\\AcObjProp Object(%<\\_ObjId "
              (itoa (vla-get-ObjectID (vlax-ename->vla-object obj)))
              ">%).Elevation \\f \"%lu2%pr0\">%"
            )
          )
        )
        (mapcar
          '(lambda (pr val)
            (vlax-put nw_obj pr val)
          )
          (list 'AttachmentPoint 'Height 'DrawingDirection 'InsertionPoint 'StyleName 'Layer 'Rotation 'BackgroundFill)
          (list 5 (getvar "TEXTSIZE") 5 pt "Standard" "Label Elevation" rtx 0)
        )
      )
    )
  )
  (prin1)
)

**steveo** · 2012-02-10, 02:56 PM

Originally Posted by Tom Beauford

Try ContourAnnotate.lsp. It works on your attached drawing or any Map data or polylines with elevations. It places the text right-side up even in twisted views. It uses the current Text Style and Size and places the text on the same layer as the contour so it turns off with the layer. Give it a try.

gave it a try.... don't work.. bunch of stuff in the program that is or is not needed for simple contour labeling.
i.e. load tcasesup.lsp ??????
Steve

**Bruno.Valsecchi** · 2012-02-10, 03:30 PM

For Object Data, i make this if you want try.
I know bug with tag OD if special character

**Tom Beauford** · 2012-02-10, 03:31 PM

Originally Posted by steveo

gave it a try.... don't work.. bunch of stuff in the program that is or is not needed for simple contour labeling.
i.e. load tcasesup.lsp ??????
Steve

Sorry, try adding

Code:

 (vl-load-com)

to the start of the routine. It's required to be loaded for using any visual lisp. Most who use it a lot have it loaded automaticly. I don't add it to my routines. There is extra labeling stuff in there. I forget sometimes that not everyone installs the free Express Tools that come with AutoCAD. If you don't have it just remark it out, it's not used for the contour elevations anyway. I use the Express Tool tcase for labeling things like street names which in our GIS are all capitalized.

**steveo** · 2012-02-10, 04:09 PM

Originally Posted by Tom Beauford

Sorry, try adding

Code:

 (vl-load-com)

to the start of the routine. It's required to be loaded for using any visual lisp. Most who use it a lot have it loaded automaticly. I don't add it to my routines. There is extra labeling stuff in there. I forget sometimes that not everyone installs the free Express Tools that come with AutoCAD. If you don't have it just remark it out, it's not used for the contour elevations anyway. I use the Express Tool tcase for labeling things like street names which in our GIS are all capitalized.

Tom... now I get the following error...
Select point on Contour Line or Street Segment:
Error: no function definition: ADE_ODGETTABLES

vl-load-com added ok and I have express tools ok in Acad2008 thanks for reply.
Steve

Thread: Contour elevation labelling..........help

Thread Tools

Display

Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Re: Contour elevation labelling..........help

Similar Threads

Help With Contour Labeling Elevation Precision

Extract a User Specified contour elevation from a surface

Contour labels all reading the same elevation?

Looking for GIS elevation contour data.

Labelling contour lines and spot elevations in AutoCAD 2007

Posting Permissions