Removing "for each tab" function

[mruu88781911]

For the life of me, I can not seem to successfully remove the "for each tab" function, and make this PlotPDF for one tab (current) only.

I thought it would be so simple! Please help me, what am I missing!?

(defun C:Gen-Plot-Single-PDF (/ savepath tab dname)

			(setvar "filedia" 0)
  
	(setq savepath (strcat (getvar "DWGPREFIX") "ProgressPrints\\"))
  
	(setq PathTest (C:Gen-CreateDirectory savepath))

  	(if (= PathTest T)
	(progn  
  		(foreach tab (layoutlist)
	  		(if (= (length (layoutlist)) 1)
				(setq	dname (strcat savepath (vl-string-subst (strcat " " tab) ".dwg" (getvar "dwgname"))))
				(setq	dname (strcat savepath (vl-string-subst (strcat "-" tab) ".dwg" (getvar "dwgname"))))
			)
    			(setvar "ctab" tab)
	  					
			(command "-plot" "y" tab "DWG to PDF.pc3" "" "m" "l" "n" "l" "" "" "y" "" "y" "n" "n" "n" dname "n" "y")
			;SOLVE: if theres eror = prompt 
		)
	  );progn
	(princ "Failed to create folder path. Please create \"ProgressPrints\" file path manually in build folder")
	);if
		
  		(setvar "filedia" 1)
  	(princ)
);defun

[Tharwat]

Hi,
Something like this ?
NOTE: I don't think that you need to disable the system variable FILEDIA since you already have used the dash symbol before the plot command and this won't show the dialog in any case unless you have it for something else.

(defun C:Gen-Plot-Single-PDF (/ tab savepath PathTest dname)
  (if (= (setq tab (getvar "ctab")) "Model")
    (alert "Must be on layout tab to continue.")
    (progn
      (setvar "filedia" 0)
      (setq savepath (strcat (getvar "DWGPREFIX") "ProgressPrints\\"))
      (setq PathTest (C:Gen-CreateDirectory savepath))

      (if PathTest
        (progn
          (setq dname (strcat savepath (vl-string-subst (strcat " " tab) ".dwg" (getvar "dwgname"))))
          
         (command "-plot" "y" tab "DWG to PDF.pc3" "" "m" "l" "n" "l" "" "" "y" "" "y" "n" "n" "n" dname "n" "y")

      )
    (princ "Failed to create folder path. Please create \"ProgressPrints\" file path manually in build folder")
    ) 
      (setvar "filedia" 1)
      )
    )
  (princ)
)

[mruu88781911]

Yes Yes YEEEEESS!! Thank you so much.

Ok, I wasn't too sure how important that was either, as it seemed to work fine without it.

Thanks again!!

[BIG-AL]

This will plot a range or just 1 layout

[Tharwat]

Yes Yes YEEEEESS!! Thank you so much.

Ok, I wasn't too sure how important that was either, as it seemed to work fine without it.

Thanks again!!

Excellent.
You're most welcome.