Modify Text

[feargt]

Hi,
I have not been able to find any help on this. I have found similar codes but nothing that does what I want.


I need to be able to change the following mtext:

"-1,624.000" to "-1,6-24.000"

at the moment the "-" symbol will always be entered as the 5th Character

would really appreciate some help on this.

I want to be able to select multiple mtext at once and then let a "foreach" or something similar run the neccessary code over it.

thanks

[Tom Beauford]

What does the text represent? Is the placement of "-" in relation to the decimal point or will it always be entered as the 5th Character?

[feargt]

it represents chainage.

But actually that is a goode point. it will always be 3 places before the decimal point and not always in the 5 th position.
It is just in this case that it is in the 5th posiiton.

[BlackBox]

Give this a try:

(vl-load-com)

(defun c:FOO (/ *error* acDoc s i)

  (defun *error* (msg)
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if (ssget "_:L"
             '((0 . "MTEXT")
               (1 . "*,*.*")
               (-4 . "<NOT")
               (1 . "*-##.*")
               (-4 . "NOT>")
              )
      )
    (progn
      (vla-startundomark
        (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
      )
      (vlax-for x (vla-get-activeselectionset acDoc)
        (vla-put-textstring
          x
          (strcat (substr (setq s (vla-get-textstring x))
                          1
                          (setq i (- (vl-string-search "." s) 2))
                  )
                  "-"
                  (substr s (1+ i))
          )
        )
      )
    )
  )
  (*error* nil)
)

[feargt]

Hi Blackbox,

that returns "error too many arguments"

[BlackBox]

Hi Blackbox,

that returns "error too many arguments"

Oops! That's what I get for writing code within my post, rather than in VLIDE... Code corrected... Give it another try?

[BlackBox]

I made one more minor edit to the selection set filter, to preclude the selection of text that already includes the hyphen ("*-##.*").

[feargt]

Thanks, that has done the trick. And it is also allows me to create variations of the command too!

Thanks

[BlackBox]

Thanks, that has done the trick. And it is also allows me to create variations of the command too!

Thanks

You're welcome; I'm happy to help.