rotate function in lisp not working, but worked in older version

[Hammer.John.J]

This lisp routine I have used for ages but skipped a view versions and I'm trying to use with 2018 and 2021 is no longer functioning as it used to. The expected functionality is during the block placement, we pick a second point using the nearest osnap to align the block with the line so that the block is aligned with 2nd point we pick and then the block is inserted. Any help is greatly appreciated.

;|Routine to label contours drawn by Line/Arc/Polyline. Originally penned by
  CiphDRMRS, aka T.Willey, on the AUGI Forums. Modified by Jeff Mishler.
  An assumption is made that a valid block with 1 attribute is selected.
  |;
(vl-load-com)

(defun c:CLB ( / *error* osz atq atd cmd e p)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if osz (setvar 'osnapz osz))
    (if atq (setvar 'attreq atq))
    (if atd (setvar 'attdia atd))
    (if cmd (setvar 'cmdecho cmd))
    (princ))
  
  
  (setq osz (getvar 'osnapz))  	(setvar 'osnapz 0)
  (setq atq (getvar 'attreq))   (setvar 'attreq 0)
  (setq atd (getvar 'attdia))   (setvar 'attdia 0)
  (setq cmd (getvar 'cmdecho))  (setvar 'cmdecho 0)
  
  (while (and (setq p (getpoint "\nPlace a label: "))
	      (setq e (car (nentselp p))))
    
    (command "_.insert" "CL3-20"
	     "_S" 1
	     "_R" (angtos (angle '(0 0 0) (vlax-curve-getFirstDeriv e (vlax-curve-getParamAtPoint e (vlax-curve-getclosestpointto e p)))) (getvar 'aunits) 8)
	     "_nea" p)
    (setpropertyvalue (entlast) "CLAB" (rtos (last p) 2 0)))
  (*error* "end")
  )

[Ed Jobe]

You might also want to attach a dwg that is set up for testing.

[Tom Beauford]

There's been a lot of changes to the INSERT command in recent years, looking at the help links below it may be hard to modify the lisp to work in both 2018 and 2022.

2018 INSERT (Command)

2022 INSERT (Command)

2022 -INSERT (Command)

2022 CLASSICINSERT (Command)

[Tom Beauford]

You might also want to attach a dwg that is set up for testing.

I have a routine that labels contour elevations with multiline text with a background mask scaled to current annotation scale.
It uses the Civil 3D command for Civil 3D contours, polyline elevations if they have them, and Elevation data if they were imported with Map 3D.

Like Ed Jobe said we'd have to have a drawing we could test on.

[Hammer.John.J]

example attached
also i edited my post, i need it for 2021 which is the same dwg format as 2018, thanks.

we cannot use background masks because of the mixing of grays through a myriad of xrefs, we need to use wipeouts and linesmerge thanks

[Ed Jobe]

also i edited my post, i need it for 2021 which is the same dwg format as 2018, thanks.

All the way to current 2023, the dwg format is still the same. What has changed are the command prompts. Different options.

[Tom Beauford]

we cannot use background masks because of the mixing of grays through a myriad of xrefs, we need to use wipeouts and linesmerge thanks

I've attached a modified drawing with two examples using multiline text with background masks set, one of them has the frame turned on.

How would background masks display differently than wipeouts? Having to add a block complicates things.

Going home now, have a nice weekend!

[Bruno.Valsecchi]

Maybe by editing your block.
Keep the attribute, modify or create a multiline style with an offset of 0.9 and -0.9 and having outgoing arcs at the ends and a fill color of 255,255,255.
With this type of multiline, simply draw a horizontal line on your attribute definition, if necessary put the drawing of it back in the foreground...

[Tharwat]

Please try the following complete program and you need to specify your attributed block name as specified in the codes below.
NOTE: The tag string that the program targets is the same one you have used into your posted codes so once you change the name of the attributed block then you need to change it as well if it is not matching to "CLAB".

(defun c:CLB (/ *error* bkn var val spc ins blk sel ent)
  ;; Tharwat Al Choufi.	- Date: 06.Aug.2022		;;
  ;; website: https://autolispprograms.wordpress.com	;;
  (defun *error* (msg)
    (and val (mapcar 'setvar var val))
    (and msg
         (not (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
         (princ (strcat "\nError => " msg))
    )
    (princ)
  )
  ;;				;;
  (setq bkn "CL2-20") ;; <<< specify your desired Attributed block name here.
  ;;				;;
  (and
    (or (tblsearch "BLOCK" bkn)
        (alert (strcat "Block name < " bkn " > was not found <!"))
    )
    (setq var '(osnapz attreq attdia)
          val (mapcar 'getvar var)
          spc (vlax-get (vla-get-activelayout
                          (vla-get-activedocument (vlax-get-acad-object))
                        )
                        'Block
              )
    )
    (mapcar 'setvar var '(0 0 0))
    (while
      (and
        (setq ins
               (getpoint
                 "\nSpecify a point on Line, Polyline object to place a label <enter to exit> : "
               )
        )
        (or (and
              (setq sel (ssget ins))
              (wcmatch (cdr (assoc 0 (entget (setq ent (ssname sel 0)))))
                       "LINE,LWPOLYLINE"
              )
            )
            (alert "Could not detect any Line & LWpolyline object <!>")
        )
      )
       (setq blk (vlax-invoke
                   spc
                   'insertblock
                   (vlax-curve-getclosestpointto ent ins)
                   bkn
                   1.
                   1.
                   1.
                   (angle '(0 0 0)
                          (vlax-curve-getFirstDeriv
                            ent
                            (vlax-curve-getParamAtPoint
                              ent
                              (vlax-curve-getclosestpointto ent ins)
                            )
                          )
                   )
                 )
       )
       (foreach att (vlax-invoke blk 'getattributes)
         (and (= (vla-get-tagstring att) "CLAB")
              (vla-put-textstring att (rtos (caddr ins) 2 0))
         )
       )
    )
  )
  (*error* nil)
  (princ)
) (vl-load-com)

[Hammer.John.J]

can't wait to test this thanks!!