Lisp error?

[Wdobbin]

I have a .lsp that assigns Xref's to a layer when certain commands are carried out. the routine seems to work fine however there is an warning displayed each time - error: AutoCAD variable setting rejected: "clayer" nil.

would someone be able to advise on how to fix this, thanks in advance.

see below code

(if (null myxr-react)
(setq myxr-react (vlr-command-reactor nil '((:vlr-commandwillstart . myxr-swaplayer)
(:vlr-commandended . myxr-restorelayer)
(:vlr-commandcancelled . myxr-restorelayer))))
)

(defun setormakelayer (layn doc)
(if (null (tblsearch "layer" layn))
(vla-add (vla-get-layers doc) layn))
(setvar "clayer" layn)
)

;;commandwillstart callback (reactor commandlist)
(defun myxr-swaplayer (r cl / doc)
(if (wcmatch (strcase (car cl)) "*ATTACH,*XCLIP*,*XREF");allowance for other commands
(progn
(setq doc (vlr-document r))
(vlr-data-set r (getvar "clayer"))
(if
(= 1 (vla-get-activespace doc))
(setormakelayer "_XREF" doc)
(setormakelayer "_XREF" doc)
))))

;;commandended callback (reactor commandlist)
(defun myxr-restorelayer (r cl)
(if (wcmatch (strcase (car cl)) "*ATTACH,*XCLIP*,*XREF");allowance for other commands
(vlr-data r))
(setvar "clayer" (vlr-data r))
(vlr-data-set r nil)
)
)

[marko_ribar]

Here you are...
I simplified it very much :

(vlr-remove-all)

(if (null myxr-react)
  (setq myxr-react (vlr-command-reactor nil
  '((:vlr-commandwillstart . myxr-swaplayer)
    (:vlr-commandended . myxr-restorelayer)
    (:vlr-commandcancelled . myxr-restorelayer)
   )
  ))
)

(defun setormakelayer (layn doc / oldlay)
  (if (null (tblsearch "layer" layn))
    (vla-add (vla-get-layers doc) layn)
  )
  (setq oldlay (getvar "clayer"))
  (setvar "clayer" layn)
  oldlay
)

;;commandwillstart callback (reactor commandlist)
(defun myxr-swaplayer (r cl / doc)
  (if (wcmatch (strcase (car cl)) "*ATTACH,*XCLIP*,*XREF");allowance for other commands
    (progn
      (setq doc (vlr-document r))
      (setq oldlay (setormakelayer "_XREF" doc))
    )
  )
)

;;commandended callback (reactor commandlist)
(defun myxr-restorelayer (r cl)
  (if oldlay
    (progn
      (setvar "clayer" oldlay)
      (setq oldlay nil)
    )
  )
)

HTH.