ssget closed polyline

[rad.77676]

Does anyone know how to create a selection set of only closed polylines?
The following specifies all polylines on specific layer, but I only need to grab closed boundaries.

(ssget "x" (list (cons 0 "LWPOLYLINE") (cons 8 "qsection")))

Thanks,
Rob

[fixo]

Does anyone know how to create a selection set of only closed polylines?
The following specifies all polylines on specific layer, but I only need to grab closed boundaries.

(ssget "x" (list (cons 0 "LWPOLYLINE") (cons 8 "qsection")))

Thanks,
Rob

Hi Rob

There is can to select with following expression:

(ssget "_X" (list (cons 0 "LWPOLYLINE")(cons 8 "qsection")(cons 70 1)))

Select all closed polylines on layer "qsection"

Thank you

f.

[rad.77676]

Hi Rob

There is can to select with following expression:

(ssget "_X" (list (cons 0 "LWPOLYLINE")(cons 8 "qsection")(cons 70 1)))

Select all closed polylines on layer "qsection"

Thank you

f.

Thanx fixo,
Next question, is there a way to create a selection set of objects that do not have a specific group of object data ("legal" ; field name)
Rob

[mohobrien]

Tear this apart. This is used to find polygons that don't have a object data table called "Disp" so if the object is simply missing the table use this.

;;; Utility to find polygons that are missing object data.
;;; Set the table name to what it is supposed to be
(defun c:no_od (/ item tables ss sset p1 p2)
  (prompt "\nSelect Objects to test by Window")
  (setq p1 (getpoint "\nFirst Corner: "))
  (setq p2 (getcorner p1 "\nSecond Corner: "))
  (setq sset	; this is the selection set of polygons to test
  (ssget
	"c"
	p1
	p2
	(list (cons 0 "LWPOLYLINE"))
  )
  )
  (if (= sset nil)   ; if nothing selected
	(progn	; do this
	  (princ)
	  (alert "No polylines selected!")
	  (exit)
	)	 ; end of routine to run if no polygons selected
	(progn	; if polygons have been selected do this
	  (setq ss (ssadd))   ; make an empty selection set to put naked polygons
	  (setq ctr 0)   ; set the counter to zero	  
	  (setq numofpolygons (sslength sset)) ; how many polygons selected
	  (while (and sset (> (sslength sset) 0))
 (setq item (ssname sset 0)) ; extract the name of first entity in the list.
 (setq tables (ade_odgettables item)) ; get the table names
 (if (= (member "Disp" tables) nil)
	 ; if particular object data is missing 
   (progn   ;- in this case "Disp"
	 (ssadd item ss)  ; add the item to the set to highlite
	 (ssdel item sset)  ; delete the item from selection set being tested
   )
   (ssdel item sset)  ; otherwise delete the item from selection set being tested
 )
 (setq ctr (+ ctr 1))  ; increase the counter
 (princ
   (strcat "\rChecked " (itoa ctr) " of " (itoa numofpolygons))
 )
	 ; checked ctr of numofpolygons
	  )	 ; get next item
	)	 ; end of routine to run if polygons selected
  )	 ; end of if
  (setq sset nil)   ; get rid of this now empty selection set
  (setq nood (sslength ss))  ; how many naked polygons
  (princ
	(strcat "\n" (itoa nood) " polygons have no object data")
  )
  (sssetfirst ss ss)   ; highlite and grip the ss selection set
  (princ)	; clean exit
)

If the field is empty use (ade_odgetfield ename table field recnum)
Remember the first recnum is 0 not 1
If nil is returned, there is no data for that field.

[fixo]

Thanx fixo,
Next question, is there a way to create a selection set of objects that do not have a specific group of object data ("legal" ; field name)
Rob

Hi Rob
Try this one

Thank you

f.

(ssget
	'((-4 . "<NOT") (102 . "{ACAD_XDICTIONARY") (-4 . "NOT>"))
      )

[rkmcswain]

Hi Rob
There is can to select with following expression:
(ssget "_X" (list (cons 0 "LWPOLYLINE")(cons 8 "qsection")(cons 70 1)))
Select all closed polylines on layer "qsection"

Sorry, but that will NOT select closed polylines whose linetype generation flag is set (because group 70 will = 129, not 1)

Try this instead:

(ssget "_X"
(list
(cons 0 "LWPOLYLINE")
(cons 8 "qsection")
(cons -4 "&")
(cons 70 1)
)
)

[kennet.sjoberg]

I think you need a function that select all lwpolylines on layer "qsection"
and then release the not closed lwpolyline.

(defun SCP (/ SelSet Index ) ;; SelectClosedPolylines on layer "qsection"
  (setq SelSet (ssget "_X" (list (cons 0 "LWPOLYLINE" )(cons 8 "qsection" ))) Index 0 )
  (repeat (sslength SelSet ) ;; step through every and check if closed
    (if (= (logand 1 (cdr (assoc 70 (entget (ssname SelSet Index ))))) 1 )
      (setq Index (1+ Index ) ) ;; if closed step to next item
      (ssdel (ssname SelSet Index ) SelSet ) ;; if not closed release from SelSet
    )
  )
  SelSet ;; Left is only closed lwpolyline in the Selset
)

test : (command "._move" (SCP) "" pause pause )

: ) Happy Computing !

kennet

[fixo]

Sorry, but that will NOT select closed polylines whose linetype generation flag is set (because group 70 will = 129, not 1)

Try this instead:

(ssget "_X"
(list
(cons 0 "LWPOLYLINE")
(cons 8 "qsection")
(cons -4 "&")
(cons 70 1)
)
)

Oh sorry I forgot about this flag
Of course there is big mistake:

(ssget '((70 . 129)));linetype generation enabled
(ssget '((70 . 1)));linetype generation disabled

Thank you for notation

f.

[kennet.sjoberg]

If you did not like my previous (SCP) function with the logand 1 filter, there the bit code allows only closed lwpolylines regardless of plinegen, you can use this simple line :

(ssget "X" '((-4 . "<AND") (0 . "LWPOLYLINE")(8 . "qsection")(-4 . "<OR")(70 . 1)(70 . 129)(-4 . "OR>")(-4 . "AND>")))

: ) Happy Computing !

kennet

[fixo]

If you did not like my previous (SCP) function with the logand 1 filter, there the bit code allows only closed lwpolylines regardless of plinegen, you can use this simple line :

(ssget "X" '((-4 . "<AND") (0 . "LWPOLYLINE")(8 . "qsection")(-4 . "<OR")(70 . 1)(70 . 129)(-4 . "OR>")(-4 . "AND>")))

: ) Happy Computing !

kennet

Hi Kennet

I not sure but I thought maybe in this case better yet to use following filter
because of splined LWPOLYLINE would be converted to POLYLINE:

(ssget "_X"
(list
(cons 0 "*POLYLINE")
(cons 8 "qsection")
(cons -4 "&")
(cons 70 1)
)
)

What you think about?
Thank you

f.