Lisp to open a file folder

[cadd4la]

Hi everyone,

I need help on a lisp that will open a file folder on my network, I tried to write one but when the code is run it opens the Documents folder. Not sure how to fix it.

(defun c:ZOF24x36 ()
   (startapp "explorer" "C:\\VDG Dropbox\\03 - C A D  Defaults\\03.01-Blocks\\03.01.04-CDs\\03.01.04.06-Details\\03.03.04.01-VDG_24x36")
)

Thanks for the help.

Cadd4la

[Tom Beauford]

This Lee Mac function should work: http://www.lee-mac.com/explore.html
Load it and try:

(LM:explore "C:\\VDG Dropbox\\03 - C A D  Defaults\\03.01-Blocks\\03.01.04-CDs\\03.01.04.06-Details\\03.03.04.01-VDG_24x36")

[Opie]

Hi everyone,

I need help on a lisp that will open a file folder on my network, I tried to write one but when the code is run it opens the Documents folder. Not sure how to fix it.

(defun c:ZOF24x36 ()
   (startapp "explorer" "C:\\VDG Dropbox\\03 - C A D  Defaults\\03.01-Blocks\\03.01.04-CDs\\03.01.04.06-Details\\03.03.04.01-VDG_24x36")
)

Thanks for the help.

Cadd4la

The issue is the spaces in your file path. You would need to encapsulate the file path within an additional set of quotes.

[rkmcswain]

I created your path as a test, and your code works fine for me.

AutoCAD 2023, Windows 10.

[cadd4la]

Tom,

Thanks for your reply, Unfortunately, the code doesn't work. This is what I get when I run it

Command: (LOAD "C:/Verde Dropbox/04 - C A D Custom Files/OpenFolder.LSP") ; error: no function definition: LM:EXPLORE

Cadd4la

[cadd4la]

Opie,

Thanks for your help, not sure where to add the additional set of quotes.

Cadd4la

[cadd4la]

R.K.,

Thank you for your reply. my code still won't work for me.

Cadd4la

[Tom Beauford]

Tom,

Thanks for your reply, Unfortunately, the code doesn't work. This is what I get when I run it
Command: (LOAD "C:/Verde Dropbox/04 - C A D Custom Files/OpenFolder.LSP") ; error: no function definition: LM:EXPLORE
Cadd4la

Guessing you saved "OpenFolder.LSP" to that folder you problem seems to be accessing that folder.
Assuming that folder is online accessing those files and folders can be slow and glitchy depending on how your network is setup.
Mirroring a copy of those files locally and accessing them from there may be a possible solution for both loading the lisp and accessing the file folder.

[Ed Jobe]

Opie,

Thanks for your help, not sure where to add the additional set of quotes.

Cadd4la

It's just how DOS works. If you have a path like C:\Program Files\, the command line sees the space and thinks that Files is an argument to C:\Program. You have to enclose the entire path in quotes "C:\Program Files". Don't forget that in lisp, you will also need an escape character for the quote inside a quote, ". Thus your code would become:

(defun c:ZOF24x36 ()
   (startapp "explorer" "\"C:\\VDG Dropbox\\03 - C A D  Defaults\\03.01-Blocks\\03.01.04-CDs\\03.01.04.06-Details\\03.03.04.01-VDG_24x36\"")
)

[Ed Jobe]

Tom,

Thanks for your reply, Unfortunately, the code doesn't work. This is what I get when I run it

Cadd4la

The function LM:explore hasn't been defined. You failed to load Lee's lisp file. You can load it at startup via acad.lsp or manually load it in this command. Did you download Lee's command from the link Tom posted in post 2? Copy the lisp from the link and save it to your acad.lsp file. Or save it to explore.lsp and in your zof function, use (load "explore.lsp").

;; Explore  -  Lee Mac
;; Opens a specified folder in a Windows Explorer window.
;; target - [int/str] Directory or ShellSpecialFolderConstants enum

(defun LM:explore ( target / rtn shl )
    (if (and (or (= 'int (type target)) (vl-file-directory-p target))
             (setq shl (vla-getinterfaceobject (vlax-get-acad-object) "shell.application"))
        )
        (progn
            (setq rtn (vl-catch-all-apply 'vlax-invoke (list shl 'explore target)))
            (vlax-release-object shl)
            (if (vl-catch-all-error-p rtn)
                (prompt (vl-catch-all-error-message rtn))
                t
            )
        )
    )
)

;;;usage
(defun c:ZOF24x36 ()
   (LM:explore "C:\\VDG Dropbox\\03 - C A D  Defaults\\03.01-Blocks\\03.01.04-CDs\\03.01.04.06-Details\\03.03.04.01-VDG_24x36")
)