Exact point using ENTSEL

[cadconcepts]

HI All
I am working on a routine where I need to select a MULTILEADER with ENTSEL but I need to obtain the exact location (point) where I selected the object. Everything I have tried thus far returns a point at either end of the MULTILEADER. Any help is greatly appreciated.
Manuel

[Opie]

Are you using running OSNAPS? You may need to disable them during that operation.

[Tom Beauford]

Try:

    (setq e (nentselp pt)
          ent (entget(ssname (ssget pt nea) 0))
          etype (cdr(assoc 0 ent))
          elayer (cdr(assoc 8 ent))
          ent (cdar ent)
    )
    (if (= etype "MULTILEADER")
      (progn
        (setq e (nentselp pt)
              ent (entget(ssname (ssget pt nea) 0))
              etype (cdr(assoc 0 ent))
              ent (cdar ent)
        )
      )
    )

[aaronic_abacus]

might have to trash some CAR and CDR for this. i'm lost, (ENTGET (CAR ENTSEL)) ?
or (CDR ENTSEL))?

entity and point, yup CDR of entsel

[Tom Beauford]

might have to trash some CAR and CDR for this. i'm lost, (ENTGET (CAR ENTSEL)) ?
or (CDR ENTSEL))?

entity and point, yup CDR of entsel

The point returned by entsel is the location of the cursor and ignores osnap settings.
From Help: The pick point returned by entsel does not represent a point that lies on the selected object. The point returned is the location of the crosshairs at the time of selection. The relationship between the pick point and the object will vary depending on the size of the pickbox and the current zoom scale.

Only way I've ever gotten around it was to try snapping to a point on the selected object.
Works best if you're zoomed to the selected object, not a perfect solution.
Code I attached was a snippet from an old lisp of mine with a different entity type hoping it might help.

[Bruno.Valsecchi]

Hi,
Even with a standard command, it is impossible to latch onto a point close to a multileader.
I only see this not very elegant method to get the exact value of the near point.

((lambda ( / loop sel pt ent pt_near)
  (setq loop T)
  (while loop
    (setq sel (entsel "\nSelect an MLeader: "))
    (cond
      ((and sel (eq (cdr (assoc 0 (entget (car sel)))) "MULTILEADER"))
        (setq
          loop nil
          pt (cadr sel)
        )
        (command "_.undo" "_mark")
        (command "_.explode" (car sel))
        (setq
          ent (nentselp pt)
          pt_near (vlax-curve-getClosestPointTo (car ent) pt)
        )
        (command "_.undo" "_back")
      )
      (T (princ "\nIs not an MLeader or the selection is empty!"))
    )
  )
  (if pt_near (command "_.line" "_none" pt_near))
  (prin1)
))

[peter]

OK using active x

;___________________________________________________________________________________________________________|
;
; Written By: Peter Jamtgaard copyright 2023 All Rights Reserved
;___________________________________________________________________________________________________________|

;___________________________________________________________________________________________________________|
;
; Command Line Function Header List
;___________________________________________________________________________________________________________|

;* C:MLN
;* Command Line Function to get the nearest point to a multileader

;* C:MultiLeaderNearest
;* Command Line Function to get the nearest point to a multileader

;___________________________________________________________________________________________________________|
;
; General Function Header List
;___________________________________________________________________________________________________________|

;  Function List Argument1 Argument2 Arguement3

;* (ListofSublistsSortbyItem lstOfSublists intItem)
;* Function to sort a list of sublists by item in sublists

;* (MultiLeaderList objOwner objMultileader lstPoint)
;* Function to read get the list of ratio of distance and point sublists from each leader and sort them

;* (MultileaderSelect)
;* Function to select a multileader

;$ End Header

;___________________________________________________________________________________________________________
; 
; Command Line Function to get the nearest point to a multileader
;___________________________________________________________________________________________________________

(defun C:MLN ()(C:MultiLeaderNearest))

(defun C:MultiLeaderNearest (/ intOwnerID
                               lstObjectAndPoint
                               lstOfSublists 
                               lstPoint
                               lstSelection 
                               objDocument
                               objMultileader
                               objOwner
                            )
 (if (and (setq lstObjectAndPoint (MultileaderSelect))
          (setq objMultileader    (car lstObjectAndPoint))
          (setq lstPoint          (cadr lstObjectAndPoint))
          (setq intOwnerID        (vla-get-OwnerID objMultileader)) 
          (setq objDocument       (vla-get-document objMultileader))  
          (setq objOwner          (vla-objectidtoobject objDocument intOwnerID))
          (setq lstOfSublists     (MultiLeaderList objOwner objMultileader lstPoint))
          (setq lstPoint          (cadr (car (reverse lstOfSublists))))
     )
; lstPoint
  (vl-cmdf "circle" lstPoint 0.1)
 )
)

;___________________________________________________________________________________________________________
; 
; Function to sort a list of sublists by item in sublists
;___________________________________________________________________________________________________________

(defun ListofSublistsSortbyItem (lstOfSublists intItem)
 (vl-sort lstOfSublists '(lambda (X Y) (< (nth intItem X) (nth intItem Y))))
)

;___________________________________________________________________________________________________________
; 
; Function to read get the list of ratio of distance and point sublists from each leader and sort them
;___________________________________________________________________________________________________________

(defun MultiLeaderList (objOwner objMultileader lstPoint / intIndex
                                                           lstOfSublists 
                                                           lstPointNearest 
                                                           objPolyline 
                                                           sngDistance 
                                                           sngRatio 
                                                           sngLength 
                       )
 (foreach intIndex (vlax-invoke objMultileader "GetLeaderLineIndexes" 0)
  (if (and (setq lstLeaderLineIndexes (vlax-invoke objMultileader "GetLeaderLineVertices" intIndex))
           (setq objPolyline          (vlax-invoke objOwner "addpolyline" lstLeaderLineIndexes))
           (setq sngLength            (vla-get-length objPolyline))
           (setq lstPointNearest      (vlax-curve-getclosestpointto objPolyline lstPoint))
           (progn (vla-delete objPolyline) T)
           (setq sngDistance          (distance lstPoint lstPointNearest))
           (setq sngRatio             (/ sngLength sngDistance))
           (> sngRatio 20.0)           
                     
      )
   (setq lstOfSublists (cons (list sngRatio lstPointNearest) lstOfSublists))   
  )
 )
 (if lstOfSublists
  (listofsublistssortbyitem lstOfSublists 0)
  (print "Error Finding Nearest Point: ")
 )
)

;___________________________________________________________________________________________________________
; 
; Function to select a multileader
;___________________________________________________________________________________________________________

(defun MultileaderSelect (/ entSelection lstOfSublists lstPoint lstSelection objSelection ssSelection)
 (while (not (and (setq lstSelection (entsel "\nSelect Mleader"))
                  (setq lstPoint     (cadr lstSelection))
                  (setq ssSelection  (ssget lstPoint (list (cons 0 "MULTILEADER"))))
                  (setq entSelection (ssname ssSelection 0))
                  (setq objSelection (vlax-ename->vla-object entSelection))
             )
        )
  (princ "\nError Selecting Multileader: ")
 )
 (list objSelection lstPoint)
)

(princ "!")
(vl-load-com)

[Langbolt]

Does this help ?

(setq PICK_PT (cdr (entsel "Select Multileader: \n")))

[Ed Jobe]

Hi Langbolt, Welcome to AUGI!

The problem with the entsel command is that it gives the EXACT location of the cursor, which may be a minuscule distance away from the leader, not actually ON the leader. The other code samples are trying different ways to compensate for that.

[pkenewell685935]

Hi Langbolt, Welcome to AUGI!

The problem with the entsel command is that it gives the EXACT location of the cursor, which may be a minuscule distance away from the leader, not actually ON the leader. The other code samples are trying different ways to compensate for that.

Maybe something Like This? I have used this effectively in the past.
(setq PICK_PT (cadr (entsel "Select Multileader: \n"))
Obj_Pt (osnap PICK_PT "NEA") ; Or could use mode "END" for a vertex.
)