Delete layer with specified text/word in layer name

[Arterius]

hi All,

I am trying to delete layers including one specific word in layer name.
I tryed a code, like below but does not work:

(defun c:dd () (command "._-layer" "delete" pause "") (princ))

When prompted for layer name(s), I simply entered *myword* (specific word in whole layer name) I got "The selected layers could not be deleted."....
Can someone help?
Thanks.

[pbejse]

hi All,

When prompted for layer name(s), I simply entered *myword* (specific word in whole layer name) I got "The selected layers could not be deleted."....
Can someone help?
Thanks.

Make sure there are no entities under the target layer name

.undelete.JPG

[Arterius]

The thing is there are entities
I would like to delete all objects on layer also.
Like you do by typing LAYDEL, and [Name], and select one and confirm.

[pbejse]

(defun c:demo ( / layname)
  (if (and (setq layname (getstring "\nEnter Layer to delete: "))
	   (/= "" layname)
	   (ssget "X" '((8 . "*myword*")))
      )
    (command "_erase" "p" "" "._-layer" "delete" layname "")
  )(princ)
)

But of course , if there are objects under the specified layer inside a block/another layout/xref. it will still bomb.

[pbejse]

(defun c:delayer (/ layname)
  (if (and (setq layname (getstring "\nEnter Layer to delete: "))
           (/= layname ""))
    (vlax-for b (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
        (if (= :vlax-false (vla-get-isxref b))
            (vlax-for o b
                (if (and (vlax-write-enabled-p o)
			 (wcmatch (strcase (vla-get-layer o)) (strcase layname)))
                    (vla-delete o)
		  )
                )
            )
        )
    )
   (repeat 4
  (vla-purgeall (vla-get-activedocument (vlax-get-acad-object)))
 )
    (princ)
)
(vl-load-com) (princ)

[Arterius]

yes, I know I need to be careful with this.
Thanks, but how to bypass "\nEnter Layer to delete: "? Just put into code my specific word, type running command and that's all?

[pbejse]

yes, I know I need to be careful with this.
Thanks, but how to bypass "\nEnter Layer to delete: "? Just put into code my specific word, type running command and that's all?

What do you mean Arterius? The command is exclusively for that <*myword*> specific keyword?

(defun c:DSL nil ;<-- Delete This Layer
    (vlax-for b (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
        (if (= :vlax-false (vla-get-isxref b))
            (vlax-for o b
                (if (and (vlax-write-enabled-p o)
			 (wcmatch (strcase (vla-get-layer o)) "*MYWORD*"))
                    (vla-delete o)
		  )
                )
            )
        )
    )
   (repeat 4
  (vla-purgeall (vla-get-activedocument (vlax-get-acad-object)))
 )
    (princ)
)
(vl-load-com) (princ)

[Arterius]

Hi pbejse,

thanks for codes! I meant that your code from post #5 prompts for *myword*, that's really fine, but I was thinking about putting *myword* as permament into routine. I have edited your code and I found what I was looking for

Thanks for your help. Regards