Help needed for modification of block extraction lisp

[radu.iordache803715]

The attached lisp selects all blocks named "TEST" in the drawing and writes a line with coordinates (Y, X) for each one in a txt file. Can someone help with a modification that will add the attributes values after the coordinates, for example:

Now it's: Y,X (one line for each block)

Should be: Y,X,Material att value,Year att value,Status att value (one line for each block)

Thanks in advance!

[Opie]

Have you searched the forums on how to get the attribute data? I'm fairly certain someone has posted a solution that may help you get there. If you use the VLISP methods, you might be able to get there easier.

[Ed Jobe]

The ActiveX BlockReference object has a GetAttributes method that you can foreach. See this thread for some sample code.

[Osama.Omari]

Use "dataextraction" command in AutoCAD to extract the current drawing attribute data or select multiple drawings or a folder that contains a lot of drawings.

[peter]

That was fun.

P=

;___________________________________________________________________________________________________________|
;
; Written By: Peter Jamtgaard copyright 2023 All Rights Reserved
;___________________________________________________________________________________________________________|
;
; Abstract: This function will extract Y,X position of ALL test block plus data from attributes and
; export it to a csv data file of same name as drawing.
;___________________________________________________________________________________________________________|

;___________________________________________________________________________________________________________|
;
; Command line function list
;___________________________________________________________________________________________________________|

;* C:SUR
;* Command Line Function to extract position and attribute textstrings of ALL "test" blocks

;* C:SurveyData
;* Command Line Function to extract position and attribute textstrings of ALL "test" blocks

;___________________________________________________________________________________________________________|
;
; General Function Header List
;___________________________________________________________________________________________________________|

;* (BlockData objBlock)
;* Function to convert a entity based selection set to a list.

;* (SurveyDataFileName)
;* Function to make a datafile name. 

;* (ErrorTrap symFunction)
;* Function to convert a entity based selection set to a list.

;* (ListToCSVFile strFilename lstOfSublists strChar)
;* Export a list of sublists of strings to a text file

;* (ListToCSVString lstSublist strChar)
;* Function to Convert List to CSV String

;* (SelectionSetToList ssSelections)
;* Function to convert a entity based selection set to a list.

;$ End Header


;___________________________________________________________________________________________________________| 
;
; Command Line Function to extract position and attribute textstrings of ALL "test" blocks
;___________________________________________________________________________________________________________|

(defun C:SUR ()(C:SurveyData))

(defun C:SurveyData (/ lstBlocks lstOfSublists ssSelections strDataFile)
 (if (and (setq ssSelections  (ssget "X" (list (cons 2 "TEST"))))
          (setq lstBlocks     (SelectionSetToList ssSelections))
          (setq lstOfSublists (mapcar 'BlockData lstBlocks))
          (setq strDataFile   (SurveyDataFileName))
          (ListToCSVFile strDataFile lstOfSublists ",")
          (getstring "\nPress Enter to view data file: ")
     )
  (command "notepad" strDataFile)
 )
 (princ)
)



;___________________________________________________________________________________________________________|
;
; Function to convert a entity based selection set to a list.
;___________________________________________________________________________________________________________|

(defun BlockData (objBlock / lstAttributeObjects lstTextStrings lstInsertion )
 (if (and (setq lstInsertion        (vlax-get objBlock "insertionpoint"))
          (setq lstAttributeObjects (vlax-invoke objBlock "getattributes"))
          (setq lstTextStrings      (mapcar '(lambda (X)(vlax-get X "textstring"))  lstAttributeObjects))
     )
  (list (nth 1 lstInsertion)
        (nth 0 lstInsertion)
        (nth 0 lstTextStrings)
        (nth 1 lstTextStrings)
        (nth 2 lstTextStrings)
  )
 )
)

;___________________________________________________________________________________________________________|
;
; Function to make a datafile name. 
;___________________________________________________________________________________________________________|

(defun SurveyDataFileName (/ strFileName strFullName)
 (if (and (setq strFilename (getvar "dwgname"))
          (/= strFileName "")
          (setq strFullName          (findfile strFileName))
          (setq strFullName          (strcase strFullName T))
     )
  (vl-string-subst ".csv" ".dwg"  strFullName 0)
 )
)






;___________________________________________________________________________________________________________|
;
; Function to convert a entity based selection set to a list.
;___________________________________________________________________________________________________________|

(defun ErrorTrap (symFunction / objError result)
 (if (vl-catch-all-error-p
      (setq objError (vl-catch-all-apply
                     '(lambda (X)(set X (eval symFunction)))
                      (list 'result))))
  nil
  (if result result 'T)
 )
)

;___________________________________________________________________________________________________________|
;
; Export a list of sublists of strings to a text file
;___________________________________________________________________________________________________________|

(defun ListToCSVFile (strFilename lstOfSublists strChar / filData lstSublist)
 (and
  (errortrap (quote (setq filData (open strFileName "w"))))
  (errortrap (quote (close filData)))
  (errortrap (quote (setq filData (open strFileName "w"))))
  (mapcar '(lambda (X)(and
                       (setq strText (ListtoCSVString X strChar))
                       (errortrap (quote (write-line strText filData)))
                      )
           )
           lstOfSublists
  )
 )
 (and
  filData
  (errortrap (quote (close filData)))
 ) 
)


;___________________________________________________________________________________________________________|
; 
; Function to Convert List to CSV String
;___________________________________________________________________________________________________________|

(defun ListToCSVString (lstSublist strChar / lstOfSublists)
 (if (and
      (setq lstSublist    (mapcar 'vl-princ-to-string lstSublist))
      (setq lstSublist  (mapcar '(lambda (X)(list strChar X)) lstSublist))
      (setq lstSublist  (apply 'append lstSublist))
     )
  (apply 'strcat (cdr lstSublist))
 )
)

;___________________________________________________________________________________________________________| 
;
; Function to convert a entity based selection set to a list.
;___________________________________________________________________________________________________________|

(defun SelectionSetToList (ssSelections / entSelection intCount lstObjects objSelection )
 (repeat (setq intCount (sslength ssSelections))
  (setq intCount (1- intCount))
  (setq entSelection (ssname ssSelections intCount))
  (setq objSelection (vlax-ename->vla-object entSelection))
  (setq lstObjects   (cons objSelection lstObjects))
 )
 lstObjects
)

(princ "!")
(vl-load-com)

[BIG-AL]

Should these be other way around XY not YX ?

(nth 1 lstInsertion)
(nth 0 lstInsertion)

A bit of fun.

Select multiple blocks with various attributes, from none to up to 25 atts in my test dwg.

Count the blocks and base the count on up to 5 levels deep in the attributes.

Make a table of the result or send to Excel direct.

Yes has a cost. Done in lisp.

eg result Door block

DOOR Black silverhandle 22
DOOR Black goldhandle 12
DOOR White silverhandle 4
DOOR White goldhandle 4

[peter]

Al,

Surveyors as a convention record Northing and Easting or Y,X.

So what he was asking for was correct if he is working with surveying

That is why I named it Survey Data.

...

I have posted recursive counting functions here too.

Yes very valuable.

If designed correctly you can generate automatic bill of materials, survey points, legends...

The potential is infinite and profitable.


P=

Al do you have this program or just working on it?

Can you post test drawing?

[BIG-AL]

Peter I will test make a few blocks and edit the blocks.

[peter]

Big Al,

I have the extract portion and wondered if you wanted a column for each tagstring or just ignore the tagstring and just extract the attributes in order.

Peter

[JaruUgarte]

Hi Sr. I can ask you a question, I need to make some modifications to your code that work for me. What I need is that instead of being a block with attributes, it is a block that only contains text. Below you will find the file that I mentioned