Create a Selection set from Civil 3D point group or point description.

[mjfarrell]

Considering this, I would go a bit further and suggest that you use the Survey Data Base, and create unique Import Evens for the various point(s) groupings.

Two reasons, first each Import Event creates a Point Group by default.
Second the point database provides a layer of 'security' in that the points are not easily simply deleted from the file.

[BlackBox]

Well, back in the day when I used Eagle Point, I could just do a crossing window and it would grab all the points within that window and ignore all the other geometry inside the window. I think it even told you how many nodes it found, which would be handy for this new drill I'm having to do. We have a new client with new needs!

"I had way too much to say back then."........That's funny, I don't care who y'are

Something like this?

This mimics the output for the "Points_List" report.

(vl-load-com)

(defun c:ListCogo (/ *error* acDoc ss data i)

  (defun *error* (msg)
    (if ss (vla-delete ss))
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if (ssget "_:L" '((0 . "AECC_COGO_POINT")))
    (progn
      (vlax-for	x (setq	ss
			 (vla-get-activeselectionset
			   (setq acDoc (vla-get-activedocument
					 (vlax-get-acad-object)
				       )
			   )
			 )
		  )
	(setq data (cons x data))
      )
      (setq i (length data))
      (vl-sort
	data
	(function
	  (lambda (a b)
	    (< (vlax-get a 'number) (vlax-get b 'number))
	    )
	  )
	)
      (prompt
	(strcat	"\nTotal COGO Point"
		(if (< 1 i)
		  "s: "
		  ": "
		)
		(itoa i)
		"\n "
	)
      )
      (prompt "\nNumber\tNorthing  \t\tEasting\t\tElevation \t Description \n")
      (foreach x data
	(prompt
	  (strcat
	    " \n"
	    (itoa (vlax-get x 'number))
	    " \t"
	    (rtos (vlax-get x 'northing))
	    " \t"
	    (rtos (vlax-get x 'easting))
	    " \t"
	    (rtos (vla-get-elevation x))
	    " \t"
	    (vla-get-description x)
	    )
	  )
	)
      (textscr)
    )
  )

  (*error* nil)
)

** Adjust the formatting/padding as needed

[Edit] - revised to sort the points prior to output

[rickquin651723]

Good morning BlackBox. I have just revisited this thread and found that you had posted some code in an answer to some of our questions about listing points. The code you posted does EXACTLY what I was after. Thank you so much. After I found the thread and copied the code I couldn't find your post to thank you. Weird. Thanks again.

[BlackBox]

Good morning BlackBox. I have just revisited this thread and found that you had posted some code in an answer to some of our questions about listing points. The code you posted does EXACTLY what I was after. Thank you so much. After I found the thread and copied the code I couldn't find your post to thank you. Weird. Thanks again.

Happy to help

[rickquin651723]

Yes!!! That's it. perfect! Thank you, BlackBox!