Delete a group of named layout tabs using a wildcard

[cadd4la]

Hi, everyone,

I'm in need of help deleting a group of named layout tabs in a file. I have a number of layout tabs with different names and they either ended with -24x36 or -30x42. (i.e LC-601-24x36 or LC-601-30x42). I would like to use a wildcard to delete either all the -24x36 or -30x42 tabs in the file at once.

I've tried writing code but it will not delete any of the tabs unless I use the full name and list all the tabs that need to be deleted.

(defun c:DELT30x42()
(SETVAR "CMDECHO" 0)
(command "undo" "begin")
(command "_Layout" "Set" "Model")
(command "_.layout" "_d" "*-30x42")
(command "undo" "end")
(SETVAR "CMDECHO" 1)
(princ))

Thanks,

Cadd4la

[BIG-AL]

Maybe

(defun c:DELT30x42()
(SETVAR "CMDECHO" 0)
(command "undo" "begin")
(setvar 'ctab "Model")
(vlax-for lay (vla-get-Layouts (vla-get-activedocument (vlax-get-acad-object)))
  (setq plotabs (cons (vla-get-name lay) plotabs))
)
(foreach lay plotabs
(if (and (/= lay "Model")
         (wcmatch lay "*30x42*"))
(command "_.layout" "_d" lay)
)
)
(command "undo" "end")
(SETVAR "CMDECHO" 1)
(princ)
)

[Tom Beauford]

May be what you're looking for: https://forums.autodesk.com/t5/visua...s/td-p/8746085

[cadd4la]

BIG-AL,

Thank you for your help, unfortunately, the code is not working for me, when I run it just lists the following.

Initializing...
Initializing...
Initializing...
Initializing...
Initializing...
Initializing...
it keeps going with Initializing... until I press the ESC key.

Also, can the code let me select either the 24x36 or 30x42 tabs in the same code?

Cadd4la

- - - Updated - - -

May be what you're looking for: https://forums.autodesk.com/t5/visua...s/td-p/8746085

Tom,

Thank you as always for your input. The code is above my skill level to modify what I need it to do.

This is as far as I can go.

(defun c:TABS ( / size oppLR ABC flag otherItems o)
(initget 1 "24x36 30x42") (setq size (getkword "\n24x36 or 30x42? [24x36/30x42]"))
(if (eq "Left" LR) (setq LR "LH" oppLR "RH") (setq LR "RH" oppLR "LH"))
(setq otherItems (list "SALE" "COVER" "SHEET 6"));<-- add more items in quotes here
(setq flag nil)
(foreach l (layoutlist)
  (if (and (not (or (wcmatch (strcase l) (strcat "*(" size ")*"))
		    (wcmatch (strcase l) (strcat "*(" ABC "-" LR ")*"))))
	   (or (wcmatch (strcase l) (strcat "*" oppLR "*"))
	       (wcmatch (strcase l) (strcat "*-" LR "*"))))
      (setq flag t)
  );if
  (foreach o otherItems
    (if (wcmatch (strcase l) (strcat "*" (strcase o) "*"))
      (setq flag t)
    );if
  );foreach
  (if flag
    (command "-LAYOUT" "_d" l)
  );if
  (setq flag nil)
);foreach
(prompt "\nComplete...")
(princ)
);defun

Cadd4la

[BIG-AL]

You have confused me by adding all sorts of stuff in code that does not make sense. Did you try just my code with layouts that have -30x42.

(defun c:DELlay ( / lay size plotabs)
(SETVAR "CMDECHO" 0)
(command "undo" "begin")
(setvar 'ctab "Model")

(initget 1 "24x36 30x42") (setq size (getkword "\n24x36 or 30x42? [24x36/30x42]"))

(vlax-for lay (vla-get-Layouts (vla-get-activedocument (vlax-get-acad-object)))
  (setq plotabs (cons (vla-get-name lay) plotabs))
)
(foreach lay plotabs
(if (and (/= lay "Model")
         (wcmatch lay size))
(command "_.layout" "_d" lay)
)
)
(command "undo" "end")
(SETVAR "CMDECHO" 1)
(princ)
)

[cadd4la]

BIG-AL,

Sorry for the confusion, the code I posted was for Tom and a reply to the link he posted and not for you.

That said, your code is not working, when I run your code it will change to the model tab and list the 24x36 or 30x42 for me to select but after I select one of them it does nothing.

Please remember from my first post.

I have a number of layout tabs with different names and they either ended with -24x36 or -30x42. (i.e LC-601-24x36 or LC-601-30x42). I would like to use a wildcard to delete either all the -24x36 or -30x42 tabs in the file at once.

I don't have any tabs in the file with just -24x36, -30x42, 24x36, or 30x42.

Cadd4la

[Opie]

Try this

(defun c:DeleteLayouts (/ DeleteTheseLayouts TriggerName)
  ;; Initialize user input options
  (initget 1 "24x36 30x42")
  ;; Request user input
  (setq TriggerName (getkword "\n24x36 or 30x42? [24x36/30x42]"))
  ;; Set current layout to the Model tab
  (setvar 'ctab "Model")
  ;; Cycle through all of the layouts
  (vlax-for layout (vla-get-layouts
                     (vla-get-activedocument (vlax-get-acad-object))
                   )
    ;; If not the model layout tab
    (if (not (= (vla-get-name layout) "Model"))
      ;; If trigger name is found
      (if (and (vlax-property-available-p layout 'name)
               (wcmatch (strcase (vla-get-name layout))
                        (strcat "*" (strcase TriggerName) "*")
               )
          )
        ;; Delete this layout
        (vl-catch-all-apply 'vla-delete (list layout))
      )
    )
  )
)

[cadd4la]

Opie,

It works great. thanks for your help.

Cadd4la

[BIG-AL]

I tested against layout1 layout2 -> etc i just looked for "out" it may be a caps problem with X. Just looked yes its case sensitive. 30X42 is different to 30x42 so strcase it.

(defun c:DELT30x42()
(SETVAR "CMDECHO" 0)
(command "undo" "begin")
(setvar 'ctab "Model")
(vlax-for lay (vla-get-Layouts (vla-get-activedocument (vlax-get-acad-object)))
  (setq plotabs (cons (vla-get-name lay) plotabs))
)
(foreach lay plotabs
(if (and (/= lay "Model")
         (wcmatch (strcase lay) "*30X42*"))
(command "_.layout" "_d" lay)
)
)
(command "undo" "end")
(SETVAR "CMDECHO" 1)
(princ)
)