Block Attribute Update

[Wdobbin]

I am trying to create a lisp that will update a title block 'SNP-00A1AH00PW'

I have a block named "SNP-00A1AH00PW".

There are 2 specific attributes which I want to change in it.

The attribute names are...

TITLE1 & TITLE2

TITLE1 will = SIP
TITLE2 will = STAGE_2

I have currently put together the following. However, this does not seem to work. Any help would be appreciated.

(if ;;retrieve a set of attributed blocks
        (setq s ;; Assign the selection set pointer to variable 's'
            (ssget "_X" ;; Search entire database
               '(
                    (0 . "INSERT") ;; Block References
                    (66 . 1) ;; Attributed
                    (2 . "SNP-00A1AH00PW") ;; with name SNP-00A1AH00PW
                )
            ) ;; end SSGET
        ) ;; end SETQ

           
            (if (setq x )
                    (setq l
                        (cons
                           '(
                                ("TITLE1"  . "SIP")
                                ("TITLE2" .  "STAGE_2")
                            )
                        ) ;; end CONS
                    ) ;; end SETQ

[Wdobbin]

I have improved on the code but its not quite there, see below.

(defun c:updateblock ("SNP-00A1AH00PW" / ss)
  (setq ss (ssget "_X" '((0 . "INSERT") (2 . "SNP-00A1AH00PW"))))
  (if ss
    (progn
      (setq i 0)
      (while (< i (sslength ss))
        (setq ent (ssname ss i))
        (setq atts (entget ent))
        (foreach att atts
          (if (= "ATTRIB" (cdr (assoc 0 att)))
            (progn
              ; Update attribute values here
              ; For example, to update the value of an attribute named "TITLE1" to "20"
              ; Replace "TITLE1" and "20" with your desired values
              (cond ((= "TITLE1" (cdr (assoc 2 att))) 
                      (setq att-value "999")
                      (entmod (subst (cons 1 att-value) (assoc 1 att) atts)))
                    ((= "TITLE2" (cdr (assoc 2 att))) 
                      (setq att-value "1.0")
                      (entmod (subst (cons 1 att-value) (assoc 1 att) atts)))
                    )
            )
          )
        )
        (setq i (+ i 1))
      )
    )
  )
)

[Wdobbin]

Still not quiet there, see below for the latest rendition.

(defun c:updateblock (block-name / SNP-00A1AH00PW)
  (setq ss (ssget "_X" '((0 . "INSERT") (2 . SNP-00A1AH00PW))))
  (if ss
    (progn
      (setq i 0)
      (while (< i (sslength ss))
        (setq ent (ssname ss i))
        (setq atts (entget ent))
        (foreach att atts
          (if (= "ATTRIB" (cdr (assoc 0 att)))
            (progn
              ; Update attribute values here
              ; For example, to update the value of an attribute named "TITLE1" to "20"
              ; Replace "TITLE1" and "20" with your desired values
              (cond ((= "TITLE1" (cdr (assoc 2 att))) 
                      (setq att-value "SIP")
                      (entmod (subst (cons 1 att-value) (assoc 1 att) atts)))
                    ((= "TITLE2" (cdr (assoc 2 att))) 
                      (setq att-value "STAGE_2")
                      (entmod (subst (cons 1 att-value) (assoc 1 att) atts)))
                    )
            )
          )
        )
        (setq i (+ i 1))
      )
    )
  )
)

Please use [code]tags.

[PaulLi_apa]

give this a try:

; updateblock find matching block & update specific attribute values
; https://forums.augi.com/showthread.php?177289-Block-Attribute-Update
(defun c:updateblock (/ blkname tagname1 tagname2 ss i sen atts)
  ; Place Block Name & Attribute Tags & Values here:
  ; For example, to update the value of an attribute named "TITLE1" to "20"
  ; Replace "TITLE1" and "20" with your desired values
  (setq blkname "SNP-00A1AH00PW"
        tagname1 (list "TITLE1" "SIP")
        tagname2 (list "TITLE2" "STAGE_2")
        ss (ssget "_X" (list '(0 . "INSERT") (cons 2 blkname)))
  )
  (if ss
    (progn
      (setq i 0)
      (while (< i (sslength ss))
        (setq sen (entnext (ssname ss i)))                           ; get attributes
        (while sen
         (setq atts (entget sen))    
         (if (/= (cdr(assoc 0 atts)) "SEQEND") 
              (cond ((= (car tagname1) (cdr (assoc 2 atts))) 
                      (entmod (setq atts(subst (cons 1 (cadr tagname1)) (assoc 1 atts) atts))))
                    ((= (car tagname2) (cdr (assoc 2 atts))) 
                      (entmod (setq atts(subst (cons 1 (cadr tagname2)) (assoc 1 atts) atts))))
              )
          ) ; if more attributes
          (setq sen (entnext sen))                     ; and search
         ) ; while attributes
        (setq i (+ i 1))
      )
      (alert(strcat"Found & Updated [" (itoa (sslength ss)) "] Blocks Matching name: [" blkname "]"))
    )
    (alert(strcat"Did NOT find any Blocks Matching name: [" blkname "]"))
  )
  (princ)
)