Setting DimStyle

[pnorman]

Hi,
I have some experience with AutoLisp but am new to Reactors and "vla-" functions.
I want to execute the following lisp within a reactor callback:

(if (tblsearch "dimstyle" "my_dimstyle")(command "dimstyle" "restore" "my_dimstyle"))

but of course I cannot use the "command" function in a reactor.
I would like a "vla-" alternative to the above please. I think I need to use "vla-put-activedimstyle" but I cannot work out how to make it work.

Thanks
Phill

PS Here is the callback function I want to use it in:

(defun ppn_reactor_tm (ppn_reactor_name ppn_layout_name / MS_SC)
  (if (= (setq *SC* (getvar "dimscale")) 0.0)
    (setq *SC* 1)
  )
  (if (= (car ppn_layout_name) "Model")
    (progn
      (if (/= (setq MS_SC (getvar "userr1")) 0.0)
	(progn
;;; Insert dimstyle restore here
	  (setvar "dimscale" MS_SC)
	  (setq *SC* (getvar "dimscale"))
	  (setvar "ltscale" (* *SC* 7.62))
	)
	(progn
;;; Insert dimstyle restore here
	  (setvar "dimscale" *SC*)
	  (setvar "ltscale" (* *SC* 7.62))
	)
      )
    )
    (progn
      (setvar "userr1" (getvar "dimscale"))
;;; Insert dimstyle restore here
      (setvar "dimscale" 1.0)
      (setq *SC* 1.0)
      (setvar "ltscale" (* *SC* 7.62))
      (if (/= (getvar "PSLTSCALE") 1)
	(alert "PSLTSCALE is not set to 1.\nPlease check.")
      )
    )
  )
  (princ)
)

(vlr-miscellaneous-reactor
  nil
  '((:vlr-layoutSwitched . ppn_reactor_tm))
)

[Jeff_M]

Well, I didn't go through the rest of your code but this little snippet should get you going.....BTW, *doc* is a global var I use.....either set it in this routine to be the activedocument or use your own global for it.

(if (tblsearch "dimstyle" "my_dimstyle")
  (progn
    (setq dstyl (vla-item (vla-get-dimstyles *doc*) "my_dimstyle"))
    (vla-put-activedimstyle *doc* dstyl)
    )
  )

Good Luck!

[pnorman]

Well, I didn't go through the rest of your code but this little snippet should get you going.....BTW, *doc* is a global var I use.....either set it in this routine to be the activedocument or use your own global for it.

(if (tblsearch "dimstyle" "my_dimstyle")
  (progn
    (setq dstyl (vla-item (vla-get-dimstyles *doc*) "my_dimstyle"))
    (vla-put-activedimstyle *doc* dstyl)
    )
  )

Good Luck!

Thanks Miff
That worked perfectly. Here is the completed code if anyone's interested!! Not sure if it has all the necessary checks and balances but thats that... I use it in conjunction with the defun c:ds below.

Cheers
Phill

;;;
;;;
;;;
(vl-load-com)

(setq *acad-object* nil)***** ; Initialize global variable 
(setq *active-document* nil)* ; Initialize global variable 
(setq *model-space* nil)***** ; Initialize global variable 

(defun acad-object () 
 (cond (*acad-object*)****** ; Return the cached object 
** (t 
*** (setq *acad-object* (vlax-get-acad-object)) 
** ) 
 ) 
) 

(defun active-document () 
 (cond (*active-document*)** ; Return the cached object 
** (t 
*** (setq *active-document* (vla-get-activedocument (acad-object))) 
** ) 
 ) 
) 

(defun model-space () 
 (cond (*model-space*)****** ; Return the cached object 
** (t 
*** (setq *model-space* (vla-get-modelspace (active-document))) 
** ) 
 ) 
) 

(defun ppn_set_activedimstyle (my_dimstyle / my_dimstyle_ob)
  (if (tblsearch "dimstyle" my_dimstyle)
    (progn
      (setq my_dimstyle_ob (vla-item (vla-get-dimstyles (active-document)) my_dimstyle))
      (vla-put-activedimstyle (active-document) my_dimstyle_ob)
    )
  )
)

;;;
;;;   Tilemode Toggle
;;;

(defun ppn_reactor_tm (ppn_reactor_name ppn_layout_name / MS_SC)
  (if (= (setq *SC* (getvar "dimscale")) 0.0)
      (setq SC 1)
  )
  (if (= (car ppn_layout_name) "Model")
    (progn
      (if (/= (setq MS_SC (getvar "userr1")) 0.0)
	(progn
                  (ppn_set_activedimstyle "my_dimstyle_name")
	  (setvar "dimscale" MS_SC)
	  (setq *SC* (getvar "dimscale"))
	  (setvar "ltscale" (* *SC* 10))
	)
	(progn
                  (ppn_set_activedimstyle "my_dimstyle_name")
	  (setvar "dimscale" *SC*)
	  (setvar "ltscale" (* *SC* 10))
	)
      )
    )
    (progn
      (setvar "userr1" (getvar "dimscale"))
      (ppn_set_activedimstyle "my_dimstyle_name")
      (setvar "dimscale" 1.0)
      (setq *SC* (getvar "dimscale"))
      (setvar "ltscale" 10.0)
    )
  )
  (princ)
)

(vlr-miscellaneous-reactor nil '((:vlr-layoutSwitched . ppn_reactor_tm)))
;;;
;;;   end tilemode toggle
;;;
(defun c:ds ( / SC#)
  (initget 4)
  (if (setq SC# (getreal (strcat "\nEnter new value for drawing scale <" (rtos (getvar "dimscale")) ">: ")))
      (progn
        (setq *SC* SC#)
        (if (zerop *SC*) (setq *SC* 1))
      )
      (progn
        (setq *SC* (getvar "dimscale") SC# *SC*)
        (if (zerop *SC*) (setq *SC* 1))
      )
  )
  (setvar "ltscale" (* *SC* 10))
  (command "style" "ppn" "arial" (* 2.20 *SC*) "1" "10" "_n" "_n")
  (command "dimstyle" "restore" "ppn")
  (setvar "dimscale" *SC*)
  (if (= (getvar "tilemode") 1) (setvar "userr1" *SC*))
(princ)
)