Autolisp challenge

[jayhay35365091]

I have a challenge for anybody who is interested. I need to be able to draw a polyline without joining the individual segments. Also I need to be able to put a specific block at the end of every segment. I'm trying to automate the drawing of my lines in a P&ID with individual polylines for segments and arrows at the end of each segment.

[Tharwat]

Shouldn't you reply to your previous thread before you start a new one HERE ?

[jayhay35365091]

Sorry about that. My jobs going 20 different directions right now and I'm trying to keep up as much as possible.

[Tharwat]

Never mind ,

If you can upload a sample drawing with the block you would to insert and showing BEFORE and AFTER it would be better for understanding the trick you want .

[jayhay35365091]

Sample DWG

[pbejse]

Sample DWG

(Defun c:PDD (/ Insert defval bl  pt1 pt2 )  
;; pBe 15Nov2013 ;;
(defun Insert (pt Nme lay ro sc)
  (entmakex (list (cons 0 "INSERT") (cons 8 lay)
                  (cons 2 Nme)(cons 50 ro)
		  (cons 41 sc)(cons 10 pt))))
(Defun defval (v msg)
   (setq v (cond ((getreal
        (strcat "\n" msg " <" (rtos (setq v
              (cond ( v ) ( 1.0 ))
            ) 2 2) ">: ")))
    ( v )
  )
))
(if (and
      (setq bl (Cdr (assoc 2 (tblsearch "BLOCK" "ARROW_1"))))
      (setq pwd (defval pwd "Enter Pline Width"))
      (setq scl (defval scl "Enter Scale"))
      (setq pt1 (getpoint "\nPick the first Point: "))
    )
 (while (setq pt2 (getpoint pt1 "\nPick Next point:"))
      (entmakex (list (cons 0 "LWPOLYLINE")
		  (cons 100 "AcDbEntity")
		  (cons 100 "AcDbPolyline")
		  (cons 90 2) (cons 43 pwd)
		  (cons 10 pt1)(cons 10 pt2)
	    )
       )
	(insert pt2 bl "FlowArrows" (angle pt1 pt2) scl)
        (setq pt1 pt2)
        )

)
  (princ)
)

HTH

[jayhay35365091]

Works near perfect pbejse. The scale of the block only effects the "x" direction. Is there a way to change the code to make it scale uniformly?

[pbejse]

Works near perfect pbejse. The scale of the block only effects the "x" direction. Is there a way to change the code to make it scale uniformly?

Here you go..

(defun Insert (pt Nme lay ro sc)
  (entmakex (list (cons 0 "INSERT") (cons 8 lay)
                  (cons 2 Nme)(cons 50 ro)
		  (cons 41 sc)(cons 42 sc)(cons 43 sc)
(cons 10 pt))))

[jayhay35365091]

Thanks a ton!! This is going to save me so much time. You are a life saver.

[jayhay35365091]

If you are feeling extra savy, do you know of a way to automaticlly break the intersecting vertical lines by a specified distance?