object to field relation

[rmk]

I have several closed polylines with fields associated with them displaying the area of the polyline.

How can i determine which field is associated with which polyline? Will it highlight the object? or is it trial and error.

[feargt]

courtesy of mr Lee Mac...

select the field and it will highlight the referenced object.

;;------------------=={ Get Field Objects }==-----------------;;
;;                                                            ;;
;;  Returns a list of entities referenced by a supplied field ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  en - Entity containing field (Text / MText / Attribute)   ;;
;;------------------------------------------------------------;;
;;  Returns:  List of entities referenced by Field, else nil  ;;
;;------------------------------------------------------------;;

(defun LM:GetFieldObjects ( en / _getfieldobjects )

    (defun _getfieldobjects ( a )
        (apply 'append
            (mapcar
                (function
                    (lambda ( a )
                        (if (= 360 (car a))
                            (_getfieldobjects (cdr a))
                            (if (= 331 (car a)) (list (cdr a)))
                        )
                    )
                )
                (entget a)
            )
        )
    )
    
    (if
        (and
            (wcmatch (cdr (assoc 0 (setq en (entget en)))) "TEXT,MTEXT,ATTRIB")
            (setq en (cdr (assoc 360 en)))
            (setq en (dictsearch en "ACAD_FIELD"))
            (setq en (dictsearch (cdr (assoc -1 en)) "TEXT"))
            (setq en (cdr (assoc 360 en)))
        )
        (_getfieldobjects en)
    )
)

(defun c:STF ( / en lst )
    (while
        (progn (setvar 'ERRNO 0) (setq en (car (nentsel "\nSelect Field: ")))
            (cond
                (   (= 7 (getvar 'ERRNO))
                    (princ "\nMissed, try again.")
                )
                (   (eq 'ENAME (type en))
                    (if (setq lst (LM:GetFieldObjects en))
                      (foreach ent lst (command "zoom" "o" ent "" ) (redraw ent 3))
                      
                        (princ "\nObject is not a Field, or Field doesn't reference any Objects.")
                    )
                )
            )
        )
    )
    (princ)
)

[rmk]

Thanks feargt and kudos to Mr. Lee Mac.....great lisp routine. works great. just what i was looking for.

[vmichl]

Or you can try the free utility FieldLink - it draws temporary (or permanent) links/arrows between the pairs field-source object (works also on blovks and tables with fields).

See:
http://www.cadforum.cz/cadforum_en/f...bjects-tip6795

Vladimir Michl, www.cadstudio.cz