Create Surface from Points

[julia.roberts435830]

I have a series of cogo points that I would like to use to create a new surface... I can do this pretty simply with a TIN, but ideally what I'd like is the points (which represent single point features such as a power pole, cell tower, etc.) to be "spikes" if you will with the surface around each point to be flat (can be a set elevation value or 0). Is there a way to do this? And if so, how?

Thank you.

[cadtag]

place a rect feature line at el=0 around the points?

[julia.roberts435830]

Around every individual point? Is there a quick way to do that as I have hundreds or thousands of points.

[Opie]

I am not sure if cadtag was meaning each point individually. However, you could automate the drawing of this rectangle around each point through AutoLISP / Visual LISP.

[BlackBox]

Quickly written:

(vl-load-com)

(defun c:SPIKE (/ *error* nomutt ss oPline pt z insertionPoint i
              acDoc cogoPoint
             )

  (defun *error* (msg)
    (and nomutt (setvar 'nomutt nomutt))
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if
    (and
      (princ "\nSelect polyline to copy: ")
      (princ)
      (setq nomutt (getvar 'nomutt))
      (setvar 'nomutt 1)
      ;;(setq ss (ssget ":S:E:L" '((0 . "AECC_FEATURE_LINE"))))
      (setq ss (ssget ":S:E:L" '((0 . "LWPOLYLINE"))))
      (setq oPline (vlax-ename->vla-object (ssname ss 0)))
      (setvar 'nomutt 0)
      (setq pt
             (trans (getpoint "\nSpecify feature line insertion point: ")
                    1
                    0
             )
      )
      (setq z (last pt))
      (setq insertionPoint (vlax-3d-point pt))
      (setq i 0)
      (princ "\nSelect COGO points: ")
      (setvar 'nomutt 1)
      (setq ss (ssget '((0 . "AECC_COGO_POINT"))))
    )
     (progn
       (vla-startundomark
         (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
       )
       (vlax-for x (vla-get-activeselectionset acDoc)
         (setq cogoPoint (vlax-get x 'location))
         (vla-move (vla-copy oPline)
                   insertionPoint
                   (vlax-3d-point (list (car cogoPoint) (cadr cogoPoint) z))
         )
         (setq i (1+ i))
       )
       (setvar 'nomutt 0)
       (prompt
         (strcat "\n"
                 (itoa i)
                 " polyline"
                 (if (= 1 i)
                   ""
                   "s"
                 )
                 " copied to "
                 (itoa (sslength ss))
                 " COGO points"
         )
       )
     )
  )
  (*error* nil)
)

[cadtag]

well, i was thinking of each point, but did not realize that the OP had thousands to deal with. For a few dozen I'd set OSNAPZ then copy my feature line from node to node.

I see BB has offered a code solution, so that should work out for her. Another thought, depending on the data source, would be querying in the XY locations and using the Z value to extrude a circle to that height. Also amenable to a LISP solution from a text file.

[BlackBox]

I see BB has offered a code solution, so that should work out for her. Another thought, depending on the data source, would be querying in the XY locations and using the Z value to extrude a circle to that height. Also amenable to a LISP solution from a text file.

Giving this another look, it seems that even when supplying the X and Y from the COGO Point's Location Property, and the Z from the base point (0.0 in my testing), the resultant Feature Lines still influenced by the destination COGO Point's elevation somehow. *kicks dirt*

When I have more time, I'll look into the SetPointElevation, and SetPointsElevation Methods.

[cadtag]

so, instead of a feature line, why not a simple 2d pline at el=0? include that as an acad object in the surface, and have a nice little pyramid shooting skyward.

reverse for boreholes.....

[BlackBox]

so, instead of a feature line, why not a simple 2d pline at el=0? include that as an acad object in the surface, and have a nice little pyramid shooting skyward.

reverse for boreholes.....

Thanks for the suggestion... Code revised above.