Leaders on layer share

[madcadder]

I got really tired of my leaders not being on my dimensions layer, so I put this together.
Not sure if something similar has been shared, so here it is...
I put it in my acaddoc
If you can make it function better let me know.

;;;
;;; Leaders on "Dimensions" layer reactor
;;;

(IF (NOT |leader_reactor|)
  (SETQ	|leader_reactor| (VLR-COMMAND-REACTOR nil
	   '((:VLR-COMMANDWILLSTART . startleadercommand)
	     (:VLR-COMMANDENDED . endleadercommand)
	     (:VLR-COMMANDCANCELLED . cancelleadercommand)
	    )
	 )
  )
)

(DEFUN startleadercommand (calling-reactor startcommandinfo / |commandstart|)
  (SETQ |leader_clayer| (GETVAR "clayer"))
  (SETQ |commandstart| (CAR startcommandinfo))
  (IF (OR (= |commandstart| "LEADER")
	  (= |commandstart| "MLEADER")
	  (= |commandstart| "QLEADER")
      )
    (SETVAR "clayer" "DIMENSIONS")
  )
  (PRINC)
)

(DEFUN endleadercommand	(calling-reactor endcommandinfo / |commandend|)
  (SETQ |commandend| (CAR endcommandinfo))
  (IF (OR (= |commandend| "LEADER")
	  (= |commandend| "MLEADER")
	  (= |commandend| "QLEADER")
      )
    (SETVAR "clayer" |leader_clayer|)
  )
  (PRINC)
)

(DEFUN cancelleadercommand (calling-reactor cancelcommandinfo / |commandcancel|)
  (SETQ |commandcancel| (CAR cancelcommandinfo))
  (IF (OR (= |commandcancel| "LEADER")
	  (= |commandcancel| "MLEADER")
	  (= |commandcancel| "QLEADER")
      )
    (SETVAR "clayer" |leader_clayer|)
  )
  (PRINC)
)

[Tom Beauford]

Lee Mac has one for directing objects created from AutoCAD commands to layers you specify. http://www.lee-mac.com/layerdirector.html