Datalinkupdate

[madcadder]

I want to put something like this in my ACADDOC, but it needs more than I know where to look to make it correct.
It would need a conditional statement to only run in there is a datalink in the drawing.
I can do the conditional statement, I can't do the drawing search for if one is in the drawing.
Help please...

Right now, my hammer method runs the command, tells me there isn't one in the current drawing, and then tries to run the "k" command (which there isn't one)

(COMMAND "_.datalinkupdate" "u" "k") ; u - Update datalink, k - all linKs

[BlackBox]

(defun c:FOO ()
  (vlax-for x (vla-get-dictionaries
		(vla-get-activedocument (vlax-get-acad-object))
	      )
    (if
      (and
	(vlax-property-available-p x 'name)
	(= "ACAD_DATALINK" (vla-get-name x))
	(< 0 (vla-get-count x))
      )
       (command "_.datalinkupdate" "_u" "_k")
    )
  )
  (princ)
)

[madcadder]

Thank ya sir.
Well, they made that one pretty obvious in name.

[framedNlv]

This is what I've been using:

(setq datalinkDict (dictsearch (namedobjdict) "ACAD_DATALINK"))
(if datalinkdict (command "DATALINKUPDATE" "u" "k"))
(princ)
)

[BlackBox]

This is what I've been using:

(setq datalinkDict (dictsearch (namedobjdict) "ACAD_DATALINK"))
(if datalinkdict (command "DATALINKUPDATE" "u" "k"))
(princ)
)

The ACAD_DATALINK dictionary can exist in a drawing without any datalinks (empty); simply create a new datalink, save the drawing, then right click & delete datalink (dictionary is still there).

Instead, consider:

(defun c:FOO2 (/ )
  (if (assoc 3 (dictsearch (namedobjdict) "ACAD_DATALINK"))
    (command "_.datalinkupdate" "_u" "_k")
  )
  (princ)
)