Toggle Layer (Part Duex) "A State of Frozen"

[madcadder]

Back for More:

Ok. From the first thread I was turning a layer ON/OFF with a keystroke. If ON-turn off; if OFF-turn on.

Well, the original intent was to totally toggle to layer. ON/OFF, LOCK/UNLOCK, FROZEN/THAW.
To keep those setting local and put back when toggled on.

I found that in order to do this I needed the ASSOC 62 and ASSOC 70 values of that layer.
The 62 I could work with, but never figured out how to work with the 70 value.

Michael S. gave the following code for a VLISP example:

(defun c:MKSxLayerToggle(/ lName lyr lyrCol)
  (setq lyrCol (vla-get-layers (vla-get-activeDocument (vlax-get-acad-object))))  ;;get the layer collection
  (setq lName  "0")  ;;<-set the layer name here
  (if (vl-catch-all-error-p (setq lyr (vl-catch-all-apply 'vla-item (list lyrCol lName))))  ;;get specific layer object or error code
(princ)  ;;if error, do nothing
(if (= (vla-get-layerOn lyr) :vlax-true)  ;;if no error, check if layer is on
  (vla-put-layerOn lyr :vlax-false)  ;;if on, turn it off
  (vla-put-layerOn lyr :vlax-true)  ;;if off, turn it on
)
  )
  (princ)
)

From that I learned a few new things: vla-get-freeze, vla-get-plottable, vla-get-lock.

So, with those I should be able to totally toggle a layer now, correct? Maybe?
And what about FROZEN IN NEW and FROZEN IN CURRENT setting? How do I work with those?

[kennet.sjoberg]

... but never figured out how to work with the 70 value....

Standard flags (bit-coded values):
1 = Layer is frozen; otherwise layer is thawed
2 = Layer is frozen by default in new viewports
4 = Layer is locked
16 = If set, table entry is externally dependent on an xref
32 = If this bit and bit 16 are both set, the externally dependent xref has been successfully resolved
64 = If set, the table entry was referenced by at least one entity in the drawing the last time the drawing was edited. (This flag is for the benefit of AutoCAD commands. It can be ignored by most programs that read DXF files and need not be set by programs that write DXF files)

: ) Happy Computing !

kennet

[madcadder]

Thank you... The info I had for group 70 definitions was incorrect. it had plotting as part of the flag.

[kennet.sjoberg]

by the way. . .

(setq MyLayer "0" ) ; <-- change here
(if (setq LayDxf (tblsearch "LAYER" MyLayer ) )
  (progn
	(princ (strcat "Layer " MyLayer " is " ) )
	(if (minusp (cdr (assoc 62 LayDxf ))) (princ "OFF" )(princ "ON" ) )
	(if (= (logand 4 (cdr (assoc 70 LayDxf ))) 4 ) (princ ", Locked" )(princ ", UnLocked" ) )
	(if (= (logand 1 (cdr (assoc 70 LayDxf ))) 1 ) (princ " and Frozen." )(princ " and Thawed." ) )
  )
  (princ " Layer do not exist " )
)

: ) Happy Computing !

kennet