Update field value/format inside of mtext

[GerWei]

I update the format of a field inside of an mtext:

(defun c: putfield ()
   (vl-load-com)
   (setq elemname (car (entsel "\nSelect Text, MText, or Attributed Block with Field Expression: ")))
   (princ "\n")
   (setq elemdata (entget elemname))
   (setq tval (cdr (assoc 1 elemdata)))				

   (setq dict (vlax-vla-object->ename (vla-GetExtensionDictionary (vlax-ename->vla-object elemname))))
   (setq flst (entget (cdr (assoc 360 (entget (cdr (last (dictnext dict "ACAD_FIELD"))))))))					
   (setq fexp (cdr (assoc 2 flst)))

   (princ (strcat "\nField Expression of Text Value \"" tval "\": " fexp "\n"))
   (setq newstr "\\AcObjProp Object(%<\\_ObjIdx 0>%).Area \\f \"%lu2\%ps[, m²]%ct8[0.0001]\"")
   (setq flst (subst (cons 2 newstr) (assoc 2 flst) flst))
   (entmod flst)
   ;; (entupd flst)
   (entupd elemname)
   (vla-update (vlax-ename->vla-object elemname))
   (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acActiveViewport)
   ;; (command "regen")

   (princ)
)

regen or regenall: no change
But the visible value do not change
If i open the mtexteditor and edit the field i can see the new format, if i update the field the new format will be applied.
How can i update the mtext/field?

[Tom Beauford]

Shouldn't be that hard. Try setting FIELDEVAL to 31 and DEMANDLOAD to 3. Maybe post a small drawing with an mtext that isn't updating so we can see what's going on? Is the lisp to replace the existing field or are you just trying to get it to update?

[BlackBox]

gerhard.weinhaeusel, please revise your post to include [CODE ] Tags.

[GerWei]

I have uploaded the dwg. FIELDEVAL always 31 , demandload 3. I change the format of the field (suffix, multiplier). If I edit the MText and update the field inside of MTexteditor the changes are applied. I want to do the visible update wirh lisp.

[Tom Beauford]

What about

 (vl-cmdf "updatefield" (car (entsel "\nSelect Text, MText, or Attributed Block with Field Expression: ")) "")

[GerWei]

No - no changes in visible text - the only way to update is edit mtext and update field.
i have also changed the text with "assoc 1 elemdata" with a new text - no visible change - edit mtext and update field: real value visible, newtext removed.

[GerWei]

Finally find a solution:

(defun c:putfield ()
   (vl-load-com)
   (setq elemname (car (entsel "\nMText mit Schriftfeld auswählen: ")))
   (setq elemdata (entget elemname))
   (setq tval (cdr (assoc 1 elemdata)))
   (setq dict (vlax-vla-object->ename (vla-GetExtensionDictionary (vlax-ename->vla-object elemname))))
   (setq flst (entget (cdr (assoc 360 (entget (cdr (last (dictnext dict "ACAD_FIELD"))))))))					
   (setq fexp (cdr (assoc 2 flst)))
   (setq newstr "\\AcObjProp Object(%<\\_ObjIdx 0>%).Area \\f \"%lu2\%pr2%ct8[0.0001]\"")
   (setq flst (subst (cons 2 newstr) (assoc 2 flst) flst))
   (entmod flst)
   (setq elemnamevla (vlax-ename->vla-object elemname))
   (vla-put-textstring elemnamevla (vla-fieldcode elemnamevla))
   (princ)
)

[BlackBox]

gerhard.weinhaeusel, please re-read post#3.

[Tom Beauford]

Nice code accessing the field with dictionary, but much easier to follow if it had the code tags.
Thanks,