Object Layers

[Berryman]

Hello.
I need help with a lisp to select objects (text, multilines, lines, polylines, etc.) From various layers and move them to other defined layers within a drawing.
E.g.
UG_CONDUIT_NEW to UG_CONDUIT_EXIST
UG_HV_NEW to UG_HV_EXIST
TEXT_2.5_NEW to TEXT_2.5_EXIST
UG_LV_NEW to UG_LV_EXIST
UG_PL_NEW to UG_PL_EXIST
UG_LVS_NEW to UG_LVS_EXIST
ASSETS_NEW to ASSETS_EXIST
I only want one selection set but includes the 7 layers with one execution.

[Tharwat]

I only want one selection set but includes the 7 layers with one execution.

Hi,

This is an example for you to get started.

(setq ss (ssget "_:L" '((0 . "LINE,MTEXT,ARC") ;; Name of objects that you'd like to select.
                        (8 . "Layer1,Layer2")  ;; Replace current example with your Layer names.
                        )
                )
      )

[devitg.89838]

Please upload a sample DWG , in ACAD 2007 or less.

[Berryman]

Thankyou for the responses.

Please see attached file Object Layers.dwg (2007).

I have copied the section of civil works so that it shows the initial drawing and then the end result (layer changes from NEW to EXIST).

Object Layers.dwg

[peter]

OK here is one way to do it.

I used the command pipe to decrease the number of library functions.

For my own code I would use a ActiveX based solution.

I like the function SelectionSetToList because LISP selection sets are a pain.

Lists of objects are much easier to manipulate using mapcar.

P=

;___________________________________________________________________________________________________________|
;
; Written By: Peter Jamtgaard copyright 2017 All Rights Reserved
;___________________________________________________________________________________________________________|
;
; Any use by unauthorized person or business is strictly prohibited.
;___________________________________________________________________________________________________________|
;
; Abstract: This routine will create various existing layers and transfer objects from the new version of the layer the the exist.
;___________________________________________________________________________________________________________|
;
; Command Line Function Header List
;___________________________________________________________________________________________________________|

;  Function and Description

;* C:ToExisting
;* Command line Function to transfer objects on a new layer to an existing layer

;* C:ToX 
;* Command line Function to transfer objects on a new layer to an existing layer
 
;___________________________________________________________________________________________________________|
;
; General Function Header List 
;___________________________________________________________________________________________________________|

;  Function, Arguments and Description

;* (SelectionSetToList ssSelections)
;* Function to convert a lisp selectionset to a list of objects

;$ End Header

;___________________________________________________________________________________________________________|
;
; Command line Function to transfer objects on a new layer to an existing layer
;___________________________________________________________________________________________________________|

(defun C:ToX ()(C:ToExisting))

(defun C:ToExisting (/ lstSublist)
 (vl-cmdf "layer" "u" "*" "")
 (foreach lstSublist (list (list "UG_CONDUIT_NEW" "UG_CONDUIT_EXIST")
                           (list "UG_HV_NEW"      "UG_HV_EXIST")
                           (list "TEXT_2.5_NEW"   "TEXT_2.5_EXIST")
                           (list "UG_LV_NEW"      "UG_LV_EXIST")
                           (list "UG_PL_NEW"      "UG_PL_EXIST")
                           (list "UG_LVS_NEW"     "UG_LVS_EXIST")
                           (list "ASSETS_NEW"     "ASSETS_EXIST")
                     )
  (if (and (vl-cmdf "layer" "m" (cadr lstSublist) "")
           (setq ssSelections (ssget (list (cons 8 (car lstSublist))))); <- revised to allow for selecting items
           (setq lstSelections (SelectionSetToList ssSelections))
      )
   (mapcar '(lambda (X)(vla-put-layer X (cadr lstSublist))) lstSelections)
  )  
 ) 
)

;___________________________________________________________________________________________________________|
;
; Function to convert a lisp selectionset to a list of objects
;___________________________________________________________________________________________________________|

(defun SelectionSetToList (ssSelections / entSelection intCount lstObjects objSelection )
 (repeat (setq intCount (sslength ssSelections))
  (and
   (setq intCount (1- intCount))
   (setq entSelection (ssname ssSelections intCount))
   (setq objSelection (vlax-ename->vla-object entSelection))
   (setq lstObjects   (cons objSelection lstObjects))
  )
 )
 lstObjects
)

(princ "!")
(vl-load-com)

[Tom Beauford]

OK here is one way to do it.

I used the command pipe to decrease the number of library functions.

For my own code I would use a ActiveX based solution.

I like the function SelectionSetToList because LISP selection sets are a pain.

Lists of objects are much easier to manipulate using mapcar.

(mapcar '(lambda (X)(vla-put-layer X (cadr lstSublist))) lstSelections)

You make this look too easy, I've put SelectionSetToList in my library.
Good reference for mapcar & lambda peter used in line 52 above: http://www.afralisp.net/autolisp/tut...and-lambda.php
Using your SelectionSetToList function I'll be using mapcar & lambda a lot more in the future.

[Tharwat]

Hi,

Here you go.

(defun c:Test (/ *error* lst doc lck sel ent get)
  ;;------------------------------------;;
  ;; Author: Tharwat - Date: 30.Jun.2017;;
  ;; Move objects from layer to another	;;
  ;; as indicated in the 'lst' variable.;;
  ;;					;;
  ;;------------------------------------;;
  (defun *error* (msg)
    (and doc (vla-endundomark doc))
    (if lck (mapcar '(lambda (u) (vla-put-lock u :vlax-true)) lck))
    (and msg (not (wcmatch (strcase msg) "*CANCEL*,*EXIT*,*BREAK*"))
      (princ (strcat "\nError =>: " msg))
    )
    (princ)
  )
  ;;				;;
  (setq lst '(("UG_CONDUIT_NEW" "UG_CONDUIT_EXIST")
              ("UG_HV_NEW" "UG_HV_EXIST")
              ("TEXT_2.5_NEW" "TEXT_2.5_EXIST")
              ("UG_LV_NEW" "UG_LV_EXIST")
              ("UG_PL_NEW" "UG_PL_EXIST")
              ("UG_LVS_NEW" "UG_LVS_EXIST")
              ("ASSETS_NEW" "ASSETS_EXIST")
             )
        doc (vla-get-activedocument (vlax-get-acad-object))
  )
  (vlax-for layer (vla-get-layers doc)
    (if (eq :vlax-true (vla-get-lock layer))
      (vla-put-lock (car (setq lck (cons layer lck))) :vlax-false)
    )
  )
  ;;				;;
  (vla-endundomark doc)
  (vla-startundomark doc)
  (if (setq sel (ssget "_X" (list (cons 8 (apply 'strcat
                                                 (mapcar (function (lambda (x) (strcat x ",")))
                                                         (mapcar 'car lst)
                                                         )
                                                 )
                                        )
                                  )
                       )
            )
    (while (setq ent (ssname sel 0))
      (entmod (subst
                 (cons 8 (cadr (assoc (cdr (assoc 8 (setq get (entget ent)))) lst)))
                 (assoc 8 get)
                 get
                 )
      )
      (ssdel ent sel)
    )
  )
  (*error* nil)
  (princ)
) (vl-load-com)

[peter]

You make this look too easy, I've put SelectionSetToList in my library.
Good reference for mapcar & lambda peter used in line 52 above: http://www.afralisp.net/autolisp/tut...and-lambda.php
Using your SelectionSetToList function I'll be using mapcar & lambda a lot more in the future.

Programming LISP is easy...

If everyone follows my AutoLISP 101 they should be able to code just as elegantly.

Later in the course I want to present my toobject and toobjects expressions which transform just about everything into objects and lists of objects.

P=

[BIG-AL]

We use the same thing but a step further with setting layer and linetypes I have a text file with around 150 names in it layold laynew colour linetype. makes setting company standards much easier and we have some dwgs that must match state authority setting so can change colours etc very easy.

[Berryman]

Tharwat, this works well however, I want to be able to select the objects.

In the drawing provided not all items change to EXIST (see top and then bottom drawing) yes, some items change but not all so I want a selection box so that the items I wish to stay as NEW can remain and the items/objects I wish to change can be selected. Does that make sense?