Move MText at a certain Z value LISP

[djin_fre3449006]

Someone please help me with this issue:
I would need a lisp routine to move the MText from Z value = 0 to the value written in the text. Example: If the MText says 20.435 I need that this text to be moved to Z value of 20.435.
The thing is that I have 1000s of text on position Z=0 and I was asked to move all of it to the height that is written in it.
I've checked on Google but couldn't find anything.
To make it even more complicated, the MText doesn't have just the height written, but it's something like TOP= 20.435.
I would be very grateful if any of you can create a Lisp routine to make my life easier.

Cheers

[Tharwat]

Try this ...

(defun c:Test (/ s )
;; Tharwat 26.11.2013  ;;
  (if (setq s (ssget "_:L" '((0 . "MTEXT"))))
    ((lambda (u / n p x e)
       (while (setq n (ssname s (setq u (1+ u))))
         (if (and (numberp (read (setq x (cdr (assoc 1 (setq e (entget n)))))))
                  (not (vl-string-search "\\P" x))
                  )
           (entmod (subst (cons 10 (list (car (setq p (cdr (assoc 10 e))))
                                         (cadr p)
                                         (atof x)
                                         ))
                          (assoc 10 e) e))
           )
         )
       ) -1)
    )
  (princ))

[djin_fre3449006]

Thank you very much! Very quick reply!
Works perfect when you have just the digits in the text!
I was wondering if you can make a change and add something so that will recognize the digits from a text as I've said in the previous message. All the text that I have is like this: TOP=20.630 ... and the code doesn't work in this case.
Cheers.

[Tharwat]

Thank you very much! Very quick reply!
Works perfect when you have just the digits in the text!
I was wondering if you can make a change and add something so that will recognize the digits from a text as I've said in the previous message. All the text that I have is like this: TOP=20.630 ... and the code doesn't work in this case.
Cheers.

You're welcome .

Try this modified one to meet your needs and let me know .

(defun c:Test (/ s)
  ;; Tharwat 26.11.2013  ;;
  (if (setq s (ssget "_:L" '((0 . "MTEXT"))))
    ((lambda (u / n p x e z)
       (while (setq n (ssname s (setq u (1+ u))))
         (if (and (setq
                    z
                     (vl-list->string
                       (vl-remove-if-not
                         (function (lambda (i) (or (< 47 i 58) (eq 46 i))))
                         (vl-string->list
                           (setq x (cdr (assoc 1 (setq e (entget n)))))
                         )
                       )
                     )
                  )
                  (not (vl-string-search "\\P" x))
             )
           (entmod (subst (cons 10
                                (list (car (setq p (cdr (assoc 10 e))))
                                      (cadr p)
                                      (atof z)
                                )
                          )
                          (assoc 10 e)
                          e
                   )
           )
         )
       )
     )
      -1
    )
  )
  (princ)
)
(vl-load-com)

[djin_fre3449006]

Thank you so much.. You made my day! Works perfect for what I need.

[Tharwat]

Thank you so much.. You made my day! Works perfect for what I need.

You're welcome anytime