Redefine blocks in all drawings within a directory

[jeremy.mooring705792]

Hi there,

DOes anyone know of a lisp that will redefine a particular block in all drawings within a directory?

[tedg]

Hi there,

DOes anyone know of a lisp that will redefine a particular block in all drawings within a directory?

Well I'm not an "expert" in this matter but that type of thing can be done with a script.
Basically redefining the block with the -insert command.

-insert
"OLDBLOCK=C:\NEWBLOCK.dwg"
0,0,0



erase
last

qsave

(you would use your block names and paths etc)
I you have something like ScriptPro, you can make it happen to tons of drawings.

[BlackBox]

Running Scripts within AutoCAD will process the drawings in series (one at a time).

Core Console allows for processing drawings both in series and parallel (multiple at once).

Here's a quick example that uses DOSLib to select multiple drawings for Core Console to process in parallel, just be mindful of how many drawings you choose to process at once, based on your workstation's CPU & RAM limitations:

First take at replacing BSU.

Here's the core LISP routine, which uses DOSLib to prompt for multiple drawing + .SCR (script) selection:

** Be sure to replace the text in red as needed **

(vl-load-com)

(defun c:SCRM() (c:ScriptMultiple))
(defun c:ScriptMultiple (/ app flag dwgs dwgPath script cprofile)
;;;
;;;  AcCoreConsole.exe [/i <input dwg>] /s <script>[/product <product>] [/l <language>]
;;;  [/isolate <userid> <userDataFolder>] [/readonly] [/p[rofile] <profile>] 
;;;
  (if
    (and
      (setq app (findfile "accoreconsole.exe"))
      (setq flag (dos_version))
      (setq dwgs
             (dos_getfilem
               "Select drawing(s) to process:"
               (if *Dwg_LastPath*
                 *Dwg_LastPath*
                 (getvar 'dwgprefix)
               )
               "Drawing files (*.dwg)|*.dwg||"
             )
      )
      (setq *Dwg_LastPath* (car dwgs))
      (setq dwgPath *Dwg_LastPath*)
      (setq dwgs (cdr dwgs))
      (setq script
             (dos_getfiled
               "Select a Script to run:"
               (if *Script_LastPath*
                 *Script_LastPath*
                 "C:\\ProgramData\\Autodesk\\C3D 2019\\BatchSaveTool\\Scripts"
               )
               "Script (*.scr)|*.scr||"
             )
      )
      (setq *Script_LastPath* (vl-filename-directory script))
      (setq cprofile (getvar 'cprofile))
    )
     (progn
       (foreach dwg dwgs
         (startapp
           (strcat
             "\""
             app
             "\" /i \""
             dwgPath
             dwg
             "\" /s \""
             script
             "\" /product \"C3D\" /p \""
             cprofile
             "\""
           )
         )
       )
     )
     (cond
       (dwgs (prompt "\n** No script selected ** \n"))
       (flag (prompt "\n** No drawing(s) selected ** \n"))
       (app (prompt "\n** DOSLib required ** \n"))
       ((prompt
          "\n** Unable to find \"AcCoreConsole.exe\" in support paths ** \n"
        )
       )
     )
  )
  (princ)
)

Cheers

Meaningless text so I can make this post.

[tedg]

Meaningless text so I can make this post.

LOL
Not meaningless.. you are the MAN!
Thanks for posting this here, another great option for batch running scripts.