Rotate selected attribute to zero degrees

[cadconcepts]

Hi All
I have the following routine that use to rotate visible attributes to zero degrees. It works well but occasionally when I am in a hurry and I miss the selection it locks up my session. I would like to add the necessary code to check that something valid has been selected. I tried the following code but it did not. Any help is greatly appreciated. Thanks.
Manuel

(defun c:A0 (/ en)
(if
  (and
   (setq en (car (entsel "\nSelect attribute to rotate: ")))
   (wcmatch (cdr (assoc 0 (entget en))) "ATTRIB")
  ) 
   (command ".attedit" "" "" "" "" en "" "a" "0" "")
)
(princ)
)

[Tharwat]

Hi,

Please try the following routine that allows you to have multiple selection on Attributed blocks and ignores the invisible attributed to be rotated to zero degree.

(defun c:Test (/ sel int ent get)
  ;; Tharwat - Date: 24.04.2018	;;
  (and (princ "\nSelect attributed blocks to rotate: ")
       (setq sel (ssget "_:L" '((0 . "INSERT") (66 . 1))))
       (repeat (setq int (sslength sel))
         (setq ent (ssname sel (setq int (1- int))))
         (while (/= (cdr (assoc 0 (setq get (entget (setq ent (entnext ent)))))) "SEQEND")
           (or (= (cdr (assoc 70 get)) 1)
               (entmod (subst '(50 . 0.0) (assoc 50 get) get)))
           )
         )
       )  
(princ)
)

[cadconcepts]

Thanks Tharwat. That works nicely. Take care.
Manuel

[Tharwat]

Thanks Tharwat. That works nicely. Take care.
Manuel

You are welcome anytime Manuel.

[cadconcepts]

Hi Tharwat
Is it possible to only rotate the selected attribute? The way it is written, it changes all attributes values in a block. Thanks.
Manuel

[Tharwat]

Yeah and here you go.

(defun c:Test (/ sel int get )
  ;; Tharwat - Date: 13.09.2022		;;
  (and (princ "\nSelect attributed blocks to rotate: ")
       (setq sel (nentsel "\nPick on attribute to rotate : "))
       (or (member '(0 . "ATTRIB") (setq get (entget (car sel))))
           (alert "Invalid object selected. Try again")
           )
       (entmod (subst '(50 . 0.0) (assoc 50 get) get))
         ) 
(princ)
)

[cadconcepts]

Hi Tharwat
Thank you. I will give it a try.
Manuel