extract linear parameter length from dynamic block

[Tharwat]

I have completed the codes for you but you need to modify it to suit your needs since that I don't know what you are trying to do with the return value from the LENGTH attribute besides that the alert message which is not logic in this case I believe.

So just ask if you stuck.

NOTE: I could not open your drawing since it's saved in later release than mine CAD 2017.

(defun c:penrodcount (/ blks num blk effname unsup)
  (if (setq blks (ssget (list (cons 0 "insert") (cons 2 "`*U*,Pencil Rod") (cons 8 "TIE - Pencil Rod"))))
    (progn                                         
      (repeat (setq num (sslength blks))
        (setq blk (vlax-ename->vla-object (ssname blks (setq num (1- num)))))
        (setq effname (vla-get-EffectiveName blk))
        (cond ((= effname "Pencil Rod") (Get:param:value blk)) ;; you need to assign the value to a variable to use it elsewhere you like in the codes.
              (t (setq unsup effname)) 
        )                       
      )                       
    )                         
  )                           
  (if unsup (alert (strcat "Unsupported block  " unsup "  found in count process")))
  (princ)
  )

(vl-load-com)

(defun Get:param:value (blk / val)
  ;; blk = Block reference vla-object.	;;
  (vl-some '(lambda (x)
              (and (= (strcase (vla-get-propertyname x)) "LENGTH")
                   (setq val (vlax-get x 'Value))
              )
            )
           (vlax-invoke blk 'getdynamicBlockproperties)
  )
  val
)

[aaronashley1977783620]

I have completed the codes for you but you need to modify it to suit your needs since that I don't know what you are trying to do with the return value from the LENGTH attribute besides that the alert message which is not logic in this case I believe.

So just ask if you stuck.

NOTE: I could not open your drawing since it's saved in later release than mine CAD 2017.

(defun c:penrodcount (/ blks num blk effname unsup)
  (if (setq blks (ssget (list (cons 0 "insert") (cons 2 "`*U*,Pencil Rod") (cons 8 "TIE - Pencil Rod"))))
    (progn                                         
      (repeat (setq num (sslength blks))
        (setq blk (vlax-ename->vla-object (ssname blks (setq num (1- num)))))
        (setq effname (vla-get-EffectiveName blk))
        (cond ((= effname "Pencil Rod") (Get:param:value blk)) ;; you need to assign the value to a variable to use it elsewhere you like in the codes.
              (t (setq unsup effname)) 
        )                       
      )                       
    )                         
  )                           
  (if unsup (alert (strcat "Unsupported block  " unsup "  found in count process")))
  (princ)
  )

(vl-load-com)

(defun Get:param:value (blk / val)
  ;; blk = Block reference vla-object.	;;
  (vl-some '(lambda (x)
              (and (= (strcase (vla-get-propertyname x)) "LENGTH")
                   (setq val (vlax-get x 'Value))
              )
            )
           (vlax-invoke blk 'getdynamicBlockproperties)
  )
  val
)

Thanks, Tharwat! I am getting a result from your code, so I think i can integrate that into what I'm doing. If I get stuck, I'll be back. Thanks again! Cheers, -Aaron

[Tharwat]

Thanks, Tharwat! I am getting a result from your code, so I think i can integrate that into what I'm doing. If I get stuck, I'll be back. Thanks again! Cheers, -Aaron

You're welcome anytime Aaron.

Feel free to ask whenever you need any further help.

Have a nice day.

[avocado]

ok, I made that change, and now it says ; error: too many arguments

try this

(defun pen-rod-count ( / blks val i)
  (setq blks (ssget "X" (list (cons 0 "insert") (cons 8 "TIE - Pencil Rod"))))
  (setq i 0)

  (repeat (sslength blks)
    (if
      (setq val (get:param:value (vlax-ename->vla-object (ssname blks i))))
      (princ (strcat "\n" (rtos val 4 2)))) ;end if

  (setq i (+ i 1)))) ;end defun

I used ssget "X" for testing purpose only

[Tharwat]

try this

I used ssget "X" for testing purpose only

Hi,
If the ssget returned nil then your routine would end with an error.

[aaronashley1977783620]

I was successful in creating a program that fulfilled its purpose! Thanks again Tharwat! But, now I have another program that is trying to do something related, but different. Instead of getting the Length value of a dynamic block, I'm trying to SET the value. I want to insert the dynamic block, and then (setq obj (entlast)) and somehow set the length property of the object to a pre-determined length.

[Tharwat]

Hi,
Is your dynamic block attributed ? and what is the name of your block ?

[aaronashley1977783620]

Hi,
Is your dynamic block attributed ? and what is the name of your block ?

This particular block doesn't have attributes. The name of the block is "15mm DWYIDAG Rod" I've attached a screenshot for clarity. Thanks!

dywidag.png

[Tharwat]

Here is an example for you to move on with your program.

(defun c:Test (/ ins blk)
  (if
    (and
      (or
	(tblsearch "BLOCK" "15mm DWYIDAG Rod")
	(alert
	  "Block name <15mm DWYIDAG Rod> wasn't found in this drawing <!>"
	)
      )
      (setq ins (getpoint "\nSpecify insertion point : "))
      (setq blk	(entmakex (list	'(0 . "INSERT")
				(cons 10 ins)
				(cons 2 "15mm DWYIDAG Rod")
				'(41 . 1.0)
				'(42 . 1.0)
				'(43 . 1.0)
			  )
		)
      )
    )
     (Set:param:value (vlax-ename->vla-object blk) 10.0) 
  )
  (princ)
)

(vl-load-com)

(defun Set:param:value (blk len / val)
  ;; blk = Block reference vla-object.	;;
  ;; len = Length value.		;;
  (vl-some '(lambda (x)
	      (and (= (strcase (vla-get-propertyname x)) "LENGTH")
		   (progn (vlax-put x 'Value len) t)
	      )
	    )
	   (vlax-invoke blk 'getdynamicBlockproperties)
  )
)

[aaronashley1977783620]

Thanks Tharwat, I'll let you know if I run into problems!