DELETE BLOCK CODE HELP

[jayhay35365091]

Can anybody edit this code to allow multiple selections and window selection?

(defun c:db (/ block ll ur objecttojoin)
      (vl-load-com)
      (setq block (car (entsel "\nSelect Block:")))
      (vla-getboundingbox (vlax-ename->vla-object block) 'll 'ur)
      (command "_.erase" block "")
      (setq objecttojoin
                 (ssget "C"
                        (vlax-safearray->list ll)
                        (vlax-safearray->list ur)))
      (command
            "_.join"
            (ssname objecttojoin 0)
            (ssname objecttojoin 1)
            "")
      )

[jdiala]

try this:

;;;; JDiala 09-13-2013 ;;;;
(defun C:test (/ ss i b)
(if
  (and
    (setq ss (ssget '((0 . "INSERT,LINE"))))
	(= 3 (sslength ss))
  )
  (progn
    (setq b t i 0)
    (while b
	  (if (= "INSERT" (cdr (assoc 0 (entget (ssname ss i)))))
	      (progn
		    (entdel (ssname ss i))
		    (ssdel (ssname ss i) ss)
			(command "_.join" (ssname ss 0) (ssname ss 1) "")
			(setq b nil)
	      )
		  (setq i (1+ i))
	  )
	)
  )
)
(princ)	  
)

[jayhay35365091]

Thanks. This code allows for window selection but I still cant make it run on multiple blocks at a time. Any ideas?

[bhull1985403354]

Well jdiala put in a line of code

(= 3 (sslength ss))

which means that if the selection set is equal to three objects that are either line or inserts, preform the following......
I'm not sure if this would need to be modified to have the program run on more than 3 items, but i'd start there to find out...

[pbejse]

Can anybody edit this code to allow multiple selections and window selection?

Try this:

(Defun c:db ( / pea ss i ll ur objecttojoin)
  (setq pea (getvar 'Peditaccept))
  (setvar 'Peditaccept 1) 
      (if (setq ss (ssget "_:L" '((0 . "INSERT"))))
          (repeat (setq i (sslength ss))
              (vla-getboundingbox (setq e (vlax-ename->vla-object (ssname ss (setq i (1- i))))) 'll 'ur)
              (vla-delete e)
          (if  (Setq objecttojoin (ssget "C"
                      (vlax-safearray->list ll)
                      (vlax-safearray->list ur) '((0 . "LWPOLYLINE,LINE"))
                   ))
            (command "_.pedit" "_M" objecttojoin "" "_J" "" "")

              )
          )
      )
(setvar 'Peditaccept pea)
  (princ)
  )

But i would be better if you add the block name in the selection

(setq ss (ssget "_:L" '((0 . "INSERT")(2 . "Blockname"))))

HTH