Object selection with a keyword option

[cadconcepts]

Hi All

Is there a that I can get a user the choice to select object or to enter a keyword as an option? My plan is to prompt the user to "Select objects individually or by [Layer]:". Any objects chosen are added to the selection set or alternatively, they can type"L" and have a subroutine build a selection set by selecting an object on a specific layer. Any help is greatly appreciated. Thanks.

Manuel

[BlackBox]

(defun c:FOO  (/ *error* _Nomutt)
  (vl-load-com)

  (defun *error*  (msg)
    (and oldNomutt (setvar 'nomutt oldNomutt))
    (if acDoc (vla-endundomark acDoc))
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** "))))                 ; Fatal error, display it
    (princ))

  (defun _Nomutt  (on) (setvar 'nomutt (if on 1 0)))

  ((lambda (acDoc oldNomutt / ss layer)
     (vla-startundomark acDoc)
     (if
       (and
         (princ "\nSelect objects, or <Enter> for layer: ")
         (_Nomutt T)
         (or (setq ss (ssget "_:L"))
             (and
               (_Nomutt nil)
               (/= "" (setq layer (getstring T "\nEnter layer name(s): "))))))

        (progn
          ;; <- Do something with the ss, or layer string here,
          ;; for now, prompt user what they chose:
          (prompt (strcat "\n** You chose to "
                          (if ss
                            "\"select objects\""
                            "\"enter layer name(s)\"")
                          " ** "))
          (*error* nil))
        ;; If no valid choice is made, report:
        (*error* "You didn't enter a valid option")))
    (vla-get-activedocument (vlax-get-acad-object))
    (getvar 'nomutt)))

[cadconcepts]

Renderman
Thanks for the code. I am still working on the routine but what I have thus far is working exactly as needed. Take care.
Manuel

[BlackBox]

Renderman
Thanks for the code. I am still working on the routine but what I have thus far is working exactly as needed. Take care.
Manuel

You're welcome; Happy to help