I need the area of a polyline in sq. ft, not sq. in.

[jtaylor.82814]

I tried the lisp by Luis Esquivel posted by Miff on September 9th, 2004 but when I use it, it puts my area in sqare inches with a tag of square feet. I thought if I changed my units it might work, but it didn't. I dont think it matters any but I run on ACAD 2002. If any one has a better script or any suggestions it would be greatly appreciated.

THX

[kennet.sjoberg]

Find the line :
(strcat (add-comma (rtos (vla-get-area vla_obj ) 2 0 ) ) " S.F." )
and convert Your unit like
(strcat (add-comma (rtos (/ (vla-get-area vla_obj ) 1000000 ) 2 0 ) ) " m2." )
that convert an area 1000mm x 1000mm in to m2

: ) Happy Computing !

kennet

[paulmcz]

Well, it would be a good idea to post the code here, if you want someone to help you.

[kennet.sjoberg]

Well paulmcz

lisp by Luis Esquivel posted by Miff on September 9th, 2004

: ) Happy Computing !

kennet

[paulmcz]

Sorry, I didn't know that he posted it right here.

[Jeff_M]

Here's a modified version that checks the Lunits sysvar and reacts accordingly. Not intended for use in metric drawings at this time.

;; =================================================
;; 2002 By Luis Esquivel
;; put the area in sq-ft of selected closed areas...
;; modified 11/22/03 by Jeff Mishler to allow use within
;; PS Viewport and to accept a Polyline that was created
;; by selecting the startpoint as the endpoint, technically
;; it is closed but the closed property isn't set.
;;
;; Command: PUTAREA

;;;(addtext <string> <point> <real>)
(defun addtext (textstring insertionpoint height / aa)
  (vl-load-com)
  (setq aa (vla-get-activedocument (vlax-get-acad-object)))
  (vla-addtext
	      (if (= 1 (vla-get-activespace aa))
		(vla-get-modelspace aa)
		(if (= (vla-get-mspace aa) :vlax-true)
		  (vla-get-modelspace aa)
		  (vla-get-paperspace aa)
		  )
		)
	      textstring
	      (vlax-3d-point insertionpoint)
	      height)
  )

(defun add-comma  (txt / strl cont1 lth cont txt1)
  (setq strl  (strlen txt)
 cont1 1
 txt1  "")
  (while (and (/= (substr txt cont1 1) ".") (<= cont1 strl))
    (setq cont1 (1+ cont1)))
  (setq lth   (1- cont1)
 cont1 1
 cont  (1- lth))
  (if (> lth 3)
    (progn
      (while (< cont1 lth)
 (setq let  (substr txt cont1 1)
       txt1 (strcat txt1 let))
 (if (and (zerop (rem cont 3)) (eq (type (read let)) 'INT))
   (setq txt1 (strcat txt1 ",")))
 (setq cont  (1- cont)
       cont1 (1+ cont1)))
      (while (<= cont1 strl)
 (setq txt1  (strcat txt1 (substr txt cont1 1))
       cont1 (1+ cont1)))
      txt1)
    txt))

(defun get-last-coord (obj / COORDS LAST_COORD)
  (setq coords (vla-get-coordinates obj)
	coords (vlax-safearray->list (vlax-variant-value coords))
	coords (reverse coords)
	last_coord (list (cadr coords)(car coords)
			 )
	)
  last_coord
  )

(defun C:PUTAREA  (/ ent vla_obj pt objname vla_text aa lunit)
  (while (setq ent (entsel "\nSelect closed object: "))
    (setq vla_obj (vlax-ename->vla-object (car ent))
   objname (vla-get-objectname vla_obj))
    (if
      (vlax-property-available-p vla_obj 'area)
       (progn
  (if
    (or
      (= "AcDbCircle" objname)
      (and (wcmatch (vla-get-objectname vla_obj) "*Polyline")
	   (or  (= :vlax-true (vla-get-closed vla_obj))
		(equal (vlax-safearray->list
		     (vlax-variant-value
		       (vla-get-coordinate vla_obj '0)))
		   (get-last-coord vla_obj)
		   0.001)
		)
	   )
      )
     (progn
       (if (setq pt (getpoint "\nPick text placement: "))
  (progn
    (setq lunit (getvar "lunits"))
    (setq vla_text
    (addtext
      (strcat
        (add-comma
          (rtos
	    (if (or (= lunit 3)
		    (= lunit 4)
		    )
	      (/ (vla-get-area vla_obj) 144)
	      (vla-get-area vla_obj)
	      )
     2
     0))
        " S.F.")
      pt
      (getvar "textsize")))

    ;; alignment to left
    (vla-put-alignment vla_text acAlignmentCenter)

    (vla-put-textalignmentpoint
      vla_text
      (vlax-3d-point pt))

    ;; use current textstyle
    (vla-put-stylename
      vla_text
      (vla-get-name
        (vla-get-activetextstyle
   (setq aa (vla-get-activedocument
       (vlax-get-acad-object)))))))))
     (prompt "\nNot a closed object. ")
    ))))
  (princ))
(princ)

[kennet.sjoberg]

...mmm, and here is a way to do it in metric mm2

(defun c:InsertArea ( / Ent Ent Area Pkt )
  (if (setq Ent (entsel "\nCommand: Select a closed LWpolyline or a region : " ) )
    (progn
      (vl-load-com)
      (setq Obj (vlax-ename->vla-Object (car Ent )) ) ;; Only closed LWPolyline or regions are allowed
      (if (or (and (= (vlax-get  Obj "ObjectName" ) "AcDbPolyline" ) (= (vlax-get  Obj "Closed" ) -1 ) ) (= (vlax-get  Obj "ObjectName" ) "AcDbRegion" ) )
        (progn
          (setq Area (vlax-get  Obj "Area" ) )
          (vlax-release-Object Obj )
          (initget 7 )
          (setq Pkt (getpoint "and place the Area Text : " ) )
          (command "._text" "J" "MC" Pkt "" "" (strcat (rtos Area 2 0  ) " mm2" ) )
        )
        (princ "That object was not allowed."  )
      )
    )
    (princ "Miss, aim better !" )
  )
  (princ)
)

: ) Happy Computing !

kennet

[jtaylor.82814]

Here's a modified version that checks the Lunits sysvar and reacts accordingly. Not intended for use in metric drawings at this time.

;; =================================================
;; 2002 By Luis Esquivel
;; put the area in sq-ft of selected closed areas...
;; modified 11/22/03 by Jeff Mishler to allow use within
;; PS Viewport and to accept a Polyline that was created
;; by selecting the startpoint as the endpoint, technically
;; it is closed but the closed property isn't set.
;;
;; Command: PUTAREA

;;;(addtext <string> <point> <real>)
(defun addtext (textstring insertionpoint height / aa)
  (vl-load-com)
  (setq aa (vla-get-activedocument (vlax-get-acad-object)))
  (vla-addtext
	      (if (= 1 (vla-get-activespace aa))
		(vla-get-modelspace aa)
		(if (= (vla-get-mspace aa) :vlax-true)
		  (vla-get-modelspace aa)
		  (vla-get-paperspace aa)
		  )
		)
	      textstring
	      (vlax-3d-point insertionpoint)
	      height)
  )

(defun add-comma  (txt / strl cont1 lth cont txt1)
  (setq strl  (strlen txt)
 cont1 1
 txt1  "")
  (while (and (/= (substr txt cont1 1) ".") (<= cont1 strl))
    (setq cont1 (1+ cont1)))
  (setq lth   (1- cont1)
 cont1 1
 cont  (1- lth))
  (if (> lth 3)
    (progn
      (while (< cont1 lth)
 (setq let  (substr txt cont1 1)
       txt1 (strcat txt1 let))
 (if (and (zerop (rem cont 3)) (eq (type (read let)) 'INT))
   (setq txt1 (strcat txt1 ",")))
 (setq cont  (1- cont)
       cont1 (1+ cont1)))
      (while (<= cont1 strl)
 (setq txt1  (strcat txt1 (substr txt cont1 1))
       cont1 (1+ cont1)))
      txt1)
    txt))

(defun get-last-coord (obj / COORDS LAST_COORD)
  (setq coords (vla-get-coordinates obj)
	coords (vlax-safearray->list (vlax-variant-value coords))
	coords (reverse coords)
	last_coord (list (cadr coords)(car coords)
			 )
	)
  last_coord
  )

(defun C:PUTAREA  (/ ent vla_obj pt objname vla_text aa lunit)
  (while (setq ent (entsel "\nSelect closed object: "))
    (setq vla_obj (vlax-ename->vla-object (car ent))
   objname (vla-get-objectname vla_obj))
    (if
      (vlax-property-available-p vla_obj 'area)
       (progn
  (if
    (or
      (= "AcDbCircle" objname)
      (and (wcmatch (vla-get-objectname vla_obj) "*Polyline")
	   (or  (= :vlax-true (vla-get-closed vla_obj))
		(equal (vlax-safearray->list
		     (vlax-variant-value
		       (vla-get-coordinate vla_obj '0)))
		   (get-last-coord vla_obj)
		   0.001)
		)
	   )
      )
     (progn
       (if (setq pt (getpoint "\nPick text placement: "))
  (progn
    (setq lunit (getvar "lunits"))
    (setq vla_text
    (addtext
      (strcat
        (add-comma
          (rtos
	    (if (or (= lunit 3)
		    (= lunit 4)
		    )
	      (/ (vla-get-area vla_obj) 144)
	      (vla-get-area vla_obj)
	      )
     2
     0))
        " S.F.")
      pt
      (getvar "textsize")))

    ;; alignment to left
    (vla-put-alignment vla_text acAlignmentCenter)

    (vla-put-textalignmentpoint
      vla_text
      (vlax-3d-point pt))

    ;; use current textstyle
    (vla-put-stylename
      vla_text
      (vla-get-name
        (vla-get-activetextstyle
   (setq aa (vla-get-activedocument
       (vlax-get-acad-object)))))))))
     (prompt "\nNot a closed object. ")
    ))))
  (princ))
(princ)

That works like a dream have absolutely no complaints. Would it be possible for it not to round to the nearest sq. ft.? If not it's no big deal but sometimes it's important to at least have it round to the nearest tenth's place.

[lance.81922]

It's easy to make the program print the area with tenths of a square foot. At line 108, the part that says:
(rtos
(if (or (= lunit 3)
(= lunit 4)
)
(/ (vla-get-area vla_obj) 144)
(vla-get-area vla_obj)
)
2
0
)
The "0" is the precision setting for RTOS. Change it to "1" for one decimal place.

[Jeff_M]

It's easy to make the program print the area with tenths of a square foot. At line 108, the part that says:
(rtos
(if (or (= lunit 3)
(= lunit 4)
)
(/ (vla-get-area vla_obj) 144)
(vla-get-area vla_obj)
)
2
0
)
The "0" is the precision setting for RTOS. Change it to "1" for one decimal place.

Or you could just remove both the 2 and 0, then the (rtos) will use your current unit and precision settings. I hard-coded it since I use this strictly for labelling lot areas on Tentative maps.