Move Hatches to specific layer

[greg.steel412420]

Hi I hope someone can help me here.
I have a drawing with 300 or so blocks most of which have some sort of hatching.

Does someone know of or could someone write a lisp routine that would select all hatches (including within the blocks) and move the to a specified layer?

It sounds fairly simple task but I am not very experienced in Autocad. I have been trying to learn how to a write lisp routine but admittedly I am completely hopeless. I have been searching forums and the closest lisp I have found is this one but seems to only move hatches with colour set to bylayer.

I would really appreciate any help someone could give me here.
Thanks

[GHarvey]

Here's a basic function that should do what you are asking:

(defun htchlay (lynm )
  (or activedocument
      (setq activedocument (vlax-get-property (vlax-get-acad-object) 'activedocument))
      ); or
  (or blocks
      (setq blocks (vlax-get-property activedocument 'blocks))
      ); or
  (or layers
      (setq layers (vlax-get-property activedocument 'layers))
      ); or
  (if (not
	(vl-catch-all-error-p (vl-catch-all-apply 'vla-item (list layers lynm)))
	); not
    (progn
      (vlax-for x blocks
	(vlax-for n x
	  (if (equal "AcDbHatch" (vlax-get-property n 'objectname))
	    (vl-catch-all-apply 'vlax-put-property (list n 'layer lynm))
	    ); if
	  ); vlax-for
	); vlax-for
      ); progn
    ); if
  (vl-cmdf "regen")
  (princ)
  ); defun

Pass it the name of an existing layer, thus:

(htchlay  "0")

[BlackBox]

This accounts for locked layers, error handling, and supports UNDO functionality as well:

(vl-load-com)

(defun _FOO (layerName / *error* acDoc oLayers layer oLayer lock)

  (defun *error* (msg)
    (foreach oLayer lock
      (vla-put-lock oLayer :vlax-true)
    )
    (if acDoc
      (progn
        (vla-endundomark acDoc)
        (vla-regen acDoc acallviewports)
      )
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (vla-startundomark
    (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
  )
  (setq oLayers (vla-get-layers acDoc))
  (vlax-for block (vla-get-blocks acDoc)
    (vlax-for x block
      (if
        (and
          (= "AcDbHatch" (vla-get-objectname x))
          (/= layerName (setq layer (vla-get-layer x)))
        )
         (progn
           (if
             (= :vlax-true
                (vla-get-lock (setq oLayer (vla-item oLayers layer)))
             )
              (progn
                (setq lock (cons oLayer lock))
                (vla-put-lock oLayer :vlax-false)
              )
           )
           (vla-put-layer x layerName)
         )
      )
    )
  )
  (*error* nil)
)

Note - You may still receive associative hatch messages for boundary objects on locked layers.


Cheers

[mikitari]

Hello!
could your lisp work upon selected blocks, instead of all in drawing?
Best regards,