Attribute Definition Copying Routine

[chris.harmon682006]

Ok... so relatively new here, so I'll apologize in advance!

What I am in search of is a Lisp routine (or other) that will copy the Tag definition of an attribute and paste the same value into the default value. Currently I have to double click the attribute, hit cntrl+c, click in the Default field and then hit cntrl+v to paste the value to the default location. If there is a faster/easier/more efficient way... I'm all ears... Thanks in advance!!!!!!


MT

[Opie]

I have no idea what you just said.

What is the purpose of copying the tag definition of an attribute to label it as the default value? How often would you use this routine?

[chris.harmon682006]

We use it for part numbers in detail blocks. I do this very frequently. If there was a faster, more efficient way of doing it, I'd be all ears.

[Tharwat]

Hi ,

I think , you can not copy the Tag definition from the Value cell but the value of the attribute unless you mean that you rewrite the value as you can see the Tag attribute straight from the Enhanced Attribute Editor .

Are you about to change all attributes in a Block ?

Something like this ?

(defun c:Test (/ s )
  (princ "\n Pick Attributed Block :")
  (if (setq s (ssget "_+.:S:E:L" '((0 . "INSERT")(66 . 1))))
    (mapcar '(lambda (u) (vla-put-textstring u (vla-get-tagstring u)))
            (vlax-invoke (vlax-ename->vla-object (ssname s 0)) 'GetAttributes))
    )
  (princ)
  )(vl-load-com)

[Coloradomrg]

Maybe I'm missing something... wouldn't redefining the block to have the tag and the default value be the same make this easier? Or does the tag somehow vary?

[tedg]

Maybe I'm missing something... wouldn't redefining the block to have the tag and the default value be the same make this easier? Or does the tag somehow vary?

I think what he's saying is sometimes the value that has been entered in the block is not the default value, and he's looking for a way to force them all to be the default value.

I may be wrong.. I think we need more info.

Like is the value going to be the same always for that block?
Or does it change per instance or project?

[greg.battin]

This LISP From Lee Lets you copy or swap text & attributes:
http://www.lee-mac.com/copytext.html

[peter]

The default value for an attribute is stored in the block definition.

Below is some code that will allow the user to create a selection set of blocks.

The routine will look at each block instance and find its block definition and create a list of sublists including the
tagstring and default textstring for each attribute.

Then it will check to see if the length of attributes in the block instance and the length of that list of sublists are equal.
It then checks to see if the tagstrings are the same.

If they are... it changes the textstring in each of the attributes to the default te.

It will not work if you have modified the attributes (number or order) after the creation of the block.

I believe that is what you asked for, or is it opposite?

P=

;___________________________________________________________________________________________________________
;
; Function for returning block attributes to default values
; Written By: Peter Jamtgaard copyright 2014 all rights reserved
;  
;___________________________________________________________________________________________________________

(defun C:Default (/ intCount entSelection lstAttributes lstDefaults objSelection ssSelections )
 (if (setq ssSelections (ssget (list (cons 0 "insert"))))
  (repeat (setq intCount (sslength ssSelections))
   (and
    (setq intCount     (1- intCount))
    (setq entSelection (ssname ssSelections intCOunt))
    (setq objSelection (vlax-ename->vla-object entSelection))
    (= (vla-get-hasattributes objSelection) :vlax-true)
    (setq lstAttributes (vlax-invoke objSelection "getattributes"))
    (setq lstDefaults   (attributedefaults objSelection))
    (defaultset objSelection)
   )
  )
 )
 (princ)
)

;___________________________________________________________________________________________________________
;
; Function for checking the tagstring and number of attributes and changing them to default values
;___________________________________________________________________________________________________________

(defun DefaultSet (objSelection)
 (or
  (and
   (= (length lstAttributes) (length lstDefaults))
   (equal (mapcar 'vla-get-tagstring lstAttributes)
          (mapcar 'car lstDefaults)
   )
   (mapcar 'vla-put-textstring lstAttributes (mapcar 'cadr lstDefaults))
  )
  (princ "\nError: The attributes have changed from the definition.")
 )
)

;___________________________________________________________________________________________________________
;
; Function for getting the tagstring and default values from a block definition
;___________________________________________________________________________________________________________

(defun AttributeDefaults (objSelection / lstOfSublists)
 (vlax-for objItem (blockdefinition objSelection)
  (and 
   (wcmatch (vla-get-objectname objItem) "AcDbAttributeDefinition")
   (setq lstOfSublists (cons (list (vla-get-tagstring objItem)(vla-get-textstring objItem)) lstOfSublists))   
  )
 )
 (reverse lstOfSublists)
)

;___________________________________________________________________________________________________________
;
; Function for getting a block definition object from the block object.
;___________________________________________________________________________________________________________


(defun BlockDefinition (objSelection / objReturn)
 (if (and (wcmatch (vla-get-objectname objSelection) 
                   "AcDbBlockReference,AcDbMInsertBlock")
          (setq objReturn (vla-item (vla-get-blocks 
                                     (vla-get-document objSelection))
                                    (vla-get-name objSelection)
                          )
          )
     )
  objReturn
 )
)

(prin1)

[peter]

If you are editing a block and want to change the default textstring of an attdef to be equal to the tagstring...

P=

(defun C:TagstringToDefault (/ intCount entSelection objSelection ssSelections )
 (if (setq ssSelections (ssget (list (cons 0 "attdef"))))
  (repeat (setq intCount (sslength ssSelections))
   (and
    (setq intCount     (1- intCount))
    (setq entSelection (ssname ssSelections intCOunt))
    (setq objSelection (vlax-ename->vla-object entSelection))
    (vla-put-textstring objSelection (vla-get-tagstring objSelection))
   )
  )
 )
 (princ)
)

[chris.harmon682006]

Thanks for the replies!! Peter NAILED IT!! That silly bit of code will save my company a tremendous amount of time! Thank you!!

Chris