Block attribute prefill LISP stops in ACAD2019

[kelvin_lloyd]

Hi All,

I've had a great lisp for a few years that has worked really well.
The LISP is built on Jimmy Bergmark's AreaText LISP, but attached the area values to a block instead.

Just upgraded from ACAD2015 to ACAD2019 and it now gets stuck at the final step of attaching attributes to the block (line ~74 in the code).

Does anyone have any ideas whats wrong?

Cheers,
KJ

[Tharwat]

Hi,
Try to replace the command call command with vl-cmdf function.

[kelvin_lloyd]

Thanks Tharwat,
The attributes are still not associated with the block though,

From the command line the output reads:

CAT
start number=6
Select object:
Select Drop Point --> Unknown command "C6". Press F1 for help.
Unknown command "AREA \F "%LU6%QF1%PS[,HA]%CT8[0.0001]">%". Press F1 for help.

[Tharwat]

Actually the routine can be written in entirely different way than that but let me ask you the following.

Firstly. Are you sure is that the path is correct?

Secondly. What is the name of the attributed block? Is it Label1 ?

[kelvin_lloyd]

Ok, that's interesting
Yes, i can confirm the path is correct. The block and DWG name is "CATCHMENT LABEL1"

[Tharwat]

The path of a drawing should have either two back slashes ( \\ ) or one forward slash ( / ) so this indicates is that your path of the drawing is incorrect .

Can you upload that attributed block drawing if its not confidential or just let me know what is the name of tag that should have the incremental number and what is the tag name for the field object as well?

It seems that your attributed block has two attributes. Right?

[kelvin_lloyd]

Yep, two attributes, The NAME and AREA

The block is here:
https://1drv.ms/u/s!AgeAUPaXe78uiIk9...KHTfQ?e=VHfCzU

The block does load, so im sure the address is correct. Its my understanding the single backslash is to denote a space in the address

[Tharwat]

Alright, please try the following program and let me know how you get on with it.

Be sure to have the current layer unlocked although I can alert message to the user for this issue if you would like to.

(defun c:Test (/ *error* var sel blk ins pth)
  ;;	Tharwat - 24.Oct.2019		;;
  (defun *error* (msg)
    (and var (mapcar 'setvar '(ATTREQ ATTDIA) var))
    (and *doc* (vla-regen *doc* AcActiveviewport))
    (and msg
         (not (wcmatch (strcase msg) "*CANCEL*,*EXIT*,*BREAK*"))
         (princ (strcat "\nError =>: " msg))
    )
    (princ)
  )
  (and
    (or (findfile (setq pth
                         "U:\\MANUALS\\CIVIL_QLD\\CAD\ Standard\ Data\\Stormwater\\Blocks\\Catchment Label1.dwg"
                  )
        )
        (alert "Path of block is uncorrect <!>")
    )
    (or *doc*
        (setq *doc* (vla-get-ActiveDocument (vlax-get-acad-object)))
    )
    (or
      (tblsearch "BLOCK" "CATCHMENT LABEL1")
      (and (setq blk (vlax-invoke
                       (vla-get-modelspace *doc*)
                       'insertblock
                       '(0. 0. 0.)
                       pth
                       1.
                       1.
                       1.
                       0.
                     )
           )
           (progn (vla-delete blk)
                  (tblsearch "BLOCK" "CATCHMENT LABEL1")
           )
      )
      (alert
        "Block name <CATCHMENT Label1> not found in original drawing <!>"
      )
    )
    (or *initdgt* (setq *initdgt* 1))
    (or (initget 6)
        (setq
          *initdgt* (cond ((getint (strcat "\nSpecify start number < "
                                           (itoa *initdgt*)
                                           " > : "
                                   )
                           )
                          )
                          (*initdgt*)
                    )
        )
    )
    (setq var (mapcar 'getvar '(ATTREQ ATTDIA)))
    (mapcar 'setvar '(ATTREQ ATTDIA) '(0 0))
  )
  (while (and (princ "\nPick a closed polyline : ")
              (setq sel (ssget "_+.:S:E" '((0 . "LWPOLYLINE"))))
         )
    (and
      (or (= (cdr (assoc 70 (entget (ssname sel 0)))) 1)
          (alert "Picked polyline is opened!. Try again.")
      )
      (setq
        ins (getpoint "\nSpecify attributed block insertion point : ")
      )
      (setq blk (vlax-invoke
                  (vla-get-modelspace *doc*)
                  'insertblock
                  ins
                  "CATCHMENT LABEL1"
                  1.
                  1.
                  1.
                  0.
                )
      )
      (mapcar
        '(lambda (at)
           (vla-put-textstring
             at
             (if (= (vla-get-tagstring at) "NAME")
               (strcat "C" (itoa *initdgt*))
               (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                       (get:id (vlax-ename->vla-object (ssname sel 0)))
                       ">%).Area \\f \"%lu6%qf1%ps[,ha]%ct8[0.0001]\">%"
               )
             )
           )
         )
        (vlax-invoke blk 'getattributes)
      )
      (setq *initdgt* (1+ *initdgt*))
    )
  )
  (*error* nil)
  (princ)
) (vl-load-com)
;;		;;
(defun get:id (o / u)
  (if (vlax-method-applicable-p
        (setq u (vla-get-Utility *doc*))
        'GetObjectIdString
      )
    (vla-GetObjectIdString u o :vlax-false)
    (itoa (vla-get-ObjectId o))
  )
)

[kelvin_lloyd]

Thats awesome!
Thanks so much, works great!

Where would you add a prefix "C" to the name?

[Tharwat]

Thats awesome!
Thanks so much, works great!

Excellent, You're welcome anytime.

Where would you add a prefix "C" to the name?

Oops, I updated the codes above and added the prefix 'C' char.