how to replace only a single string by pre decided string.

[mohammad.raees637333]

Hi....
My query is that I want to replace the value of a pre decided string to a single string by clicking on it. Find and replace is not useful for this because it replaces all strings. For example in autocad drawing any text is given and by clicking on this text it should be replaced by pre decided text "xyz" (for example).

Thanks in advance!!!!!

[ngwalters412556]

(if
  (vl-string-search 
    "<Unique Identifier>" 
    (setq txt1 
      (vlax-get-property 
        (setq ent1 
          (vlax-ename->vla-object (car(entsel "\nSelect Text:\t")))
      )
      'textstring)
    )
  )
  (vlax-put-property ent1 'textstring (strcat "<Your Text Stuff Here>" "<More Stuff>"))
)

You could put a test at the if function to test that it is at the beginning of the string if it's not a unique identifier (i.e. it could appear in the text after it, false positives). Yes it could be more robust, testing for nil entities etc, but that will get you started.

[Tom Beauford]

Hi....
My query is that I want to replace the value of a pre decided string to a single string by clicking on it. Find and replace is not useful for this because it replaces all strings. For example in autocad drawing any text is given and by clicking on this text it should be replaced by pre decided text "xyz" (for example).

Thanks in advance!!!!!

Find and replace gives the options to Replace or Find Next as well as Replace All. What version are you using?

[BlackBox]

My query is that I want to replace the value of a pre decided string to a single string by clicking on it. Find and replace is not useful for this because it replaces all strings. For example in autocad drawing any text is given and by clicking on this text it should be replaced by pre decided text "xyz" (for example).

I am unsure if you intentionally requested to select each-and-every-single text entity one-at-a-time or not, so this will allow you to do that, or select multiple text entities at once:

(defun c:FOO (/ *error* acDoc)

  (defun *error* (msg)
    (if	acDoc (vla-endundomark acDoc))
    (cond ((not msg))							; Normal exit
	  ((member msg '("Function cancelled" "quit / exit abort")))	; <esc> or (quit)
	  ((princ (strcat "\n** Error: " msg " ** ")))			; Fatal error, display it
    )
    (princ)
  )

  (if (ssget "_:L" '((0 . "TEXT,MTEXT")))
    (progn
      (vla-startundomark
	(setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
      )
      (vlax-for	x (vla-get-activeselectionset acDoc)
	(vla-put-textstring x "xyz")
      )
    )
  )
  (*error* nil)
)