Rotate multiline text to viewport orientation

[tim_newsome]

How do I get multiline text to rotate to viewport orientation?

[Tom Beauford]

Try: https://www.cadtutor.net/forum/topic...comment-557172
or https://forums.augi.com/showthread.p...=1#post1332928

My macro for "Mtext 0 width"

^C^C_mtext;\r;(/ (* 180 (- (getvar "viewtwist"))) pi);w;0

creates it Horizontal in TWisted Viewports.

[tim_newsome]

Tom,

Does Macro mean it could be created as a command?

I entered this as a new Macro (command in CUI), and its telling me I dont have permission to. It looks as though its trying to write to a sub directory I don't have. Is there a way to change that to something current on my C: drive?

[Tom Beauford]

Tom,

Does Macro mean it could be created as a command?

I entered this as a new Macro (command in CUI), and its telling me I don't have permission to. It looks as though its trying to write to a sub directory I don't have. Is there a way to change that to something current on my C: drive?

You have to first add it as a command in the CUI then add it either to a Ribbon Panel or a Toolbar. It's not a command you can enter from the Command line:

It uses lisp so it would have to be modified to work with a LT version.

I don't have a LT version to check, but this macro using DIESEL works for me:

^C^C_mtext;\r;$M=$(/,$(*,$(-,0,$(getvar,viewtwist)),180),3.14159265359);w;0

It should work in a LT version. Had to enter 3.14159265359, PI wouldn't work.

[MMccall]

I hop into the viewport, set the UCS to View, select the multiline text and give it a rotation of 0 in the properties window. The rotation is relative to the viewport.

[Tom Beauford]

I hop into the viewport, set the UCS to View, select the multiline text and give it a rotation of 0 in the properties window. The rotation is relative to the viewport.

Ideal for many users, certainly what I'd use if I could! Could cause serious issues for those of us doing Civil, Survey, Map, or other work fixed to World or specific coordinate systems.

[MMccall]

I'm in civil and I've been doing it that way for 14 yrs. Obviously never insert anything into model space through the viewport that needs the correct coordinated system after its been set to View. (like insert points, north arrows, xrefs) Do those things in the real Model space as it remains as it was with the UCS set to world.

[BlackBox]

I'm in civil and I've been doing it that way for 14 yrs. Obviously never insert anything into model space through the viewport that needs the correct coordinated system after its been set to View. (like insert points, north arrows, xrefs) Do those things in the real Model space as it remains as it was with the UCS set to world.

I too work in Civil, though all of my drawings are in World UCS in Model and through Viewports; I simply 'twist' my Viewports as needed for that sheet (using a LISP that uses DVIEW + SNAPANG), so it doesn't matter what tab is active, I can always insert or copy + paste between drawings and all of my new annotations, etc are aligned with the sheet.

[Tom Beauford]

I too work in Civil, though all of my drawings are in World UCS in Model and through Viewports; I simply 'twist' my Viewports as needed for that sheet (using a LISP that uses DVIEW + SNAPANG), so it doesn't matter what tab is active, I can always insert or copy + paste between drawings and all of my new annotations, etc are aligned with the sheet.

While probably not as elegant as your lisp I've been using this macro for many years:

^C^C_dview;all;;tw;\;^P(progn(setvar "snapang" (- (getvar "viewtwist")))(princ))

With the attached image ViewTwist.png which I was able to create easily with your code.

[BlackBox]

While probably not as elegant as your lisp I've been using this macro for many years:

^C^C_dview;all;;tw;\;^P(progn(setvar "snapang" (- (getvar "viewtwist")))(princ))

Here's an old post from 2013; I've only made some minor enhancements to since:

... would you mind sharing

Not at all; here's mine... Take from this what you like:

(vl-load-com)
;;;--------------------------------------------------------------------;
;;; Twist dview function:
(defun c:TW () (c:TWIST))
(defun c:TWIST (/ *error* RTD cmdecho osmode pt1 pt2 acDoc ang)
  (prompt "\rTWIST")

  (defun *error* (msg)
    (and cmdecho (setvar 'cmdecho cmdecho))
    (and osmode (setvar 'osmode osmode))
    (if acDoc
      (vla-endundomark acDoc)
    )
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (defun RTD (ang) (/ (* ang 180.0) pi))

  (if (and (setq cmdecho (getvar 'cmdecho))
           (setvar 'cmdecho 0)
           (setq osmode (getvar 'osmode))
           (setvar 'osmode 512)
           (setq pt1 (getpoint "\nSpecify start point (left): "))
           (not (initget 32))
           (setq pt2 (getpoint pt1 "\nSpecify end point (right): "))
      )
    (progn
      (vla-startundomark
        (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
      )
      (command "._dview"
               "l"
               ""
               "PO"
               "@0,0,0"
               "@0,0,1"
               ""
               "._dview"
               "l"
               ""
               "tw"
               (- 360 (RTD (setq ang (angle pt1 pt2))))
               ""
      )
      (setvar 'snapang ang)
    )
  )
  (*error* nil)
)
;;;--------------------------------------------------------------------;
;;; Untwist dview function:
(defun c:UTW () (c:UNTWIST))
(defun c:UNTWIST (/ *error* cmdecho acDoc)
  (prompt "\rUNTWIST")

  (defun *error* (msg)
    (if acDoc
      (vla-endundomark acDoc)
    )
    (and cmdecho (setvar 'cmdecho cmdecho))
    (cond ((not msg))                                                   ; Normal exit
          ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
          ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
    )
    (princ)
  )

  (if (and (setq cmdecho (getvar 'cmdecho))
           (setvar 'cmdecho 0)
      )
    (progn
      (vla-startundomark
        (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
      )
      (command "._dview" "l" "" "tw" 0 "" "._UCS" "W")
      (setvar 'snapang 0)
    )
  )
  (*error* nil)
)

[Edit]

With the attached image ViewTwist.png which I was able to create easily with your code.

You mean the PNGOUTT (aka PNGOUT Transparent) app from a while back?

That's awesome!

[/Edit]

Cheers