freeze all objects in a selection set

[james.randjelovic355350]

Hi guys,

I'm trying to write some lisp that will freeze all the layers of a particular group of objects. E.g. it could go through and find all the dimension objects and freeze the layers they're on. Is there an easy way to freeze the layers of a selection set? Any help appreciated.

[rkmcswain]

Hi guys,

I'm trying to write some lisp that will freeze all the layers of a particular group of objects. E.g. it could go through and find all the dimension objects and freeze the layers they're on. Is there an easy way to freeze the layers of a selection set? Any help appreciated.

What about the built in Layer Freeze command?
It lets you pick any number of objects (selection set) and it freezes the layers those objects are on.

-OR- are you trying to use lisp to feed this routine a particular set of layer names (i.e., so you don't have to pick)?

[james.randjelovic355350]

I'd prefer it if I could automate the process so that I didn't have to select the objects myself. Would the best approach be to -

1) go through every object in a drawing
2) check if it's a dimension
3) if it is, store the layer that the object is on in a list
4) use the freeze command to freeze all those layers

This was what I originally intended to do but I got stuck determining if the object was a dimension. E.g. to select objects of a particular type you can just do

(ssget "X" '((0 . "DIMENSION"))))

but then how do you extract the layer information of each of those objects?

[rkmcswain]

Here is a very basic example. The result is a list in the variable "lst"

(setq sset (ssget "_X" '((0 . "DIMENSION"))) i 0 lst '()) ; Select all the dims
(if sset                                                  ; if there were any, proceed
  (repeat (sslength sset)                                 ; loop
    (setq item (ssname sset i))                           ; get an item
    (setq data (entget item))                             ; get its data
    (setq layr (cdr (assoc 8 data)))                      ; find the layer
    (setq lst (cons layr lst))                            ; add it to the list
    (setq i (1+ i))                                       ; increment the counter
  )
)

[BlackBox]

Written quickly, this uses the -LAYER Command in order to support both UNDO, and LAYERP functionality.

(vl-load-com)

(defun c:LayFrzDim (/ *error* ss layerName layers oldCmdecho clayer)

  (defun *error* (msg)
    (and oldCmdecho (setvar 'cmdecho oldCmdecho))
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if (setq ss (ssget "_x" '((0 . "DIMENSION"))))
    (progn
      (vlax-for x (setq ss
                         (vla-get-activeselectionset
                           (vla-get-activedocument (vlax-get-acad-object))
                         )
                  )
        (if
          (not
            (vl-position (setq layername (vla-get-layer x)) layers)
          )
           (setq layers (cons layerName layers))
        )
      )
      (vla-delete ss)
      (setq oldCmdecho (getvar 'cmdecho))
      (setvar 'cmdecho 0)
      (setq clayer (getvar 'clayer))
      (vl-cmdf
        "._-layer"
        "freeze"
        (vl-string-right-trim
          ","
          (apply 'strcat
                 (mapcar (function (lambda (x) (strcat x ",")))
                         (vl-remove-if
                           (function
                             (lambda (x) (= clayer x))
                           )
                           layers
                         )
                 )
          )
        )
        ""
      )
    )
    (prompt "\n** No dimensions found ** ")
  )
  (*error* nil)
)

[james.randjelovic355350]

Thanks a lot, those are really helpful. I found another script on these forums and changed it a bit, so that I can move all the dimension objects to a new layer, "dimensions", just in case an architect puts dimensions on the same layer as stuff we don't want frozen. Minor issue, but is there an easy way to combine this code with the script you wrote Renderman? I tried combining it in the obvious way, making one big function which had the input arguments of both, but it didn't seem to work. Here's the code I wanted to add.

(defun C:mvlay ( / sset)
  ; if the layer dimensions does not exist, then create it 
  (if (not (tblsearch "LAYER" "dimensions"))
    (command "._LAYER" "_N" "dimensions" "_C" "5" "dimensions" "" "")
  )
  ; grab everything that's dimensions 
  (setq sset (ssget "_X" '((0 . "DIMENSION"))))
  ; change it to layer dimensions
  (command "._change" sset "" "_P" "_LA" "dimensions" "")
  (princ)
)

[BlackBox]

For simplicity, there's no need to create a list of each layer a dimension resides on to feed to the -LAYER Command, if your intention is to move all Dimensions to a "DIMENSIONS" Layer... Instead, consider this simple adaptation of the code you posted:

(defun c:FOO (/ layerName ss)
  
  ;; if the layer dimensions does not exist, then create it 
  (if (not (tblsearch "layer" (setq layerName "DIMENSIONS")))
    (command "._-layer" "new" layerName "color" "5" layerName "" ""
            )
  )

  ;; grab everything that's dimensions 
  (if (setq ss (ssget "_x" '((0 . "DIMENSION"))))
    (progn
      
      ;; change it to layer dimensions
      (command "._change" ss "" "properties" "layer" layerName "")

      ;; freeze only the dimensions layer
      (command "._-layer" "freeze" layerName "")
    )
    (prompt "\n** No dimensions found ** ")
  )
  (princ)
)