Need a little debugging help: "Error, too few arguments"

[stusic]

Hey All,

I can't seem to find the error of my ways in this code. Can anyone take a peek and tell me what's wrong?

Thanks

(defun c:BlockReplace (old new / ss)
  (vl-load-com)
  (command "-insert" "X:\\CONTROLLED_DOCUMENTS\\SYSTEMS\\ENGINEERING_DOCUMENTS\\AUTOCAD_STANDARDS\\blocks\\Balloon_Tag.dwg" ^C)
  (setq old ("Balloon_T,Balloon_TL,Balloon_TR,Balloon_L,Balloon_R,Balloon_B,Balloon_BL,Balloon_BR"))
  (if
    (and
      (setq ss (ssget "_X" (list
                           '(0 . "INSERT")
			   '(8 . "TAGS")
                            (cons 2 old)
                           '(66 . 1)
                           '(410 . "Model")
			   )
                        )); there are some
      (tblsearch "Balloon_Tag" new); the Block is defined
    ); and
    (foreach ; then
      x
      (mapcar 'cadr (ssnamex ss))
      (vla-put-name (vlax-ename->vla-object x) new)
    ); foreach
  ); if
  (princ)
); defun

[stusic]

Found a couple of issues: didn't have the right syntax of "tblsearch", didn't define the variable "new". Now get "too few arguments", lol.

(defun c:BlockReplace (old new / ss)
  (vl-load-com)
  (command "-insert" "X:\\CONTROLLED_DOCUMENTS\\SYSTEMS\\ENGINEERING_DOCUMENTS\\AUTOCAD_STANDARDS\\blocks\\Balloon_Tag.dwg" ^C)
  (setq old ("Balloon_T,Balloon_TL,Balloon_TR,Balloon_L,Balloon_R,Balloon_B,Balloon_BL,Balloon_BR"))
  (setq new ("Balloon_Tag"))
  (if
    (and
      (setq ss (ssget "_X" (list
                           '(0 . "INSERT")
			   '(8 . "TAGS")
                            (cons 2 old)
                           '(66 . 1)
                           '(410 . "Model")
			   )
                        )); there are some
      (tblsearch "block" new); the Block is defined
    ); and
    (foreach ; then
      x
      (mapcar 'cadr (ssnamex ss))
      (vla-put-name (vlax-ename->vla-object x) new)
    ); foreach
  ); if
  (princ)
); defun

[BlackBox]

Couple of things to consider....

When you prefix the Defun call's Symbol with "C:" you're defining a Command, and Commands do not accept parameters (arguments).

Here's some quickly written alternatives to the code you posted, where to Command uses hard-coded input, and the Sub-Function accepts parameters:

(vl-load-com)

(defun c:FooCommand (/ ss new)
  (command
    "-insert"
    "X:\\CONTROLLED_DOCUMENTS\\SYSTEMS\\ENGINEERING_DOCUMENTS\\AUTOCAD_STANDARDS\\blocks\\Balloon_Tag.dwg"
    ^C
  )

  (if (and (setq ss
                  (ssget
                    "_x"
                    '((0 . "INSERT")
                      (8 . "TAGS")
                      (2
                       .
                       "Balloon_T,Balloon_TL,Balloon_TR,Balloon_L,Balloon_R,Balloon_B,Balloon_BL,Balloon_BR"
                      )
                      (66 . 1)
                      (410 . "Model")
                     )
                  )
           )
           (tblsearch "block" (setq new "Balloon_Tag"))
      )
    (progn
      (vlax-for x (setq ss (vla-get-activeselectionset
                             (vla-get-activedocument
                               (vlax-get-acad-object)
                             )
                           )
                  )
        (vla-put-name x new)
      )
      (vla-delete ss)
    )
  )
  (princ)
)

(defun FooSubFunction (old new / ss)
  (command
    "-insert"
    "X:\\CONTROLLED_DOCUMENTS\\SYSTEMS\\ENGINEERING_DOCUMENTS\\AUTOCAD_STANDARDS\\blocks\\Balloon_Tag.dwg"
    ^C
  )

  (if (and (setq ss
                  (ssget
                    "_x"
                    (list '(0 . "INSERT")
                      '(8 . "TAGS")
                      (cons 2 old)
                      '(66 . 1)
                      '(410 . "Model")
                     )
                  )
           )
           (tblsearch "block" new)
      )
    (progn
      (vlax-for x (setq ss (vla-get-activeselectionset
                             (vla-get-activedocument
                               (vlax-get-acad-object)
                             )
                           )
                  )
        (vla-put-name x new)
      )
      (vla-delete ss)
    )
  )
  (princ)
)

[stusic]

Well, that works well, but I'm not sure I follow you. Aside from defining "old" elsewhere, the only thing I see different is the placement of the "new" behind the slash for the arguments instead of in front of it.. Is that it? I didn't think that had an impact. So local is REAL local...

Thanks for your help tho'.

[Opie]

What error(s) are you receiving?

What Renderman is saying is the way you currently have the routine coded, you would not be able to pass the necessary arguments to the routine. You would have to enclose the routine within a set of parenthesis with the associated arguments included. This would make the c: prefix unnecessary.

There may be other errors, but that is the first one I have encountered at the moment.

[BlackBox]

Well, that works well, but I'm not sure I follow you. Aside from defining "old" elsewhere, the only thing I see different is the placement of the "new" behind the slash for the arguments instead of in front of it.. Is that it? I didn't think that had an impact. So local is REAL local...

Just to make sure that the basics are covered first, perhaps you'd do well to go back over the documentation for Defun.

Separately, Lee has some great tutorials on his site... Consider this one as it relates to this topic: Localizing Variables

[stusic]

Separately, Lee has some great tutorials on his site... Consider this one as it relates to this topic: Localizing Variables

Thank you for showing me this; that's something I've missed and didn't realize the use or importance.

[BlackBox]

Thank you for showing me this; that's something I've missed and didn't realize the use or importance.

You're welcome; I'm happy to help.